setjmp.S revision 43227c0b400a33dc9722269beda26313c391fb1e 
1/*	$OpenBSD: setjmp.S,v 1.3 2012/08/22 17:19:34 pascal Exp $	*/
2/*	$NetBSD: __setjmp14.S,v 1.1 2001/06/19 00:25:02 fvdl Exp $	*/
3
4/*
5 * Copyright (c) 2001 Wasabi Systems, Inc.
6 * All rights reserved.
7 *
8 * Written by Frank van der Linden for Wasabi Systems, Inc.
9 *
10 * Redistribution and use in source and binary forms, with or without
11 * modification, are permitted provided that the following conditions
12 * are met:
13 * 1. Redistributions of source code must retain the above copyright
14 *    notice, this list of conditions and the following disclaimer.
15 * 2. Redistributions in binary form must reproduce the above copyright
16 *    notice, this list of conditions and the following disclaimer in the
17 *    documentation and/or other materials provided with the distribution.
18 * 3. All advertising materials mentioning features or use of this software
19 *    must display the following acknowledgement:
20 *      This product includes software developed for the NetBSD Project by
21 *      Wasabi Systems, Inc.
22 * 4. The name of Wasabi Systems, Inc. may not be used to endorse
23 *    or promote products derived from this software without specific prior
24 *    written permission.
25 *
26 * THIS SOFTWARE IS PROVIDED BY WASABI SYSTEMS, INC. ``AS IS'' AND
27 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
28 * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
29 * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL WASABI SYSTEMS, INC
30 * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
31 * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
32 * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
33 * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
34 * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
35 * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
36 * POSSIBILITY OF SUCH DAMAGE.
37 */
38
39#include <private/bionic_asm.h>
40#include <machine/setjmp.h>
41
42/*
43 * C library -- _setjmp, _longjmp
44 *
45 *	longjmp(a,v)
46 * will generate a "return(v)" from the last call to
47 *	setjmp(a)
48 * by restoring registers from the stack.
49 * The previous signal state is restored.
50 */
51
52ENTRY(setjmp)
53	pushq	%rdi
54	xorq	%rdi,%rdi
55	call	PIC_PLT(sigblock)
56	popq	%rdi
57	movq	%rax,(_JB_SIGMASK * 8)(%rdi)
58
59	movq	(%rsp),%r11
60	movq	%rbx,(_JB_RBX * 8)(%rdi)
61	movq	%rbp,(_JB_RBP * 8)(%rdi)
62	movq	%r12,(_JB_R12 * 8)(%rdi)
63	movq	%r13,(_JB_R13 * 8)(%rdi)
64	movq	%r14,(_JB_R14 * 8)(%rdi)
65	movq	%r15,(_JB_R15 * 8)(%rdi)
66	movq	%rsp,(_JB_RSP * 8)(%rdi)
67	movq	%r11,(_JB_PC  * 8)(%rdi)
68
692:	xorl	%eax,%eax
70	ret
71END(setjmp)
72
73ENTRY(longjmp)
74	movq	%rdi,%r12
75	movl	%esi,%r8d
76
77	movq	(_JB_SIGMASK * 8)(%rdi),%rdi
78	pushq	%r8
79	call	PIC_PLT(sigsetmask)
80	popq	%r8
81	movq	(_JB_RBX * 8)(%r12),%rbx
82	movq	(_JB_RBP * 8)(%r12),%rbp
83	movq	(_JB_R13 * 8)(%r12),%r13
84	movq	(_JB_R14 * 8)(%r12),%r14
85	movq	(_JB_R15 * 8)(%r12),%r15
86	movq	(_JB_RSP * 8)(%r12),%rsp
87	movq	(_JB_PC  * 8)(%r12),%r11
88	movq	(_JB_R12 * 8)(%r12),%r12
89
90	movl	%r8d,%eax
91	testl	%eax,%eax
92	jnz	1f
93	incl	%eax
941:	movq	%r11,0(%rsp)
95	ret
96END(longjmp)
97