clone.S revision f94fd3ccc66e05f53965bc14237778c0d8437bb6 
1/*
2 * Copyright (C) 2008-2010 The Android Open Source Project
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions
7 * are met:
8 *  * Redistributions of source code must retain the above copyright
9 *    notice, this list of conditions and the following disclaimer.
10 *  * Redistributions in binary form must reproduce the above copyright
11 *    notice, this list of conditions and the following disclaimer in
12 *    the documentation and/or other materials provided with the
13 *    distribution.
14 *
15 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
16 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
17 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
18 * FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
19 * COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
20 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
21 * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS
22 * OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
23 * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
24 * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
25 * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
26 * SUCH DAMAGE.
27 */
28
29#include <machine/asm.h>
30#include <sys/linux-syscalls.h>
31
32ENTRY(__pthread_clone)
33    @ insert the args onto the new stack
34    stmdb r1!, {r0, r3}
35
36    @ do the system call
37    @ get flags
38
39    mov     r0, r2
40
41    @ new sp is already in r1
42
43    stmfd   sp!, {r4, r7}
44    ldr     r7, =__NR_clone
45    swi     #0
46
47    movs    r0, r0
48    ldmnefd sp!, {r4, r7}
49    blt     __error
50    bxne    lr
51
52
53    @ pick the function arg and call address off the stack and jump
54    @ to the C __thread_entry function which does some setup and then
55    @ calls the thread's start function
56
57    pop     {r0, r1}
58    mov     r2, sp			@ __thread_entry needs the TLS pointer
59    b       __thread_entry
60
61__error:
62    mov     r0, #-1
63    bx      lr
64END(__pthread_clone)
65
66
67    #
68    # This function is defined as:
69    #
70    #   pid_t  __bionic_clone( int  flags, void *child_stack,
71    #                          pid_t *pid, void *tls, pid_t *ctid,
72    #                          int  (*fn)(void *), void* arg );
73    #
74    # NOTE: This is not the same signature than the GLibc
75    #       __clone function here !! Placing 'fn' and 'arg'
76    #       at the end of the parameter list makes the
77    #       implementation much simpler.
78    #
79
80ENTRY(__bionic_clone)
81    mov     ip, sp
82    .save   {r4, r5, r6, r7}
83
84    # save registers to parent stack
85    stmfd   sp!, {r4, r5, r6, r7}
86
87    # load extra parameters
88    ldmfd   ip, {r4, r5, r6}
89
90    # store 'fn' and 'arg' to the child stack
91    str     r5, [r1, #-4]
92    str     r6, [r1, #-8]
93
94    # system call
95    ldr     r7, =__NR_clone
96    swi     #0
97    movs    r0, r0
98    beq     1f
99
100    # in parent, reload saved registers
101    # then either exit or error
102    #
103    ldmfd   sp!, {r4, r5, r6, r7}
104    bxne    lr
105    b       __set_syscall_errno
106
1071:  # in the child - pick arguments
108    ldr    r0, [sp, #-4]
109    ldr    r1, [sp, #-8]
110    b      __bionic_clone_entry
111END(__bionic_clone)
112