__bionic_clone.S revision 40bc7cd4ed9fb848a7b3d934f69669f64ceed707 
1/*
2 * Copyright (C) 2008-2010 The Android Open Source Project
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions
7 * are met:
8 *  * Redistributions of source code must retain the above copyright
9 *    notice, this list of conditions and the following disclaimer.
10 *  * Redistributions in binary form must reproduce the above copyright
11 *    notice, this list of conditions and the following disclaimer in
12 *    the documentation and/or other materials provided with the
13 *    distribution.
14 *
15 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
16 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
17 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
18 * FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
19 * COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
20 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
21 * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS
22 * OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
23 * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
24 * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
25 * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
26 * SUCH DAMAGE.
27 */
28
29#include <private/bionic_asm.h>
30
31// pid_t __bionic_clone(int flags, void* child_stack, pid_t* parent_tid, void* tls, pid_t* child_tid, int (*fn)(void*), void* arg);
32ENTRY(__bionic_clone)
33    mov     ip, sp
34    .save   {r4, r5, r6, r7}
35    # save registers to parent stack
36    stmfd   sp!, {r4, r5, r6, r7}
37    .cfi_def_cfa_offset 16
38    .cfi_rel_offset r4, 0
39    .cfi_rel_offset r5, 4
40    .cfi_rel_offset r6, 8
41    .cfi_rel_offset r7, 12
42
43    # load extra parameters
44    ldmfd   ip, {r4, r5, r6}
45
46    # store 'fn' and 'arg' to the child stack
47    str     r5, [r1, #-4]
48    str     r6, [r1, #-8]
49
50    # System call
51    ldr     r7, =__NR_clone
52    swi     #0
53    movs    r0, r0
54    beq     1f
55
56    # In the parent, reload saved registers then either return or set errno.
57    ldmfd   sp!, {r4, r5, r6, r7}
58    .cfi_def_cfa_offset 0
59    cmn     r0, #(MAX_ERRNO + 1)
60    bxls    lr
61    neg     r0, r0
62    b       __set_errno
63
641:  # The child.
65    # Re-add the unwind directives that were reset from above.
66    .cfi_def_cfa_offset 16
67    .cfi_rel_offset r4, 0
68    .cfi_rel_offset r5, 4
69    .cfi_rel_offset r6, 8
70    .cfi_rel_offset r7, 12
71    ldr    r0, [sp, #-4]
72    ldr    r1, [sp, #-8]
73    b      __bionic_clone_entry
74END(__bionic_clone)
75