1# Copyright 2014 The Chromium Authors. All rights reserved.
2# Use of this source code is governed by a BSD-style license that can be
3# found in the LICENSE file.
4
5import("//third_party/WebKit/Source/bindings/bindings.gni")
6import("//third_party/WebKit/Source/core/core.gni")
7
8visibility = [ "//third_party/WebKit/Source/*" ]
9
10protocol_file = "../../devtools/protocol.json"
11
12action("protocol_sources") {
13  script = "CodeGeneratorInspector.py"
14
15  inputs = [
16    # The helper script imported by CodeGeneratorInspector.py.
17    "CodeGeneratorInspectorStrings.py",
18    protocol_file,
19  ]
20  outputs = [
21    "$blink_core_output_dir/InspectorBackendDispatcher.cpp",
22    "$blink_core_output_dir/InspectorBackendDispatcher.h",
23    "$blink_core_output_dir/InspectorFrontend.cpp",
24    "$blink_core_output_dir/InspectorFrontend.h",
25    "$blink_core_output_dir/InspectorTypeBuilder.cpp",
26    "$blink_core_output_dir/InspectorTypeBuilder.h",
27  ]
28
29  args = [
30    rebase_path(protocol_file, root_build_dir),
31    "--output_dir", rebase_path(blink_core_output_dir, root_build_dir),
32  ]
33
34  deps = [
35    ":protocol_version",
36  ]
37}
38
39action("instrumentation_sources") {
40  script = "CodeGeneratorInstrumentation.py"
41
42  inputs = [
43    # Input file for the script.
44    "InspectorInstrumentation.idl",
45  ]
46
47  outputs = [
48    "$blink_core_output_dir/InspectorCanvasInstrumentationInl.h",
49    "$blink_core_output_dir/InspectorConsoleInstrumentationInl.h",
50    "$blink_core_output_dir/InspectorInstrumentationInl.h",
51    "$blink_core_output_dir/InspectorOverridesInl.h",
52    "$blink_core_output_dir/InstrumentingAgentsInl.h",
53    "$blink_core_output_dir/InspectorInstrumentationImpl.cpp",
54  ]
55
56  args = [
57    rebase_path("InspectorInstrumentation.idl", root_build_dir),
58    "--output_dir", rebase_path(blink_core_output_dir, root_build_dir),
59  ]
60}
61
62action("protocol_version") {
63  script = "generate-inspector-protocol-version"
64
65  inputs = [ protocol_file ]
66  output_file = "$blink_core_output_dir/InspectorProtocolVersion.h"
67  outputs = [ output_file ]
68
69  args = [
70    "-o", rebase_path(output_file, root_build_dir),
71    rebase_path(protocol_file, root_build_dir),
72  ]
73}
74