__bionic_clone.S revision 8df0fe0c74b7af819f36e37ec9b924fdd22c8ba4 
1/*
2 * Copyright (C) 2013 The Android Open Source Project
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions
7 * are met:
8 *  * Redistributions of source code must retain the above copyright
9 *    notice, this list of conditions and the following disclaimer.
10 *  * Redistributions in binary form must reproduce the above copyright
11 *    notice, this list of conditions and the following disclaimer in
12 *    the documentation and/or other materials provided with the
13 *    distribution.
14 *
15 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
16 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
17 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
18 * FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
19 * COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
20 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
21 * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS
22 * OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
23 * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
24 * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
25 * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
26 * SUCH DAMAGE.
27 */
28
29#include <private/bionic_asm.h>
30
31// pid_t __bionic_clone(int flags, void* child_stack, pid_t* parent_tid, void* tls, pid_t* child_tid, int (*fn)(void*), void* arg);
32
33ENTRY(__bionic_clone)
34    stp     x29, x30, [sp, #-16]!
35    .cfi_def_cfa_offset 16
36    .cfi_rel_offset x29, 0
37    .cfi_rel_offset x30, 8
38    mov     x29,  sp
39
40    # Copy 'fn' and 'arg' onto the child stack.
41    stp     x5, x6, [x1, #-16]
42
43    # Make the system call.
44    mov     x8, __NR_clone
45    svc     #0
46
47    # Are we the child?
48    cbz     x0, .L_bc_child
49
50    ldp     x29, x30, [sp], #16
51    .cfi_def_cfa_offset 0
52    .cfi_restore x29
53    .cfi_restore x30
54
55    # Set errno if something went wrong.
56    cmn     x0, #(MAX_ERRNO + 1)
57    cneg    x0, x0, hi
58    b.hi    __set_errno
59
60    ret
61
62.L_bc_child:
63    # We're in the child now. Set the end of the frame record chain...
64    mov     x29, xzr
65    # Setting x30 to 0 will make the unwinder stop at __bionic_clone_entry
66    mov     x30, xzr
67    # ...and call __bionic_clone_entry with the 'fn' and 'arg' we stored on the child stack.
68    ldp     x0, x1, [sp, #-16]
69    b       __bionic_clone_entry
70END(__bionic_clone)
71.hidden __bionic_clone
72