configure.ac revision c4edfa63eda06f02cc5bc1a65d366c55bd2eda30 
1
2AC_INIT([iptables], [1.4.3.1])
3
4# See libtool.info "Libtool's versioning system"
5libxtables_vcurrent=2
6libxtables_vage=0
7
8AC_CONFIG_HEADERS([config.h])
9AC_CONFIG_MACRO_DIR([m4])
10AC_PROG_INSTALL
11AM_INIT_AUTOMAKE([-Wall])
12AC_PROG_CC
13AM_PROG_CC_C_O
14AC_DISABLE_STATIC
15AM_PROG_LIBTOOL
16
17AC_ARG_WITH([kernel],
18	AS_HELP_STRING([--with-kernel=PATH],
19	[Path to kernel source/build directory]),
20	[kbuilddir="$withval"; ksourcedir="$withval";])
21AC_ARG_WITH([kbuild],
22	AS_HELP_STRING([--with-kbuild=PATH],
23	[Path to kernel build directory [[/lib/modules/CURRENT/build]]]),
24	[kbuilddir="$withval"])
25AC_ARG_WITH([ksource],
26	AS_HELP_STRING([--with-ksource=PATH],
27	[Path to kernel source directory [[/lib/modules/CURRENT/source]]]),
28	[ksourcedir="$withval"])
29AC_ARG_WITH([xtlibdir],
30	AS_HELP_STRING([--with-xtlibdir=PATH],
31	[Path where to install Xtables extensions [[LIBEXECDIR/xtables]]]),
32	[xtlibdir="$withval"],
33	[xtlibdir="${libexecdir}/xtables"])
34AC_ARG_ENABLE([devel],
35	AS_HELP_STRING([--enable-devel],
36	[Install Xtables development headers]),
37	[enable_devel="$enableval"], [enable_devel="yes"])
38AC_ARG_ENABLE([libipq],
39	AS_HELP_STRING([--enable-libipq], [Build and install libipq]))
40AC_ARG_WITH([pkgconfigdir], AS_HELP_STRING([--with-pkgconfigdir=PATH],
41	[Path to the pkgconfig directory [[LIBDIR/pkgconfig]]]),
42	[pkgconfigdir="$withval"], [pkgconfigdir='${libdir}/pkgconfig'])
43
44AC_CHECK_HEADER([linux/dccp.h])
45
46blacklist_modules="";
47if test "$ac_cv_header_linux_dccp_h" != "yes"; then
48	blacklist_modules="$blacklist_modules dccp";
49fi;
50AC_SUBST([blacklist_modules])
51
52AM_CONDITIONAL([ENABLE_STATIC], [test "$enable_static" = "yes"])
53AM_CONDITIONAL([ENABLE_SHARED], [test "$enable_shared" = "yes"])
54AM_CONDITIONAL([ENABLE_DEVEL], [test "$enable_devel" = "yes"])
55AM_CONDITIONAL([ENABLE_LIBIPQ], [test "$enable_libipq" = "yes"])
56
57regular_CFLAGS="-D_LARGEFILE_SOURCE=1 -D_LARGE_FILES -D_FILE_OFFSET_BITS=64 \
58	-D_REENTRANT -Wall -Waggregate-return -Wmissing-declarations \
59	-Wmissing-prototypes -Wredundant-decls -Wshadow -Wstrict-prototypes \
60	-Winline -pipe \
61	-DXTABLES_LIBDIR=\\\"\${xtlibdir}\\\" -DXTABLES_INTERNAL";
62kinclude_CFLAGS="";
63if [[ -n "$kbuilddir" ]]; then
64	kinclude_CFLAGS="$kinclude_CFLAGS -I $kbuilddir/include";
65fi;
66if [[ -n "$ksourcedir" ]]; then
67	kinclude_CFLAGS="$kinclude_CFLAGS -I $ksourcedir/include";
68fi;
69
70AC_SUBST([regular_CFLAGS])
71AC_SUBST([kinclude_CFLAGS])
72AC_SUBST([kbuilddir])
73AC_SUBST([ksourcedir])
74AC_SUBST([xtlibdir])
75AC_SUBST([pkgconfigdir])
76AC_SUBST([libxtables_vcurrent])
77AC_SUBST([libxtables_vage])
78libxtables_vmajor=$(($libxtables_vcurrent - $libxtables_vage));
79AC_SUBST([libxtables_vmajor])
80
81AC_CONFIG_FILES([Makefile extensions/GNUmakefile include/Makefile
82	libipq/Makefile
83	include/xtables.h include/iptables/internal.h libiptc.pc xtables.pc])
84AC_OUTPUT
85