memset.S revision 5f7ccea3ffab05aeceecb85c821003cf580630d3 
1/*
2 * Copyright (C) 2008 The Android Open Source Project
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions
7 * are met:
8 *  * Redistributions of source code must retain the above copyright
9 *    notice, this list of conditions and the following disclaimer.
10 *  * Redistributions in binary form must reproduce the above copyright
11 *    notice, this list of conditions and the following disclaimer in
12 *    the documentation and/or other materials provided with the
13 *    distribution.
14 *
15 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
16 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
17 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
18 * FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
19 * COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
20 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
21 * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS
22 * OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
23 * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
24 * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
25 * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
26 * SUCH DAMAGE.
27 */
28
29#include <machine/cpu-features.h>
30#include <machine/asm.h>
31#include "libc_events.h"
32
33/*
34 * This code assumes it is running on a processor that supports all arm v7
35 * instructions, that supports neon instructions, and that supports
36 * unaligned neon instruction accesses to memory.
37 */
38
39    .fpu    neon
40
41ENTRY(__memset_chk)
42        .cfi_startproc
43        cmp         r2, r3
44        bls         .L_done
45
46        // Preserve lr for backtrace.
47        .save       {lr}
48        push        {lr}
49        .cfi_def_cfa_offset 4
50        .cfi_rel_offset lr, 0
51
52        ldr         r0, error_message
53        ldr         r1, error_code
541:
55        add         r0, pc
56        bl          __fortify_chk_fail
57error_code:
58        .word       BIONIC_EVENT_MEMSET_BUFFER_OVERFLOW
59error_message:
60        .word       error_string-(1b+8)
61
62        .cfi_endproc
63END(__memset_chk)
64
65ENTRY(bzero)
66        .cfi_startproc
67        mov     r2, r1
68        mov     r1, #0
69
70.L_done:
71        // Fall through to memset...
72        .cfi_endproc
73END(bzero)
74
75/* memset() returns its first argument.  */
76ENTRY(memset)
77        .cfi_startproc
78        .save       {r0}
79        stmfd       sp!, {r0}
80        .cfi_def_cfa_offset 4
81        .cfi_rel_offset r0, 0
82
83        vdup.8      q0, r1
84
85        /* make sure we have at least 32 bytes to write */
86        subs        r2, r2, #32
87        blo         2f
88        vmov        q1, q0
89
901:      /* The main loop writes 32 bytes at a time */
91        subs        r2, r2, #32
92        vst1.8      {d0 - d3}, [r0]!
93        bhs         1b
94
952:      /* less than 32 left */
96        add         r2, r2, #32
97        tst         r2, #0x10
98        beq         3f
99
100        // writes 16 bytes, 128-bits aligned
101        vst1.8      {d0, d1}, [r0]!
1023:      /* write up to 15-bytes (count in r2) */
103        movs        ip, r2, lsl #29
104        bcc         1f
105        vst1.8      {d0}, [r0]!
1061:      bge         2f
107        vst1.32     {d0[0]}, [r0]!
1082:      movs        ip, r2, lsl #31
109        strmib      r1, [r0], #1
110        strcsb      r1, [r0], #1
111        strcsb      r1, [r0], #1
112        ldmfd       sp!, {r0}
113        bx          lr
114        .cfi_endproc
115END(memset)
116
117        .data
118error_string:
119        .string     "memset buffer overflow"
120