quick_entrypoints_arm.S revision 235e77bd9f19e4faefda109be40f8744f3a66f40 
1/*
2 * Copyright (C) 2012 The Android Open Source Project
3 *
4 * Licensed under the Apache License, Version 2.0 (the "License");
5 * you may not use this file except in compliance with the License.
6 * You may obtain a copy of the License at
7 *
8 *      http://www.apache.org/licenses/LICENSE-2.0
9 *
10 * Unless required by applicable law or agreed to in writing, software
11 * distributed under the License is distributed on an "AS IS" BASIS,
12 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
13 * See the License for the specific language governing permissions and
14 * limitations under the License.
15 */
16
17#include "asm_support_arm.S"
18
19#include "arch/quick_alloc_entrypoints.S"
20
21    /* Deliver the given exception */
22    .extern artDeliverExceptionFromCode
23    /* Deliver an exception pending on a thread */
24    .extern artDeliverPendingException
25
26    /*
27     * Macro that sets up the callee save frame to conform with
28     * Runtime::CreateCalleeSaveMethod(kSaveAll)
29     */
30.macro SETUP_SAVE_ALL_CALLEE_SAVE_FRAME
31    push {r4-r11, lr} @ 9 words of callee saves
32    .save {r4-r11, lr}
33    .cfi_adjust_cfa_offset 36
34    .cfi_rel_offset r4, 0
35    .cfi_rel_offset r5, 4
36    .cfi_rel_offset r6, 8
37    .cfi_rel_offset r7, 12
38    .cfi_rel_offset r8, 16
39    .cfi_rel_offset r9, 20
40    .cfi_rel_offset r10, 24
41    .cfi_rel_offset r11, 28
42    .cfi_rel_offset lr, 32
43    vpush {s0-s31}
44    .pad #128
45    .cfi_adjust_cfa_offset 128
46    sub sp, #12       @ 3 words of space, bottom word will hold Method*
47    .pad #12
48    .cfi_adjust_cfa_offset 12
49
50     // Ugly compile-time check, but we only have the preprocessor.
51#if (FRAME_SIZE_SAVE_ALL_CALLEE_SAVE != 36 + 128 + 12)
52#error "SAVE_ALL_CALLEE_SAVE_FRAME(ARM) size not as expected."
53#endif
54.endm
55
56    /*
57     * Macro that sets up the callee save frame to conform with
58     * Runtime::CreateCalleeSaveMethod(kRefsOnly).
59     */
60.macro SETUP_REF_ONLY_CALLEE_SAVE_FRAME
61    push {r5-r8, r10-r11, lr} @ 7 words of callee saves
62    .save {r5-r8, r10-r11, lr}
63    .cfi_adjust_cfa_offset 28
64    .cfi_rel_offset r5, 0
65    .cfi_rel_offset r6, 4
66    .cfi_rel_offset r7, 8
67    .cfi_rel_offset r8, 12
68    .cfi_rel_offset r10, 16
69    .cfi_rel_offset r11, 20
70    .cfi_rel_offset lr, 24
71    sub sp, #4                @ bottom word will hold Method*
72    .pad #4
73    .cfi_adjust_cfa_offset 4
74
75    // Ugly compile-time check, but we only have the preprocessor.
76#if (FRAME_SIZE_REFS_ONLY_CALLEE_SAVE != 28 + 4)
77#error "REFS_ONLY_CALLEE_SAVE_FRAME(ARM) size not as expected."
78#endif
79.endm
80
81.macro RESTORE_REF_ONLY_CALLEE_SAVE_FRAME
82    add sp, #4               @ bottom word holds Method*
83    pop {r5-r8, r10-r11, lr} @ 7 words of callee saves
84    .cfi_restore r5
85    .cfi_restore r6
86    .cfi_restore r7
87    .cfi_restore r8
88    .cfi_restore r10
89    .cfi_restore r11
90    .cfi_adjust_cfa_offset -32
91.endm
92
93.macro RESTORE_REF_ONLY_CALLEE_SAVE_FRAME_AND_RETURN
94    add sp, #4               @ bottom word holds Method*
95    pop {r5-r8, r10-r11, lr} @ 7 words of callee saves
96    .cfi_restore r5
97    .cfi_restore r6
98    .cfi_restore r7
99    .cfi_restore r8
100    .cfi_restore r10
101    .cfi_restore r11
102    .cfi_adjust_cfa_offset -32
103    bx  lr                   @ return
104.endm
105
106    /*
107     * Macro that sets up the callee save frame to conform with
108     * Runtime::CreateCalleeSaveMethod(kRefsAndArgs).
109     */
110.macro SETUP_REF_AND_ARGS_CALLEE_SAVE_FRAME
111    push {r1-r3, r5-r8, r10-r11, lr}  @ 10 words of callee saves
112    .save {r1-r3, r5-r8, r10-r11, lr}
113    .cfi_rel_offset r1, 0
114    .cfi_rel_offset r2, 4
115    .cfi_rel_offset r3, 8
116    .cfi_rel_offset r5, 12
117    .cfi_rel_offset r6, 16
118    .cfi_rel_offset r7, 20
119    .cfi_rel_offset r8, 24
120    .cfi_rel_offset r10, 28
121    .cfi_rel_offset r11, 32
122    .cfi_rel_offset lr, 36
123    .cfi_adjust_cfa_offset 40
124    sub sp, #8                        @ 2 words of space, bottom word will hold Method*
125    .pad #8
126    .cfi_adjust_cfa_offset 8
127
128    // Ugly compile-time check, but we only have the preprocessor.
129#if (FRAME_SIZE_REFS_AND_ARGS_CALLEE_SAVE != 40 + 8)
130#error "REFS_AND_ARGS_CALLEE_SAVE_FRAME(ARM) size not as expected."
131#endif
132.endm
133
134.macro RESTORE_REF_AND_ARGS_CALLEE_SAVE_FRAME
135    add  sp, #8                      @ rewind sp
136    pop {r1-r3, r5-r8, r10-r11, lr}  @ 10 words of callee saves
137    .cfi_restore r1
138    .cfi_restore r2
139    .cfi_restore r3
140    .cfi_restore r5
141    .cfi_restore r6
142    .cfi_restore r7
143    .cfi_restore r8
144    .cfi_restore r10
145    .cfi_restore r11
146    .cfi_adjust_cfa_offset -48
147.endm
148
149.macro RETURN_IF_RESULT_IS_ZERO
150    cbnz   r0, 1f              @ result non-zero branch over
151    bx     lr                  @ return
1521:
153.endm
154
155.macro RETURN_IF_RESULT_IS_NON_ZERO
156    cbz    r0, 1f              @ result zero branch over
157    bx     lr                  @ return
1581:
159.endm
160
161    /*
162     * Macro that set calls through to artDeliverPendingExceptionFromCode, where the pending
163     * exception is Thread::Current()->exception_
164     */
165.macro DELIVER_PENDING_EXCEPTION
166    .fnend
167    .fnstart
168    SETUP_SAVE_ALL_CALLEE_SAVE_FRAME           @ save callee saves for throw
169    mov    r0, r9                              @ pass Thread::Current
170    mov    r1, sp                              @ pass SP
171    b      artDeliverPendingExceptionFromCode  @ artDeliverPendingExceptionFromCode(Thread*, SP)
172.endm
173
174.macro NO_ARG_RUNTIME_EXCEPTION c_name, cxx_name
175    .extern \cxx_name
176ENTRY \c_name
177    SETUP_SAVE_ALL_CALLEE_SAVE_FRAME  // save all registers as basis for long jump context
178    mov r0, r9                      @ pass Thread::Current
179    mov r1, sp                      @ pass SP
180    b   \cxx_name                   @ \cxx_name(Thread*, SP)
181END \c_name
182.endm
183
184.macro ONE_ARG_RUNTIME_EXCEPTION c_name, cxx_name
185    .extern \cxx_name
186ENTRY \c_name
187    SETUP_SAVE_ALL_CALLEE_SAVE_FRAME  // save all registers as basis for long jump context
188    mov r1, r9                      @ pass Thread::Current
189    mov r2, sp                      @ pass SP
190    b   \cxx_name                   @ \cxx_name(Thread*, SP)
191    bkpt
192END \c_name
193.endm
194
195.macro TWO_ARG_RUNTIME_EXCEPTION c_name, cxx_name
196    .extern \cxx_name
197ENTRY \c_name
198    SETUP_SAVE_ALL_CALLEE_SAVE_FRAME  // save all registers as basis for long jump context
199    mov r2, r9                      @ pass Thread::Current
200    mov r3, sp                      @ pass SP
201    b   \cxx_name                   @ \cxx_name(Thread*, SP)
202    bkpt
203END \c_name
204.endm
205
206    /*
207     * Called by managed code, saves callee saves and then calls artThrowException
208     * that will place a mock Method* at the bottom of the stack. Arg1 holds the exception.
209     */
210ONE_ARG_RUNTIME_EXCEPTION art_quick_deliver_exception, artDeliverExceptionFromCode
211
212    /*
213     * Called by managed code to create and deliver a NullPointerException.
214     */
215NO_ARG_RUNTIME_EXCEPTION art_quick_throw_null_pointer_exception, artThrowNullPointerExceptionFromCode
216
217    /*
218     * Called by managed code to create and deliver an ArithmeticException.
219     */
220NO_ARG_RUNTIME_EXCEPTION art_quick_throw_div_zero, artThrowDivZeroFromCode
221
222    /*
223     * Called by managed code to create and deliver an ArrayIndexOutOfBoundsException. Arg1 holds
224     * index, arg2 holds limit.
225     */
226TWO_ARG_RUNTIME_EXCEPTION art_quick_throw_array_bounds, artThrowArrayBoundsFromCode
227
228    /*
229     * Called by managed code to create and deliver a StackOverflowError.
230     */
231NO_ARG_RUNTIME_EXCEPTION art_quick_throw_stack_overflow, artThrowStackOverflowFromCode
232
233    /*
234     * Called by managed code to create and deliver a NoSuchMethodError.
235     */
236ONE_ARG_RUNTIME_EXCEPTION art_quick_throw_no_such_method, artThrowNoSuchMethodFromCode
237
238    /*
239     * All generated callsites for interface invokes and invocation slow paths will load arguments
240     * as usual - except instead of loading arg0/r0 with the target Method*, arg0/r0 will contain
241     * the method_idx.  This wrapper will save arg1-arg3, load the caller's Method*, align the
242     * stack and call the appropriate C helper.
243     * NOTE: "this" is first visible argument of the target, and so can be found in arg1/r1.
244     *
245     * The helper will attempt to locate the target and return a 64-bit result in r0/r1 consisting
246     * of the target Method* in r0 and method->code_ in r1.
247     *
248     * If unsuccessful, the helper will return NULL/NULL. There will bea pending exception in the
249     * thread and we branch to another stub to deliver it.
250     *
251     * On success this wrapper will restore arguments and *jump* to the target, leaving the lr
252     * pointing back to the original caller.
253     */
254.macro INVOKE_TRAMPOLINE c_name, cxx_name
255    .extern \cxx_name
256ENTRY \c_name
257    SETUP_REF_AND_ARGS_CALLEE_SAVE_FRAME  @ save callee saves in case allocation triggers GC
258    ldr    r2, [sp, #48]                  @ pass caller Method*
259    mov    r3, r9                         @ pass Thread::Current
260    mov    r12, sp
261    str    r12, [sp, #-16]!               @ expand the frame and pass SP
262    .pad #16
263    .cfi_adjust_cfa_offset 16
264    bl     \cxx_name                      @ (method_idx, this, caller, Thread*, SP)
265    add    sp, #16                        @ strip the extra frame
266    .cfi_adjust_cfa_offset -16
267    mov    r12, r1                        @ save Method*->code_
268    RESTORE_REF_AND_ARGS_CALLEE_SAVE_FRAME
269    cbz    r0, 1f                         @ did we find the target? if not go to exception delivery
270    bx     r12                            @ tail call to target
2711:
272    DELIVER_PENDING_EXCEPTION
273END \c_name
274.endm
275
276INVOKE_TRAMPOLINE art_quick_invoke_interface_trampoline, artInvokeInterfaceTrampoline
277INVOKE_TRAMPOLINE art_quick_invoke_interface_trampoline_with_access_check, artInvokeInterfaceTrampolineWithAccessCheck
278
279INVOKE_TRAMPOLINE art_quick_invoke_static_trampoline_with_access_check, artInvokeStaticTrampolineWithAccessCheck
280INVOKE_TRAMPOLINE art_quick_invoke_direct_trampoline_with_access_check, artInvokeDirectTrampolineWithAccessCheck
281INVOKE_TRAMPOLINE art_quick_invoke_super_trampoline_with_access_check, artInvokeSuperTrampolineWithAccessCheck
282INVOKE_TRAMPOLINE art_quick_invoke_virtual_trampoline_with_access_check, artInvokeVirtualTrampolineWithAccessCheck
283
284    /*
285     * Quick invocation stub.
286     * On entry:
287     *   r0 = method pointer
288     *   r1 = argument array or NULL for no argument methods
289     *   r2 = size of argument array in bytes
290     *   r3 = (managed) thread pointer
291     *   [sp] = JValue* result
292     *   [sp + 4] = shorty
293     */
294ENTRY art_quick_invoke_stub
295    push   {r0, r4, r5, r9, r11, lr}       @ spill regs
296    .save  {r0, r4, r5, r9, r11, lr}
297    .pad #24
298    .cfi_adjust_cfa_offset 24
299    .cfi_rel_offset r0, 0
300    .cfi_rel_offset r4, 4
301    .cfi_rel_offset r5, 8
302    .cfi_rel_offset r9, 12
303    .cfi_rel_offset r11, 16
304    .cfi_rel_offset lr, 20
305    mov    r11, sp                         @ save the stack pointer
306    .cfi_def_cfa_register r11
307    mov    r9, r3                          @ move managed thread pointer into r9
308#ifdef ARM_R4_SUSPEND_FLAG
309    mov    r4, #SUSPEND_CHECK_INTERVAL     @ reset r4 to suspend check interval
310#endif
311    add    r5, r2, #16                     @ create space for method pointer in frame
312    and    r5, #0xFFFFFFF0                 @ align frame size to 16 bytes
313    sub    sp, r5                          @ reserve stack space for argument array
314    add    r0, sp, #4                      @ pass stack pointer + method ptr as dest for memcpy
315    bl     memcpy                          @ memcpy (dest, src, bytes)
316    ldr    r0, [r11]                       @ restore method*
317    ldr    r1, [sp, #4]                    @ copy arg value for r1
318    ldr    r2, [sp, #8]                    @ copy arg value for r2
319    ldr    r3, [sp, #12]                   @ copy arg value for r3
320    mov    ip, #0                          @ set ip to 0
321    str    ip, [sp]                        @ store NULL for method* at bottom of frame
322    ldr    ip, [r0, #METHOD_QUICK_CODE_OFFSET]  @ get pointer to the code
323    blx    ip                              @ call the method
324    mov    sp, r11                         @ restore the stack pointer
325    ldr    ip, [sp, #24]                   @ load the result pointer
326    strd   r0, [ip]                        @ store r0/r1 into result pointer
327    pop    {r0, r4, r5, r9, r11, lr}       @ restore spill regs
328    .cfi_restore r0
329    .cfi_restore r4
330    .cfi_restore r5
331    .cfi_restore r9
332    .cfi_restore lr
333    .cfi_adjust_cfa_offset -24
334    bx     lr
335END art_quick_invoke_stub
336
337    /*
338     * On entry r0 is uint32_t* gprs_ and r1 is uint32_t* fprs_
339     */
340ARM_ENTRY art_quick_do_long_jump
341    vldm r1, {s0-s31}     @ load all fprs from argument fprs_
342    ldr  r2, [r0, #60]    @ r2 = r15 (PC from gprs_ 60=4*15)
343    ldr  r14, [r0, #56]   @ (LR from gprs_ 56=4*14)
344    add  r0, r0, #12      @ increment r0 to skip gprs_[0..2] 12=4*3
345    ldm  r0, {r3-r13}     @ load remaining gprs from argument gprs_
346    mov  r0, #0           @ clear result registers r0 and r1
347    mov  r1, #0
348    bx   r2               @ do long jump
349END art_quick_do_long_jump
350
351    /*
352     * Entry from managed code that calls artHandleFillArrayDataFromCode and delivers exception on
353     * failure.
354     */
355    .extern artHandleFillArrayDataFromCode
356ENTRY art_quick_handle_fill_data
357    SETUP_REF_ONLY_CALLEE_SAVE_FRAME  @ save callee saves in case exception allocation triggers GC
358    mov    r2, r9                          @ pass Thread::Current
359    mov    r3, sp                          @ pass SP
360    bl     artHandleFillArrayDataFromCode  @ (Array*, const DexFile::Payload*, Thread*, SP)
361    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME
362    RETURN_IF_RESULT_IS_ZERO
363    DELIVER_PENDING_EXCEPTION
364END art_quick_handle_fill_data
365
366    /*
367     * Entry from managed code that calls artLockObjectFromCode, may block for GC. r0 holds the
368     * possibly null object to lock.
369     */
370    .extern artLockObjectFromCode
371ENTRY art_quick_lock_object
372    cbz    r0, .Lslow_lock
373.Lretry_lock:
374    ldr    r2, [r9, #THREAD_ID_OFFSET]
375    ldrex  r1, [r0, #LOCK_WORD_OFFSET]
376    cbnz   r1, .Lnot_unlocked         @ already thin locked
377    @ unlocked case - r2 holds thread id with count of 0
378    strex  r3, r2, [r0, #LOCK_WORD_OFFSET]
379    cbnz   r3, .Lstrex_fail           @ store failed, retry
380    dmb    ish                        @ full (LoadLoad|LoadStore) memory barrier
381    bx lr
382.Lstrex_fail:
383    b .Lretry_lock                    @ unlikely forward branch, need to reload and recheck r1/r2
384.Lnot_unlocked:
385    lsr    r3, r1, 30
386    cbnz   r3, .Lslow_lock            @ if either of the top two bits are set, go slow path
387    eor    r2, r1, r2                 @ lock_word.ThreadId() ^ self->ThreadId()
388    uxth   r2, r2                     @ zero top 16 bits
389    cbnz   r2, .Lslow_lock            @ lock word and self thread id's match -> recursive lock
390                                      @ else contention, go to slow path
391    add    r2, r1, #65536             @ increment count in lock word placing in r2 for storing
392    lsr    r1, r2, 30                 @ if either of the top two bits are set, we overflowed.
393    cbnz   r1, .Lslow_lock            @ if we overflow the count go slow path
394    str    r2, [r0, #LOCK_WORD_OFFSET] @ no need for strex as we hold the lock
395    bx lr
396.Lslow_lock:
397    SETUP_REF_ONLY_CALLEE_SAVE_FRAME  @ save callee saves in case we block
398    mov    r1, r9                     @ pass Thread::Current
399    mov    r2, sp                     @ pass SP
400    bl     artLockObjectFromCode      @ (Object* obj, Thread*, SP)
401    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME
402    RETURN_IF_RESULT_IS_ZERO
403    DELIVER_PENDING_EXCEPTION
404END art_quick_lock_object
405
406    /*
407     * Entry from managed code that calls artUnlockObjectFromCode and delivers exception on failure.
408     * r0 holds the possibly null object to lock.
409     */
410    .extern artUnlockObjectFromCode
411ENTRY art_quick_unlock_object
412    cbz    r0, .Lslow_unlock
413    ldr    r1, [r0, #LOCK_WORD_OFFSET]
414    lsr    r2, r1, 30
415    cbnz   r2, .Lslow_unlock          @ if either of the top two bits are set, go slow path
416    ldr    r2, [r9, #THREAD_ID_OFFSET]
417    eor    r3, r1, r2                 @ lock_word.ThreadId() ^ self->ThreadId()
418    uxth   r3, r3                     @ zero top 16 bits
419    cbnz   r3, .Lslow_unlock          @ do lock word and self thread id's match?
420    cmp    r1, #65536
421    bpl    .Lrecursive_thin_unlock
422    @ transition to unlocked, r3 holds 0
423    dmb    ish                        @ full (LoadStore|StoreStore) memory barrier
424    str    r3, [r0, #LOCK_WORD_OFFSET]
425    bx     lr
426.Lrecursive_thin_unlock:
427    sub    r1, r1, #65536
428    str    r1, [r0, #LOCK_WORD_OFFSET]
429    bx     lr
430.Lslow_unlock:
431    SETUP_REF_ONLY_CALLEE_SAVE_FRAME  @ save callee saves in case exception allocation triggers GC
432    mov    r1, r9                     @ pass Thread::Current
433    mov    r2, sp                     @ pass SP
434    bl     artUnlockObjectFromCode    @ (Object* obj, Thread*, SP)
435    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME
436    RETURN_IF_RESULT_IS_ZERO
437    DELIVER_PENDING_EXCEPTION
438END art_quick_unlock_object
439
440    /*
441     * Entry from managed code that calls artIsAssignableFromCode and on failure calls
442     * artThrowClassCastException.
443     */
444    .extern artThrowClassCastException
445ENTRY art_quick_check_cast
446    push {r0-r1, lr}                    @ save arguments, link register and pad
447    .save {r0-r1, lr}
448    .cfi_adjust_cfa_offset 12
449    .cfi_rel_offset r0, 0
450    .cfi_rel_offset r1, 4
451    .cfi_rel_offset lr, 8
452    sub sp, #4
453    .pad #4
454    .cfi_adjust_cfa_offset 4
455    bl artIsAssignableFromCode
456    cbz    r0, .Lthrow_class_cast_exception
457    add sp, #4
458    .cfi_adjust_cfa_offset -4
459    pop {r0-r1, pc}
460.Lthrow_class_cast_exception:
461    add sp, #4
462    .cfi_adjust_cfa_offset -4
463    pop {r0-r1, lr}
464    .cfi_restore r0
465    .cfi_restore r1
466    SETUP_SAVE_ALL_CALLEE_SAVE_FRAME  // save all registers as basis for long jump context
467    mov r2, r9                      @ pass Thread::Current
468    mov r3, sp                      @ pass SP
469    b   artThrowClassCastException  @ (Class*, Class*, Thread*, SP)
470    bkpt
471END art_quick_check_cast
472
473    /*
474     * Entry from managed code for array put operations of objects where the value being stored
475     * needs to be checked for compatibility.
476     * r0 = array, r1 = index, r2 = value
477     */
478ENTRY art_quick_aput_obj_with_null_and_bound_check
479    tst r0, r0
480    bne art_quick_aput_obj_with_bound_check
481    b art_quick_throw_null_pointer_exception
482END art_quick_aput_obj_with_null_and_bound_check
483
484    .hidden art_quick_aput_obj_with_bound_check
485ENTRY art_quick_aput_obj_with_bound_check
486    ldr r3, [r0, #ARRAY_LENGTH_OFFSET]
487    cmp r3, r1
488    bhi art_quick_aput_obj
489    mov r0, r1
490    mov r1, r3
491    b art_quick_throw_array_bounds
492END art_quick_aput_obj_with_bound_check
493
494    .hidden art_quick_aput_obj
495ENTRY art_quick_aput_obj
496    cbz r2, .Ldo_aput_null
497    ldr r3, [r0, #CLASS_OFFSET]
498    ldr ip, [r2, #CLASS_OFFSET]
499    ldr r3, [r3, #CLASS_COMPONENT_TYPE_OFFSET]
500    cmp r3, ip  @ value's type == array's component type - trivial assignability
501    bne .Lcheck_assignability
502.Ldo_aput:
503    add r3, r0, #OBJECT_ARRAY_DATA_OFFSET
504    str r2, [r3, r1, lsl #2]
505    ldr r3, [r9, #THREAD_CARD_TABLE_OFFSET]
506    lsr r0, r0, #7
507    strb r3, [r3, r0]
508    blx lr
509.Ldo_aput_null:
510    add r3, r0, #OBJECT_ARRAY_DATA_OFFSET
511    str r2, [r3, r1, lsl #2]
512    blx lr
513.Lcheck_assignability:
514    push {r0-r2, lr}             @ save arguments
515    .save {r0-r2, lr}
516    .cfi_adjust_cfa_offset 16
517    .cfi_rel_offset r0, 0
518    .cfi_rel_offset r1, 4
519    .cfi_rel_offset r2, 8
520    .cfi_rel_offset lr, 12
521    mov r1, ip
522    mov r0, r3
523    bl artIsAssignableFromCode
524    cbz r0, .Lthrow_array_store_exception
525    pop {r0-r2, lr}
526    .cfi_restore r0
527    .cfi_restore r1
528    .cfi_restore r2
529    .cfi_restore lr
530    .cfi_adjust_cfa_offset -16
531    add r3, r0, #OBJECT_ARRAY_DATA_OFFSET
532    str r2, [r3, r1, lsl #2]
533    ldr r3, [r9, #THREAD_CARD_TABLE_OFFSET]
534    lsr r0, r0, #7
535    strb r3, [r3, r0]
536    blx lr
537.Lthrow_array_store_exception:
538    pop {r0-r2, lr}
539    .cfi_restore r0
540    .cfi_restore r1
541    .cfi_restore r2
542    .cfi_restore lr
543    .cfi_adjust_cfa_offset -16
544    SETUP_SAVE_ALL_CALLEE_SAVE_FRAME
545    mov r1, r2
546    mov r2, r9                   @ pass Thread::Current
547    mov r3, sp                   @ pass SP
548    b artThrowArrayStoreException  @ (Class*, Class*, Thread*, SP)
549    bkpt                         @ unreached
550END art_quick_aput_obj
551
552    /*
553     * Entry from managed code when uninitialized static storage, this stub will run the class
554     * initializer and deliver the exception on error. On success the static storage base is
555     * returned.
556     */
557    .extern artInitializeStaticStorageFromCode
558ENTRY art_quick_initialize_static_storage
559    SETUP_REF_ONLY_CALLEE_SAVE_FRAME           @ save callee saves in case of GC
560    mov    r2, r9                              @ pass Thread::Current
561    mov    r3, sp                              @ pass SP
562    @ artInitializeStaticStorageFromCode(uint32_t type_idx, Method* referrer, Thread*, SP)
563    bl     artInitializeStaticStorageFromCode
564    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME
565    RETURN_IF_RESULT_IS_NON_ZERO
566    DELIVER_PENDING_EXCEPTION
567END art_quick_initialize_static_storage
568
569    /*
570     * Entry from managed code when dex cache misses for a type_idx
571     */
572    .extern artInitializeTypeFromCode
573ENTRY art_quick_initialize_type
574    SETUP_REF_ONLY_CALLEE_SAVE_FRAME           @ save callee saves in case of GC
575    mov    r2, r9                              @ pass Thread::Current
576    mov    r3, sp                              @ pass SP
577    @ artInitializeTypeFromCode(uint32_t type_idx, Method* referrer, Thread*, SP)
578    bl     artInitializeTypeFromCode
579    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME
580    RETURN_IF_RESULT_IS_NON_ZERO
581    DELIVER_PENDING_EXCEPTION
582END art_quick_initialize_type
583
584    /*
585     * Entry from managed code when type_idx needs to be checked for access and dex cache may also
586     * miss.
587     */
588    .extern artInitializeTypeAndVerifyAccessFromCode
589ENTRY art_quick_initialize_type_and_verify_access
590    SETUP_REF_ONLY_CALLEE_SAVE_FRAME           @ save callee saves in case of GC
591    mov    r2, r9                              @ pass Thread::Current
592    mov    r3, sp                              @ pass SP
593    @ artInitializeTypeAndVerifyAccessFromCode(uint32_t type_idx, Method* referrer, Thread*, SP)
594    bl     artInitializeTypeAndVerifyAccessFromCode
595    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME
596    RETURN_IF_RESULT_IS_NON_ZERO
597    DELIVER_PENDING_EXCEPTION
598END art_quick_initialize_type_and_verify_access
599
600    /*
601     * Called by managed code to resolve a static field and load a 32-bit primitive value.
602     */
603    .extern artGet32StaticFromCode
604ENTRY art_quick_get32_static
605    SETUP_REF_ONLY_CALLEE_SAVE_FRAME     @ save callee saves in case of GC
606    ldr    r1, [sp, #32]                 @ pass referrer
607    mov    r2, r9                        @ pass Thread::Current
608    mov    r3, sp                        @ pass SP
609    bl     artGet32StaticFromCode        @ (uint32_t field_idx, const Method* referrer, Thread*, SP)
610    ldr    r1, [r9, #THREAD_EXCEPTION_OFFSET]  @ load Thread::Current()->exception_
611    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME
612    cbnz   r1, 1f                        @ success if no exception pending
613    bx     lr                            @ return on success
6141:
615    DELIVER_PENDING_EXCEPTION
616END art_quick_get32_static
617
618    /*
619     * Called by managed code to resolve a static field and load a 64-bit primitive value.
620     */
621    .extern artGet64StaticFromCode
622ENTRY art_quick_get64_static
623    SETUP_REF_ONLY_CALLEE_SAVE_FRAME     @ save callee saves in case of GC
624    ldr    r1, [sp, #32]                 @ pass referrer
625    mov    r2, r9                        @ pass Thread::Current
626    mov    r3, sp                        @ pass SP
627    bl     artGet64StaticFromCode        @ (uint32_t field_idx, const Method* referrer, Thread*, SP)
628    ldr    r2, [r9, #THREAD_EXCEPTION_OFFSET]  @ load Thread::Current()->exception_
629    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME
630    cbnz   r2, 1f                        @ success if no exception pending
631    bx     lr                            @ return on success
6321:
633    DELIVER_PENDING_EXCEPTION
634END art_quick_get64_static
635
636    /*
637     * Called by managed code to resolve a static field and load an object reference.
638     */
639    .extern artGetObjStaticFromCode
640ENTRY art_quick_get_obj_static
641    SETUP_REF_ONLY_CALLEE_SAVE_FRAME     @ save callee saves in case of GC
642    ldr    r1, [sp, #32]                 @ pass referrer
643    mov    r2, r9                        @ pass Thread::Current
644    mov    r3, sp                        @ pass SP
645    bl     artGetObjStaticFromCode       @ (uint32_t field_idx, const Method* referrer, Thread*, SP)
646    ldr    r1, [r9, #THREAD_EXCEPTION_OFFSET]  @ load Thread::Current()->exception_
647    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME
648    cbnz   r1, 1f                        @ success if no exception pending
649    bx     lr                            @ return on success
6501:
651    DELIVER_PENDING_EXCEPTION
652END art_quick_get_obj_static
653
654    /*
655     * Called by managed code to resolve an instance field and load a 32-bit primitive value.
656     */
657    .extern artGet32InstanceFromCode
658ENTRY art_quick_get32_instance
659    SETUP_REF_ONLY_CALLEE_SAVE_FRAME     @ save callee saves in case of GC
660    ldr    r2, [sp, #32]                 @ pass referrer
661    mov    r3, r9                        @ pass Thread::Current
662    mov    r12, sp
663    str    r12, [sp, #-16]!              @ expand the frame and pass SP
664    bl     artGet32InstanceFromCode      @ (field_idx, Object*, referrer, Thread*, SP)
665    add    sp, #16                       @ strip the extra frame
666    ldr    r1, [r9, #THREAD_EXCEPTION_OFFSET]  @ load Thread::Current()->exception_
667    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME
668    cbnz   r1, 1f                        @ success if no exception pending
669    bx     lr                            @ return on success
6701:
671    DELIVER_PENDING_EXCEPTION
672END art_quick_get32_instance
673
674    /*
675     * Called by managed code to resolve an instance field and load a 64-bit primitive value.
676     */
677    .extern artGet64InstanceFromCode
678ENTRY art_quick_get64_instance
679    SETUP_REF_ONLY_CALLEE_SAVE_FRAME     @ save callee saves in case of GC
680    ldr    r2, [sp, #32]                 @ pass referrer
681    mov    r3, r9                        @ pass Thread::Current
682    mov    r12, sp
683    str    r12, [sp, #-16]!              @ expand the frame and pass SP
684    .pad #16
685    .cfi_adjust_cfa_offset 16
686    bl     artGet64InstanceFromCode      @ (field_idx, Object*, referrer, Thread*, SP)
687    add    sp, #16                       @ strip the extra frame
688    .cfi_adjust_cfa_offset -16
689    ldr    r2, [r9, #THREAD_EXCEPTION_OFFSET]  @ load Thread::Current()->exception_
690    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME
691    cbnz   r2, 1f                        @ success if no exception pending
692    bx     lr                            @ return on success
6931:
694    DELIVER_PENDING_EXCEPTION
695END art_quick_get64_instance
696
697    /*
698     * Called by managed code to resolve an instance field and load an object reference.
699     */
700    .extern artGetObjInstanceFromCode
701ENTRY art_quick_get_obj_instance
702    SETUP_REF_ONLY_CALLEE_SAVE_FRAME     @ save callee saves in case of GC
703    ldr    r2, [sp, #32]                 @ pass referrer
704    mov    r3, r9                        @ pass Thread::Current
705    mov    r12, sp
706    str    r12, [sp, #-16]!              @ expand the frame and pass SP
707    .pad #16
708    .cfi_adjust_cfa_offset 16
709    bl     artGetObjInstanceFromCode     @ (field_idx, Object*, referrer, Thread*, SP)
710    add    sp, #16                       @ strip the extra frame
711    .cfi_adjust_cfa_offset -16
712    ldr    r1, [r9, #THREAD_EXCEPTION_OFFSET]  @ load Thread::Current()->exception_
713    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME
714    cbnz   r1, 1f                        @ success if no exception pending
715    bx     lr                            @ return on success
7161:
717    DELIVER_PENDING_EXCEPTION
718END art_quick_get_obj_instance
719
720    /*
721     * Called by managed code to resolve a static field and store a 32-bit primitive value.
722     */
723    .extern artSet32StaticFromCode
724ENTRY art_quick_set32_static
725    SETUP_REF_ONLY_CALLEE_SAVE_FRAME     @ save callee saves in case of GC
726    ldr    r2, [sp, #32]                 @ pass referrer
727    mov    r3, r9                        @ pass Thread::Current
728    mov    r12, sp
729    str    r12, [sp, #-16]!              @ expand the frame and pass SP
730    .pad #16
731    .cfi_adjust_cfa_offset 16
732    bl     artSet32StaticFromCode        @ (field_idx, new_val, referrer, Thread*, SP)
733    add    sp, #16                       @ strip the extra frame
734    .cfi_adjust_cfa_offset -16
735    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME
736    RETURN_IF_RESULT_IS_ZERO
737    DELIVER_PENDING_EXCEPTION
738END art_quick_set32_static
739
740    /*
741     * Called by managed code to resolve a static field and store a 64-bit primitive value.
742     * On entry r0 holds field index, r1:r2 hold new_val
743     */
744    .extern artSet64StaticFromCode
745ENTRY art_quick_set64_static
746    SETUP_REF_ONLY_CALLEE_SAVE_FRAME     @ save callee saves in case of GC
747    mov    r3, r2                        @ pass one half of wide argument
748    mov    r2, r1                        @ pass other half of wide argument
749    ldr    r1, [sp, #32]                 @ pass referrer
750    mov    r12, sp                       @ save SP
751    sub    sp, #8                        @ grow frame for alignment with stack args
752    .pad #8
753    .cfi_adjust_cfa_offset 8
754    push   {r9, r12}                     @ pass Thread::Current and SP
755    .save {r9, r12}
756    .cfi_adjust_cfa_offset 8
757    .cfi_rel_offset r9, 0
758    bl     artSet64StaticFromCode        @ (field_idx, referrer, new_val, Thread*, SP)
759    add    sp, #16                       @ release out args
760    .cfi_adjust_cfa_offset -16
761    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME   @ TODO: we can clearly save an add here
762    RETURN_IF_RESULT_IS_ZERO
763    DELIVER_PENDING_EXCEPTION
764END art_quick_set64_static
765
766    /*
767     * Called by managed code to resolve a static field and store an object reference.
768     */
769    .extern artSetObjStaticFromCode
770ENTRY art_quick_set_obj_static
771    SETUP_REF_ONLY_CALLEE_SAVE_FRAME     @ save callee saves in case of GC
772    ldr    r2, [sp, #32]                 @ pass referrer
773    mov    r3, r9                        @ pass Thread::Current
774    mov    r12, sp
775    str    r12, [sp, #-16]!              @ expand the frame and pass SP
776    .pad #16
777    .cfi_adjust_cfa_offset 16
778    bl     artSetObjStaticFromCode       @ (field_idx, new_val, referrer, Thread*, SP)
779    add    sp, #16                       @ strip the extra frame
780    .cfi_adjust_cfa_offset -16
781    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME
782    RETURN_IF_RESULT_IS_ZERO
783    DELIVER_PENDING_EXCEPTION
784END art_quick_set_obj_static
785
786    /*
787     * Called by managed code to resolve an instance field and store a 32-bit primitive value.
788     */
789    .extern artSet32InstanceFromCode
790ENTRY art_quick_set32_instance
791    SETUP_REF_ONLY_CALLEE_SAVE_FRAME     @ save callee saves in case of GC
792    ldr    r3, [sp, #32]                 @ pass referrer
793    mov    r12, sp                       @ save SP
794    sub    sp, #8                        @ grow frame for alignment with stack args
795    .pad #8
796    .cfi_adjust_cfa_offset 8
797    push   {r9, r12}                     @ pass Thread::Current and SP
798    .save {r9, r12}
799    .cfi_adjust_cfa_offset 8
800    .cfi_rel_offset r9, 0
801    .cfi_rel_offset r12, 4
802    bl     artSet32InstanceFromCode      @ (field_idx, Object*, new_val, referrer, Thread*, SP)
803    add    sp, #16                       @ release out args
804    .cfi_adjust_cfa_offset -16
805    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME   @ TODO: we can clearly save an add here
806    RETURN_IF_RESULT_IS_ZERO
807    DELIVER_PENDING_EXCEPTION
808END art_quick_set32_instance
809
810    /*
811     * Called by managed code to resolve an instance field and store a 64-bit primitive value.
812     */
813    .extern artSet32InstanceFromCode
814ENTRY art_quick_set64_instance
815    SETUP_REF_ONLY_CALLEE_SAVE_FRAME     @ save callee saves in case of GC
816    mov    r12, sp                       @ save SP
817    sub    sp, #8                        @ grow frame for alignment with stack args
818    .pad #8
819    .cfi_adjust_cfa_offset 8
820    push   {r9, r12}                     @ pass Thread::Current and SP
821    .save {r9, r12}
822    .cfi_adjust_cfa_offset 8
823    .cfi_rel_offset r9, 0
824    bl     artSet64InstanceFromCode      @ (field_idx, Object*, new_val, Thread*, SP)
825    add    sp, #16                       @ release out args
826    .cfi_adjust_cfa_offset -16
827    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME   @ TODO: we can clearly save an add here
828    RETURN_IF_RESULT_IS_ZERO
829    DELIVER_PENDING_EXCEPTION
830END art_quick_set64_instance
831
832    /*
833     * Called by managed code to resolve an instance field and store an object reference.
834     */
835    .extern artSetObjInstanceFromCode
836ENTRY art_quick_set_obj_instance
837    SETUP_REF_ONLY_CALLEE_SAVE_FRAME     @ save callee saves in case of GC
838    ldr    r3, [sp, #32]                 @ pass referrer
839    mov    r12, sp                       @ save SP
840    sub    sp, #8                        @ grow frame for alignment with stack args
841    .pad #8
842    .cfi_adjust_cfa_offset 8
843    push   {r9, r12}                     @ pass Thread::Current and SP
844    .save {r9, r12}
845    .cfi_adjust_cfa_offset 8
846    .cfi_rel_offset r9, 0
847    bl     artSetObjInstanceFromCode     @ (field_idx, Object*, new_val, referrer, Thread*, SP)
848    add    sp, #16                       @ release out args
849    .cfi_adjust_cfa_offset -16
850    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME   @ TODO: we can clearly save an add here
851    RETURN_IF_RESULT_IS_ZERO
852    DELIVER_PENDING_EXCEPTION
853END art_quick_set_obj_instance
854
855    /*
856     * Entry from managed code to resolve a string, this stub will allocate a String and deliver an
857     * exception on error. On success the String is returned. R0 holds the referring method,
858     * R1 holds the string index. The fast path check for hit in strings cache has already been
859     * performed.
860     */
861    .extern artResolveStringFromCode
862ENTRY art_quick_resolve_string
863    SETUP_REF_ONLY_CALLEE_SAVE_FRAME  @ save callee saves in case of GC
864    mov    r2, r9                     @ pass Thread::Current
865    mov    r3, sp                     @ pass SP
866    @ artResolveStringFromCode(Method* referrer, uint32_t string_idx, Thread*, SP)
867    bl     artResolveStringFromCode
868    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME
869    RETURN_IF_RESULT_IS_NON_ZERO
870    DELIVER_PENDING_EXCEPTION
871END art_quick_resolve_string
872
873// Macro to facilitate adding new allocation entrypoints.
874.macro TWO_ARG_DOWNCALL name, entrypoint, return
875    .extern \entrypoint
876ENTRY \name
877    SETUP_REF_ONLY_CALLEE_SAVE_FRAME  @ save callee saves in case of GC
878    mov    r2, r9                     @ pass Thread::Current
879    mov    r3, sp                     @ pass SP
880    bl     \entrypoint     @ (uint32_t type_idx, Method* method, Thread*, SP)
881    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME
882    \return
883    DELIVER_PENDING_EXCEPTION
884END \name
885.endm
886
887// Macro to facilitate adding new array allocation entrypoints.
888.macro THREE_ARG_DOWNCALL name, entrypoint, return
889    .extern \entrypoint
890ENTRY \name
891    SETUP_REF_ONLY_CALLEE_SAVE_FRAME  @ save callee saves in case of GC
892    mov    r3, r9                     @ pass Thread::Current
893    mov    r12, sp
894    str    r12, [sp, #-16]!           @ expand the frame and pass SP
895    .pad #16
896    .cfi_adjust_cfa_offset 16
897    @ (uint32_t type_idx, Method* method, int32_t component_count, Thread*, SP)
898    bl     \entrypoint
899    add    sp, #16                    @ strip the extra frame
900    .cfi_adjust_cfa_offset -16
901    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME
902    \return
903    DELIVER_PENDING_EXCEPTION
904END \name
905.endm
906
907// Generate the allocation entrypoints for each allocator.
908GENERATE_ALL_ALLOC_ENTRYPOINTS
909
910    /*
911     * Called by managed code when the value in rSUSPEND has been decremented to 0.
912     */
913    .extern artTestSuspendFromCode
914ENTRY art_quick_test_suspend
915#ifdef ARM_R4_SUSPEND_FLAG
916    ldrh    r0, [rSELF, #THREAD_FLAGS_OFFSET]
917    mov    rSUSPEND, #SUSPEND_CHECK_INTERVAL  @ reset rSUSPEND to SUSPEND_CHECK_INTERVAL
918    cbnz   r0, 1f                             @ check Thread::Current()->suspend_count_ == 0
919    bx     lr                                 @ return if suspend_count_ == 0
9201:
921#endif
922    mov    r0, rSELF
923    SETUP_REF_ONLY_CALLEE_SAVE_FRAME          @ save callee saves for stack crawl
924    mov    r1, sp
925    bl     artTestSuspendFromCode             @ (Thread*, SP)
926    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME_AND_RETURN
927END art_quick_test_suspend
928
929ENTRY art_quick_implicit_suspend
930    mov    r0, rSELF
931    SETUP_REF_ONLY_CALLEE_SAVE_FRAME          @ save callee saves for stack crawl
932    mov    r1, sp
933    bl     artTestSuspendFromCode             @ (Thread*, SP)
934    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME_AND_RETURN
935END art_quick_implicit_suspend
936
937    /*
938     * Called by managed code that is attempting to call a method on a proxy class. On entry
939     * r0 holds the proxy method and r1 holds the receiver; r2 and r3 may contain arguments. The
940     * frame size of the invoked proxy method agrees with a ref and args callee save frame.
941     */
942     .extern artQuickProxyInvokeHandler
943ENTRY art_quick_proxy_invoke_handler
944    SETUP_REF_AND_ARGS_CALLEE_SAVE_FRAME
945    str     r0, [sp, #0]           @ place proxy method at bottom of frame
946    mov     r2, r9                 @ pass Thread::Current
947    mov     r3, sp                 @ pass SP
948    blx     artQuickProxyInvokeHandler  @ (Method* proxy method, receiver, Thread*, SP)
949    ldr     r2, [r9, #THREAD_EXCEPTION_OFFSET]  @ load Thread::Current()->exception_
950    add     sp, #16                @ skip r1-r3, 4 bytes padding.
951    .cfi_adjust_cfa_offset -16
952    cbnz    r2, 1f                 @ success if no exception is pending
953    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME
954    bx      lr                     @ return on success
9551:
956    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME
957    DELIVER_PENDING_EXCEPTION
958END art_quick_proxy_invoke_handler
959
960    /*
961     * Called to resolve an imt conflict. r12 is a hidden argument that holds the target method's
962     * dex method index.
963     */
964ENTRY art_quick_imt_conflict_trampoline
965    ldr    r0, [sp, #0]            @ load caller Method*
966    ldr    r0, [r0, #METHOD_DEX_CACHE_METHODS_OFFSET]  @ load dex_cache_resolved_methods
967    add    r0, #OBJECT_ARRAY_DATA_OFFSET  @ get starting address of data
968    ldr    r0, [r0, r12, lsl 2]    @ load the target method
969    b art_quick_invoke_interface_trampoline
970END art_quick_imt_conflict_trampoline
971
972    .extern artQuickResolutionTrampoline
973ENTRY art_quick_resolution_trampoline
974    SETUP_REF_AND_ARGS_CALLEE_SAVE_FRAME
975    mov     r2, r9                 @ pass Thread::Current
976    mov     r3, sp                 @ pass SP
977    blx     artQuickResolutionTrampoline  @ (Method* called, receiver, Thread*, SP)
978    cbz     r0, 1f                 @ is code pointer null? goto exception
979    mov     r12, r0
980    ldr  r0, [sp, #0]              @ load resolved method in r0
981    RESTORE_REF_AND_ARGS_CALLEE_SAVE_FRAME
982    bx      r12                    @ tail-call into actual code
9831:
984    RESTORE_REF_AND_ARGS_CALLEE_SAVE_FRAME
985    DELIVER_PENDING_EXCEPTION
986END art_quick_resolution_trampoline
987
988    /*
989     * Called to do a generic JNI down-call
990     */
991ENTRY_NO_HIDE art_quick_generic_jni_trampoline
992    SETUP_REF_AND_ARGS_CALLEE_SAVE_FRAME
993    str r0, [sp, #0]  // Store native ArtMethod* to bottom of stack.
994
995    // Save rSELF
996    mov r11, rSELF
997    // Save SP , so we can have static CFI info. r10 is saved in ref_and_args.
998    mov r10, sp
999    .cfi_def_cfa_register r10
1000
1001    sub sp, sp, #5120
1002
1003    // prepare for artQuickGenericJniTrampoline call
1004    // (Thread*,  SP)
1005    //    r0      r1   <= C calling convention
1006    //  rSELF     r10  <= where they are
1007
1008    mov r0, rSELF   // Thread*
1009    mov r1, r10
1010    blx artQuickGenericJniTrampoline  // (Thread*, sp)
1011
1012    // The C call will have registered the complete save-frame on success.
1013    // The result of the call is:
1014    // r0: pointer to native code, 0 on error.
1015    // r1: pointer to the bottom of the used area of the alloca, can restore stack till there.
1016
1017    // Check for error = 0.
1018    cbz r0, .Lentry_error
1019
1020    // Release part of the alloca.
1021    mov sp, r1
1022
1023    // Save the code pointer
1024    mov r12, r0
1025
1026    // Load parameters from frame into registers.
1027    pop {r0-r3}
1028
1029    // Softfloat.
1030    // TODO: Change to hardfloat when supported.
1031
1032    blx r12           // native call.
1033
1034    // result sign extension is handled in C code
1035    // prepare for artQuickGenericJniEndTrampoline call
1036    // (Thread*, result, result_f)
1037    //    r0      r1,r2    r3,stack       <= C calling convention
1038    //    r11     r0,r1    r0,r1          <= where they are
1039    sub sp, sp, #12 // Stack alignment.
1040
1041    push {r1}
1042    mov r3, r0
1043    mov r2, r1
1044    mov r1, r0
1045    mov r0, r11
1046
1047    blx artQuickGenericJniEndTrampoline
1048
1049    // Tear down the alloca.
1050    mov sp, r10
1051    .cfi_def_cfa_register sp
1052
1053    // Restore self pointer.
1054    mov r9, r11
1055
1056    // Pending exceptions possible.
1057    ldr r2, [r9, #THREAD_EXCEPTION_OFFSET]  @ load Thread::Current()->exception_
1058    cbnz r2, .Lexception_in_native
1059
1060    // Tear down the callee-save frame.
1061    RESTORE_REF_AND_ARGS_CALLEE_SAVE_FRAME
1062
1063    bx lr      // ret
1064
1065.Lentry_error:
1066    mov sp, r10
1067    .cfi_def_cfa_register sp
1068    mov r9, r11
1069.Lexception_in_native:
1070    RESTORE_REF_AND_ARGS_CALLEE_SAVE_FRAME
1071    DELIVER_PENDING_EXCEPTION
1072
1073END art_quick_generic_jni_trampoline
1074
1075    .extern artQuickToInterpreterBridge
1076ENTRY_NO_HIDE art_quick_to_interpreter_bridge
1077    SETUP_REF_AND_ARGS_CALLEE_SAVE_FRAME
1078    mov     r1, r9                 @ pass Thread::Current
1079    mov     r2, sp                 @ pass SP
1080    blx     artQuickToInterpreterBridge    @ (Method* method, Thread*, SP)
1081    ldr     r2, [r9, #THREAD_EXCEPTION_OFFSET]  @ load Thread::Current()->exception_
1082    add     sp, #16                @ skip r1-r3, 4 bytes padding.
1083    .cfi_adjust_cfa_offset -16
1084    RESTORE_REF_ONLY_CALLEE_SAVE_FRAME
1085    cbnz    r2, 1f                 @ success if no exception is pending
1086    bx    lr                       @ return on success
10871:
1088    DELIVER_PENDING_EXCEPTION
1089END art_quick_to_interpreter_bridge
1090
1091    /*
1092     * Routine that intercepts method calls and returns.
1093     */
1094    .extern artInstrumentationMethodEntryFromCode
1095    .extern artInstrumentationMethodExitFromCode
1096ENTRY art_quick_instrumentation_entry
1097    SETUP_REF_AND_ARGS_CALLEE_SAVE_FRAME
1098    str   r0, [sp, #4]     @ preserve r0
1099    mov   r12, sp          @ remember sp
1100    str   lr, [sp, #-16]!  @ expand the frame and pass LR
1101    .pad #16
1102    .cfi_adjust_cfa_offset 16
1103    .cfi_rel_offset lr, 0
1104    mov   r2, r9         @ pass Thread::Current
1105    mov   r3, r12        @ pass SP
1106    blx   artInstrumentationMethodEntryFromCode  @ (Method*, Object*, Thread*, SP, LR)
1107    add   sp, #16        @ remove out argument and padding from stack
1108    .cfi_adjust_cfa_offset -16
1109    mov   r12, r0        @ r12 holds reference to code
1110    ldr   r0, [sp, #4]   @ restore r0
1111    RESTORE_REF_AND_ARGS_CALLEE_SAVE_FRAME
1112    blx   r12            @ call method with lr set to art_quick_instrumentation_exit
1113END art_quick_instrumentation_entry
1114    .type art_quick_instrumentation_exit, #function
1115    .global art_quick_instrumentation_exit
1116art_quick_instrumentation_exit:
1117    .cfi_startproc
1118    .fnstart
1119    mov   lr, #0         @ link register is to here, so clobber with 0 for later checks
1120    SETUP_REF_ONLY_CALLEE_SAVE_FRAME
1121    mov   r12, sp        @ remember bottom of caller's frame
1122    push  {r0-r1}        @ save return value
1123    .save {r0-r1}
1124    .cfi_adjust_cfa_offset 8
1125    .cfi_rel_offset r0, 0
1126    .cfi_rel_offset r1, 4
1127    sub   sp, #8         @ space for return value argument
1128    .pad #8
1129    .cfi_adjust_cfa_offset 8
1130    strd r0, [sp]        @ r0/r1 -> [sp] for fpr_res
1131    mov   r2, r0         @ pass return value as gpr_res
1132    mov   r3, r1
1133    mov   r0, r9         @ pass Thread::Current
1134    mov   r1, r12        @ pass SP
1135    blx   artInstrumentationMethodExitFromCode  @ (Thread*, SP, gpr_res, fpr_res)
1136    add   sp, #8
1137    .cfi_adjust_cfa_offset -8
1138
1139    mov   r2, r0         @ link register saved by instrumentation
1140    mov   lr, r1         @ r1 is holding link register if we're to bounce to deoptimize
1141    pop   {r0, r1}       @ restore return value
1142    .cfi_restore r0
1143    .cfi_restore r1
1144    add sp, #32          @ remove callee save frame
1145    .cfi_adjust_cfa_offset -32
1146    bx    r2             @ return
1147END art_quick_instrumentation_exit
1148
1149    /*
1150     * Instrumentation has requested that we deoptimize into the interpreter. The deoptimization
1151     * will long jump to the upcall with a special exception of -1.
1152     */
1153    .extern artDeoptimize
1154ENTRY art_quick_deoptimize
1155    SETUP_SAVE_ALL_CALLEE_SAVE_FRAME
1156    mov    r0, r9         @ Set up args.
1157    mov    r1, sp
1158    blx    artDeoptimize  @ artDeoptimize(Thread*, SP)
1159END art_quick_deoptimize
1160
1161    /*
1162     * Signed 64-bit integer multiply.
1163     *
1164     * Consider WXxYZ (r1r0 x r3r2) with a long multiply:
1165     *        WX
1166     *      x YZ
1167     *  --------
1168     *     ZW ZX
1169     *  YW YX
1170     *
1171     * The low word of the result holds ZX, the high word holds
1172     * (ZW+YX) + (the high overflow from ZX).  YW doesn't matter because
1173     * it doesn't fit in the low 64 bits.
1174     *
1175     * Unlike most ARM math operations, multiply instructions have
1176     * restrictions on using the same register more than once (Rd and Rm
1177     * cannot be the same).
1178     */
1179    /* mul-long vAA, vBB, vCC */
1180ENTRY art_quick_mul_long
1181    push    {r9 - r10}
1182    .save {r9 - r10}
1183    .cfi_adjust_cfa_offset 8
1184    .cfi_rel_offset r9, 0
1185    .cfi_rel_offset r10, 4
1186    mul     ip, r2, r1                  @  ip<- ZxW
1187    umull   r9, r10, r2, r0             @  r9/r10 <- ZxX
1188    mla     r2, r0, r3, ip              @  r2<- YxX + (ZxW)
1189    add     r10, r2, r10                @  r10<- r10 + low(ZxW + (YxX))
1190    mov     r0,r9
1191    mov     r1,r10
1192    pop     {r9 - r10}
1193    .cfi_adjust_cfa_offset -8
1194    .cfi_restore r9
1195    .cfi_restore r10
1196    bx      lr
1197END art_quick_mul_long
1198
1199    /*
1200     * Long integer shift.  This is different from the generic 32/64-bit
1201     * binary operations because vAA/vBB are 64-bit but vCC (the shift
1202     * distance) is 32-bit.  Also, Dalvik requires us to ignore all but the low
1203     * 6 bits.
1204     * On entry:
1205     *   r0: low word
1206     *   r1: high word
1207     *   r2: shift count
1208     */
1209    /* shl-long vAA, vBB, vCC */
1210ARM_ENTRY art_quick_shl_long            @ ARM code as thumb code requires spills
1211    and     r2, r2, #63                 @ r2<- r2 & 0x3f
1212    mov     r1, r1, asl r2              @  r1<- r1 << r2
1213    rsb     r3, r2, #32                 @  r3<- 32 - r2
1214    orr     r1, r1, r0, lsr r3          @  r1<- r1 | (r0 << (32-r2))
1215    subs    ip, r2, #32                 @  ip<- r2 - 32
1216    movpl   r1, r0, asl ip              @  if r2 >= 32, r1<- r0 << (r2-32)
1217    mov     r0, r0, asl r2              @  r0<- r0 << r2
1218    bx      lr
1219END art_quick_shl_long
1220
1221    /*
1222     * Long integer shift.  This is different from the generic 32/64-bit
1223     * binary operations because vAA/vBB are 64-bit but vCC (the shift
1224     * distance) is 32-bit.  Also, Dalvik requires us to ignore all but the low
1225     * 6 bits.
1226     * On entry:
1227     *   r0: low word
1228     *   r1: high word
1229     *   r2: shift count
1230     */
1231    /* shr-long vAA, vBB, vCC */
1232ARM_ENTRY art_quick_shr_long            @ ARM code as thumb code requires spills
1233    and     r2, r2, #63                 @ r0<- r0 & 0x3f
1234    mov     r0, r0, lsr r2              @  r0<- r2 >> r2
1235    rsb     r3, r2, #32                 @  r3<- 32 - r2
1236    orr     r0, r0, r1, asl r3          @  r0<- r0 | (r1 << (32-r2))
1237    subs    ip, r2, #32                 @  ip<- r2 - 32
1238    movpl   r0, r1, asr ip              @  if r2 >= 32, r0<-r1 >> (r2-32)
1239    mov     r1, r1, asr r2              @  r1<- r1 >> r2
1240    bx      lr
1241END art_quick_shr_long
1242
1243    /*
1244     * Long integer shift.  This is different from the generic 32/64-bit
1245     * binary operations because vAA/vBB are 64-bit but vCC (the shift
1246     * distance) is 32-bit.  Also, Dalvik requires us to ignore all but the low
1247     * 6 bits.
1248     * On entry:
1249     *   r0: low word
1250     *   r1: high word
1251     *   r2: shift count
1252     */
1253    /* ushr-long vAA, vBB, vCC */
1254ARM_ENTRY art_quick_ushr_long           @ ARM code as thumb code requires spills
1255    and     r2, r2, #63                 @ r0<- r0 & 0x3f
1256    mov     r0, r0, lsr r2              @  r0<- r2 >> r2
1257    rsb     r3, r2, #32                 @  r3<- 32 - r2
1258    orr     r0, r0, r1, asl r3          @  r0<- r0 | (r1 << (32-r2))
1259    subs    ip, r2, #32                 @  ip<- r2 - 32
1260    movpl   r0, r1, lsr ip              @  if r2 >= 32, r0<-r1 >>> (r2-32)
1261    mov     r1, r1, lsr r2              @  r1<- r1 >>> r2
1262    bx      lr
1263END art_quick_ushr_long
1264
1265    /*
1266     * String's indexOf.
1267     *
1268     * On entry:
1269     *    r0:   string object (known non-null)
1270     *    r1:   char to match (known <= 0xFFFF)
1271     *    r2:   Starting offset in string data
1272     */
1273ENTRY art_quick_indexof
1274    push {r4, r10-r11, lr} @ 4 words of callee saves
1275    .save {r4, r10-r11, lr}
1276    .cfi_adjust_cfa_offset 16
1277    .cfi_rel_offset r4, 0
1278    .cfi_rel_offset r10, 4
1279    .cfi_rel_offset r11, 8
1280    .cfi_rel_offset lr, 12
1281    ldr   r3, [r0, #STRING_COUNT_OFFSET]
1282    ldr   r12, [r0, #STRING_OFFSET_OFFSET]
1283    ldr   r0, [r0, #STRING_VALUE_OFFSET]
1284
1285    /* Clamp start to [0..count] */
1286    cmp   r2, #0
1287    it    lt
1288    movlt r2, #0
1289    cmp   r2, r3
1290    it    gt
1291    movgt r2, r3
1292
1293    /* Build a pointer to the start of string data */
1294    add   r0, #STRING_DATA_OFFSET
1295    add   r0, r0, r12, lsl #1
1296
1297    /* Save a copy in r12 to later compute result */
1298    mov   r12, r0
1299
1300    /* Build pointer to start of data to compare and pre-bias */
1301    add   r0, r0, r2, lsl #1
1302    sub   r0, #2
1303
1304    /* Compute iteration count */
1305    sub   r2, r3, r2
1306
1307    /*
1308     * At this point we have:
1309     *   r0: start of data to test
1310     *   r1: char to compare
1311     *   r2: iteration count
1312     *   r12: original start of string data
1313     *   r3, r4, r10, r11 available for loading string data
1314     */
1315
1316    subs  r2, #4
1317    blt   .Lindexof_remainder
1318
1319.Lindexof_loop4:
1320    ldrh  r3, [r0, #2]!
1321    ldrh  r4, [r0, #2]!
1322    ldrh  r10, [r0, #2]!
1323    ldrh  r11, [r0, #2]!
1324    cmp   r3, r1
1325    beq   .Lmatch_0
1326    cmp   r4, r1
1327    beq   .Lmatch_1
1328    cmp   r10, r1
1329    beq   .Lmatch_2
1330    cmp   r11, r1
1331    beq   .Lmatch_3
1332    subs  r2, #4
1333    bge   .Lindexof_loop4
1334
1335.Lindexof_remainder:
1336    adds  r2, #4
1337    beq   .Lindexof_nomatch
1338
1339.Lindexof_loop1:
1340    ldrh  r3, [r0, #2]!
1341    cmp   r3, r1
1342    beq   .Lmatch_3
1343    subs  r2, #1
1344    bne   .Lindexof_loop1
1345
1346.Lindexof_nomatch:
1347    mov   r0, #-1
1348    pop {r4, r10-r11, pc}
1349
1350.Lmatch_0:
1351    sub   r0, #6
1352    sub   r0, r12
1353    asr   r0, r0, #1
1354    pop {r4, r10-r11, pc}
1355.Lmatch_1:
1356    sub   r0, #4
1357    sub   r0, r12
1358    asr   r0, r0, #1
1359    pop {r4, r10-r11, pc}
1360.Lmatch_2:
1361    sub   r0, #2
1362    sub   r0, r12
1363    asr   r0, r0, #1
1364    pop {r4, r10-r11, pc}
1365.Lmatch_3:
1366    sub   r0, r12
1367    asr   r0, r0, #1
1368    pop {r4, r10-r11, pc}
1369END art_quick_indexof
1370
1371   /*
1372     * String's compareTo.
1373     *
1374     * Requires rARG0/rARG1 to have been previously checked for null.  Will
1375     * return negative if this's string is < comp, 0 if they are the
1376     * same and positive if >.
1377     *
1378     * On entry:
1379     *    r0:   this object pointer
1380     *    r1:   comp object pointer
1381     *
1382     */
1383    .extern __memcmp16
1384ENTRY art_quick_string_compareto
1385    mov    r2, r0         @ this to r2, opening up r0 for return value
1386    sub    r0, r2, r1     @ Same?
1387    cbnz   r0,1f
1388    bx     lr
13891:                        @ Same strings, return.
1390
1391    push {r4, r7-r12, lr} @ 8 words - keep alignment
1392    .save {r4, r7-r12, lr}
1393    .cfi_adjust_cfa_offset 32
1394    .cfi_rel_offset r4, 0
1395    .cfi_rel_offset r7, 4
1396    .cfi_rel_offset r8, 8
1397    .cfi_rel_offset r9, 12
1398    .cfi_rel_offset r10, 16
1399    .cfi_rel_offset r11, 20
1400    .cfi_rel_offset r12, 24
1401    .cfi_rel_offset lr, 28
1402
1403    ldr    r4, [r2, #STRING_OFFSET_OFFSET]
1404    ldr    r9, [r1, #STRING_OFFSET_OFFSET]
1405    ldr    r7, [r2, #STRING_COUNT_OFFSET]
1406    ldr    r10, [r1, #STRING_COUNT_OFFSET]
1407    ldr    r2, [r2, #STRING_VALUE_OFFSET]
1408    ldr    r1, [r1, #STRING_VALUE_OFFSET]
1409
1410    /*
1411     * At this point, we have:
1412     *    value:  r2/r1
1413     *    offset: r4/r9
1414     *    count:  r7/r10
1415     * We're going to compute
1416     *    r11 <- countDiff
1417     *    r10 <- minCount
1418     */
1419     subs  r11, r7, r10
1420     it    ls
1421     movls r10, r7
1422
1423     /* Now, build pointers to the string data */
1424     add   r2, r2, r4, lsl #1
1425     add   r1, r1, r9, lsl #1
1426     /*
1427      * Note: data pointers point to previous element so we can use pre-index
1428      * mode with base writeback.
1429      */
1430     add   r2, #STRING_DATA_OFFSET-2   @ offset to contents[-1]
1431     add   r1, #STRING_DATA_OFFSET-2   @ offset to contents[-1]
1432
1433     /*
1434      * At this point we have:
1435      *   r2: *this string data
1436      *   r1: *comp string data
1437      *   r10: iteration count for comparison
1438      *   r11: value to return if the first part of the string is equal
1439      *   r0: reserved for result
1440      *   r3, r4, r7, r8, r9, r12 available for loading string data
1441      */
1442
1443    subs  r10, #2
1444    blt   .Ldo_remainder2
1445
1446      /*
1447       * Unroll the first two checks so we can quickly catch early mismatch
1448       * on long strings (but preserve incoming alignment)
1449       */
1450
1451    ldrh  r3, [r2, #2]!
1452    ldrh  r4, [r1, #2]!
1453    ldrh  r7, [r2, #2]!
1454    ldrh  r8, [r1, #2]!
1455    subs  r0, r3, r4
1456    it    eq
1457    subseq  r0, r7, r8
1458    bne   .Ldone
1459    cmp   r10, #28
1460    bgt   .Ldo_memcmp16
1461    subs  r10, #3
1462    blt   .Ldo_remainder
1463
1464.Lloopback_triple:
1465    ldrh  r3, [r2, #2]!
1466    ldrh  r4, [r1, #2]!
1467    ldrh  r7, [r2, #2]!
1468    ldrh  r8, [r1, #2]!
1469    ldrh  r9, [r2, #2]!
1470    ldrh  r12,[r1, #2]!
1471    subs  r0, r3, r4
1472    it    eq
1473    subseq  r0, r7, r8
1474    it    eq
1475    subseq  r0, r9, r12
1476    bne   .Ldone
1477    subs  r10, #3
1478    bge   .Lloopback_triple
1479
1480.Ldo_remainder:
1481    adds  r10, #3
1482    beq   .Lreturn_diff
1483
1484.Lloopback_single:
1485    ldrh  r3, [r2, #2]!
1486    ldrh  r4, [r1, #2]!
1487    subs  r0, r3, r4
1488    bne   .Ldone
1489    subs  r10, #1
1490    bne   .Lloopback_single
1491
1492.Lreturn_diff:
1493    mov   r0, r11
1494    pop   {r4, r7-r12, pc}
1495
1496.Ldo_remainder2:
1497    adds  r10, #2
1498    bne   .Lloopback_single
1499    mov   r0, r11
1500    pop   {r4, r7-r12, pc}
1501
1502    /* Long string case */
1503.Ldo_memcmp16:
1504    mov   r7, r11
1505    add   r0, r2, #2
1506    add   r1, r1, #2
1507    mov   r2, r10
1508    bl    __memcmp16
1509    cmp   r0, #0
1510    it    eq
1511    moveq r0, r7
1512.Ldone:
1513    pop   {r4, r7-r12, pc}
1514END art_quick_string_compareto
1515