MipsInstrFormats.td revision e4bf77a1282bfdacb61bae192fdf79a696be780a 
1//===-- MipsInstrFormats.td - Mips Instruction Formats -----*- tablegen -*-===//
2//
3//                     The LLVM Compiler Infrastructure
4//
5// This file is distributed under the University of Illinois Open Source
6// License. See LICENSE.TXT for details.
7//
8//===----------------------------------------------------------------------===//
9
10//===----------------------------------------------------------------------===//
11//  Describe MIPS instructions format
12//
13//  CPU INSTRUCTION FORMATS
14//
15//  opcode  - operation code.
16//  rs      - src reg.
17//  rt      - dst reg (on a 2 regs instr) or src reg (on a 3 reg instr).
18//  rd      - dst reg, only used on 3 regs instr.
19//  shamt   - only used on shift instructions, contains the shift amount.
20//  funct   - combined with opcode field give us an operation code.
21//
22//===----------------------------------------------------------------------===//
23
24// Format specifies the encoding used by the instruction.  This is part of the
25// ad-hoc solution used to emit machine instruction encodings by our machine
26// code emitter.
27class Format<bits<4> val> {
28  bits<4> Value = val;
29}
30
31def Pseudo    : Format<0>;
32def FrmR      : Format<1>;
33def FrmI      : Format<2>;
34def FrmJ      : Format<3>;
35def FrmFR     : Format<4>;
36def FrmFI     : Format<5>;
37def FrmOther  : Format<6>; // Instruction w/ a custom format
38
39class MMRel;
40
41def Std2MicroMips : InstrMapping {
42  let FilterClass = "MMRel";
43  // Instructions with the same BaseOpcode and isNVStore values form a row.
44  let RowFields = ["BaseOpcode"];
45  // Instructions with the same predicate sense form a column.
46  let ColFields = ["Arch"];
47  // The key column is the unpredicated instructions.
48  let KeyCol = ["se"];
49  // Value columns are PredSense=true and PredSense=false
50  let ValueCols = [["se"], ["micromips"]];
51}
52
53class StdArch {
54  string Arch = "se";
55}
56
57// Generic Mips Format
58class MipsInst<dag outs, dag ins, string asmstr, list<dag> pattern,
59               InstrItinClass itin, Format f>: Instruction
60{
61  field bits<32> Inst;
62  Format Form = f;
63
64  let Namespace = "Mips";
65
66  let Size = 4;
67
68  bits<6> Opcode = 0;
69
70  // Top 6 bits are the 'opcode' field
71  let Inst{31-26} = Opcode;
72
73  let OutOperandList = outs;
74  let InOperandList  = ins;
75
76  let AsmString   = asmstr;
77  let Pattern     = pattern;
78  let Itinerary   = itin;
79
80  //
81  // Attributes specific to Mips instructions...
82  //
83  bits<4> FormBits = Form.Value;
84
85  // TSFlags layout should be kept in sync with MipsInstrInfo.h.
86  let TSFlags{3-0}   = FormBits;
87
88  let DecoderNamespace = "Mips";
89
90  field bits<32> SoftFail = 0;
91}
92
93// Mips32/64 Instruction Format
94class InstSE<dag outs, dag ins, string asmstr, list<dag> pattern,
95             InstrItinClass itin, Format f, string opstr = ""> :
96  MipsInst<outs, ins, asmstr, pattern, itin, f> {
97  let Predicates = [HasStdEnc];
98  string BaseOpcode = opstr;
99  string Arch;
100}
101
102// Mips Pseudo Instructions Format
103class MipsPseudo<dag outs, dag ins, list<dag> pattern,
104                 InstrItinClass itin = IIPseudo> :
105  MipsInst<outs, ins, "", pattern, itin, Pseudo> {
106  let isCodeGenOnly = 1;
107  let isPseudo = 1;
108}
109
110// Mips32/64 Pseudo Instruction Format
111class PseudoSE<dag outs, dag ins, list<dag> pattern,
112               InstrItinClass itin = IIPseudo>:
113  MipsPseudo<outs, ins, pattern, itin> {
114  let Predicates = [HasStdEnc];
115}
116
117// Pseudo-instructions for alternate assembly syntax (never used by codegen).
118// These are aliases that require C++ handling to convert to the target
119// instruction, while InstAliases can be handled directly by tblgen.
120class MipsAsmPseudoInst<dag outs, dag ins, string asmstr>:
121  MipsInst<outs, ins, asmstr, [], IIPseudo, Pseudo> {
122  let isPseudo = 1;
123  let Pattern = [];
124}
125//===----------------------------------------------------------------------===//
126// Format R instruction class in Mips : <|opcode|rs|rt|rd|shamt|funct|>
127//===----------------------------------------------------------------------===//
128
129class FR<bits<6> op, bits<6> _funct, dag outs, dag ins, string asmstr,
130         list<dag> pattern, InstrItinClass itin>:
131  InstSE<outs, ins, asmstr, pattern, itin, FrmR>
132{
133  bits<5>  rd;
134  bits<5>  rs;
135  bits<5>  rt;
136  bits<5>  shamt;
137  bits<6>  funct;
138
139  let Opcode = op;
140  let funct  = _funct;
141
142  let Inst{25-21} = rs;
143  let Inst{20-16} = rt;
144  let Inst{15-11} = rd;
145  let Inst{10-6}  = shamt;
146  let Inst{5-0}   = funct;
147}
148
149//===----------------------------------------------------------------------===//
150// Format I instruction class in Mips : <|opcode|rs|rt|immediate|>
151//===----------------------------------------------------------------------===//
152
153class FI<bits<6> op, dag outs, dag ins, string asmstr, list<dag> pattern,
154         InstrItinClass itin>: InstSE<outs, ins, asmstr, pattern, itin, FrmI>
155{
156  bits<5>  rt;
157  bits<5>  rs;
158  bits<16> imm16;
159
160  let Opcode = op;
161
162  let Inst{25-21} = rs;
163  let Inst{20-16} = rt;
164  let Inst{15-0}  = imm16;
165}
166
167class BranchBase<bits<6> op, dag outs, dag ins, string asmstr,
168                  list<dag> pattern, InstrItinClass itin>:
169  InstSE<outs, ins, asmstr, pattern, itin, FrmI>
170{
171  bits<5>  rs;
172  bits<5>  rt;
173  bits<16> imm16;
174
175  let Opcode = op;
176
177  let Inst{25-21} = rs;
178  let Inst{20-16} = rt;
179  let Inst{15-0}  = imm16;
180}
181
182//===----------------------------------------------------------------------===//
183// Format J instruction class in Mips : <|opcode|address|>
184//===----------------------------------------------------------------------===//
185
186class FJ<bits<6> op>
187{
188  bits<26> target;
189
190  bits<32> Inst;
191
192  let Inst{31-26} = op;
193  let Inst{25-0}  = target;
194}
195
196//===----------------------------------------------------------------------===//
197// MFC instruction class in Mips : <|op|mf|rt|rd|0000000|sel|>
198//===----------------------------------------------------------------------===//
199class MFC3OP_FM<bits<6> op, bits<5> mfmt>
200{
201  bits<5> rt;
202  bits<5> rd;
203  bits<3> sel;
204
205  bits<32> Inst;
206
207  let Inst{31-26} = op;
208  let Inst{25-21} = mfmt;
209  let Inst{20-16} = rt;
210  let Inst{15-11} = rd;
211  let Inst{10-3}  = 0;
212  let Inst{2-0}   = sel;
213}
214
215class ADD_FM<bits<6> op, bits<6> funct> : StdArch {
216  bits<5> rd;
217  bits<5> rs;
218  bits<5> rt;
219
220  bits<32> Inst;
221
222  let Inst{31-26} = op;
223  let Inst{25-21} = rs;
224  let Inst{20-16} = rt;
225  let Inst{15-11} = rd;
226  let Inst{10-6}  = 0;
227  let Inst{5-0}   = funct;
228}
229
230class ADDI_FM<bits<6> op> : StdArch {
231  bits<5>  rs;
232  bits<5>  rt;
233  bits<16> imm16;
234
235  bits<32> Inst;
236
237  let Inst{31-26} = op;
238  let Inst{25-21} = rs;
239  let Inst{20-16} = rt;
240  let Inst{15-0}  = imm16;
241}
242
243class SRA_FM<bits<6> funct, bit rotate> : StdArch {
244  bits<5> rd;
245  bits<5> rt;
246  bits<5> shamt;
247
248  bits<32> Inst;
249
250  let Inst{31-26} = 0;
251  let Inst{25-22} = 0;
252  let Inst{21}    = rotate;
253  let Inst{20-16} = rt;
254  let Inst{15-11} = rd;
255  let Inst{10-6}  = shamt;
256  let Inst{5-0}   = funct;
257}
258
259class SRLV_FM<bits<6> funct, bit rotate> : StdArch {
260  bits<5> rd;
261  bits<5> rt;
262  bits<5> rs;
263
264  bits<32> Inst;
265
266  let Inst{31-26} = 0;
267  let Inst{25-21} = rs;
268  let Inst{20-16} = rt;
269  let Inst{15-11} = rd;
270  let Inst{10-7}  = 0;
271  let Inst{6}     = rotate;
272  let Inst{5-0}   = funct;
273}
274
275class BEQ_FM<bits<6> op> {
276  bits<5>  rs;
277  bits<5>  rt;
278  bits<16> offset;
279
280  bits<32> Inst;
281
282  let Inst{31-26} = op;
283  let Inst{25-21} = rs;
284  let Inst{20-16} = rt;
285  let Inst{15-0}  = offset;
286}
287
288class BGEZ_FM<bits<6> op, bits<5> funct> {
289  bits<5>  rs;
290  bits<16> offset;
291
292  bits<32> Inst;
293
294  let Inst{31-26} = op;
295  let Inst{25-21} = rs;
296  let Inst{20-16} = funct;
297  let Inst{15-0}  = offset;
298}
299
300class B_FM {
301  bits<16> offset;
302
303  bits<32> Inst;
304
305  let Inst{31-26} = 4;
306  let Inst{25-21} = 0;
307  let Inst{20-16} = 0;
308  let Inst{15-0}  = offset;
309}
310
311class SLTI_FM<bits<6> op> : StdArch {
312  bits<5> rt;
313  bits<5> rs;
314  bits<16> imm16;
315
316  bits<32> Inst;
317
318  let Inst{31-26} = op;
319  let Inst{25-21} = rs;
320  let Inst{20-16} = rt;
321  let Inst{15-0}  = imm16;
322}
323
324class MFLO_FM<bits<6> funct> {
325  bits<5> rd;
326
327  bits<32> Inst;
328
329  let Inst{31-26} = 0;
330  let Inst{25-16} = 0;
331  let Inst{15-11} = rd;
332  let Inst{10-6}  = 0;
333  let Inst{5-0}   = funct;
334}
335
336class MTLO_FM<bits<6> funct> {
337  bits<5> rs;
338
339  bits<32> Inst;
340
341  let Inst{31-26} = 0;
342  let Inst{25-21} = rs;
343  let Inst{20-6}  = 0;
344  let Inst{5-0}   = funct;
345}
346
347class SEB_FM<bits<5> funct, bits<6> funct2> {
348  bits<5> rd;
349  bits<5> rt;
350
351  bits<32> Inst;
352
353  let Inst{31-26} = 0x1f;
354  let Inst{25-21} = 0;
355  let Inst{20-16} = rt;
356  let Inst{15-11} = rd;
357  let Inst{10-6}  = funct;
358  let Inst{5-0}   = funct2;
359}
360
361class CLO_FM<bits<6> funct> {
362  bits<5> rd;
363  bits<5> rs;
364  bits<5> rt;
365
366  bits<32> Inst;
367
368  let Inst{31-26} = 0x1c;
369  let Inst{25-21} = rs;
370  let Inst{20-16} = rt;
371  let Inst{15-11} = rd;
372  let Inst{10-6}  = 0;
373  let Inst{5-0}   = funct;
374  let rt = rd;
375}
376
377class LUI_FM {
378  bits<5> rt;
379  bits<16> imm16;
380
381  bits<32> Inst;
382
383  let Inst{31-26} = 0xf;
384  let Inst{25-21} = 0;
385  let Inst{20-16} = rt;
386  let Inst{15-0}  = imm16;
387}
388
389class JALR_FM {
390  bits<5> rd;
391  bits<5> rs;
392
393  bits<32> Inst;
394
395  let Inst{31-26} = 0;
396  let Inst{25-21} = rs;
397  let Inst{20-16} = 0;
398  let Inst{15-11} = rd;
399  let Inst{10-6}  = 0;
400  let Inst{5-0}   = 9;
401}
402
403class BGEZAL_FM<bits<5> funct> {
404  bits<5>  rs;
405  bits<16> offset;
406
407  bits<32> Inst;
408
409  let Inst{31-26} = 1;
410  let Inst{25-21} = rs;
411  let Inst{20-16} = funct;
412  let Inst{15-0}  = offset;
413}
414
415class SYNC_FM {
416  bits<5> stype;
417
418  bits<32> Inst;
419
420  let Inst{31-26} = 0;
421  let Inst{10-6}  = stype;
422  let Inst{5-0}   = 0xf;
423}
424
425class MULT_FM<bits<6> op, bits<6> funct> : StdArch {
426  bits<5>  rs;
427  bits<5>  rt;
428
429  bits<32> Inst;
430
431  let Inst{31-26} = op;
432  let Inst{25-21} = rs;
433  let Inst{20-16} = rt;
434  let Inst{15-6}  = 0;
435  let Inst{5-0}   = funct;
436}
437
438class EXT_FM<bits<6> funct> {
439  bits<5> rt;
440  bits<5> rs;
441  bits<5> pos;
442  bits<5> size;
443
444  bits<32> Inst;
445
446  let Inst{31-26} = 0x1f;
447  let Inst{25-21} = rs;
448  let Inst{20-16} = rt;
449  let Inst{15-11} = size;
450  let Inst{10-6}  = pos;
451  let Inst{5-0}   = funct;
452}
453
454class RDHWR_FM {
455  bits<5> rt;
456  bits<5> rd;
457
458  bits<32> Inst;
459
460  let Inst{31-26} = 0x1f;
461  let Inst{25-21} = 0;
462  let Inst{20-16} = rt;
463  let Inst{15-11} = rd;
464  let Inst{10-6}  = 0;
465  let Inst{5-0}   = 0x3b;
466}
467
468class TEQ_FM<bits<6> funct> {
469  bits<5> rs;
470  bits<5> rt;
471  bits<10> code_;
472
473  bits<32> Inst;
474
475  let Inst{31-26} = 0;
476  let Inst{25-21} = rs;
477  let Inst{20-16} = rt;
478  let Inst{15-6}  = code_;
479  let Inst{5-0}   = funct;
480}
481
482class TEQI_FM<bits<5> funct> {
483  bits<5> rs;
484  bits<16> imm16;
485
486  bits<32> Inst;
487
488  let Inst{31-26} = 1;
489  let Inst{25-21} = rs;
490  let Inst{20-16}   = funct;
491  let Inst{15-0}  = imm16;
492}
493//===----------------------------------------------------------------------===//
494//  System calls format <op|code_|funct>
495//===----------------------------------------------------------------------===//
496
497class SYS_FM<bits<6> funct>
498{
499  bits<20> code_;
500  bits<32> Inst;
501  let Inst{31-26} = 0x0;
502  let Inst{25-6} = code_;
503  let Inst{5-0}  = funct;
504}
505
506//===----------------------------------------------------------------------===//
507//  Break instruction format <op|code_1|funct>
508//===----------------------------------------------------------------------===//
509
510class BRK_FM<bits<6> funct>
511{
512  bits<10> code_1;
513  bits<10> code_2;
514  bits<32> Inst;
515  let Inst{31-26} = 0x0;
516  let Inst{25-16} = code_1;
517  let Inst{15-6}  = code_2;
518  let Inst{5-0}   = funct;
519}
520
521//===----------------------------------------------------------------------===//
522//  Exception return format <Cop0|1|0|funct>
523//===----------------------------------------------------------------------===//
524
525class ER_FM<bits<6> funct>
526{
527  bits<32> Inst;
528  let Inst{31-26} = 0x10;
529  let Inst{25}    = 1;
530  let Inst{24-6}  = 0;
531  let Inst{5-0}   = funct;
532}
533
534
535//===----------------------------------------------------------------------===//
536//  Enable/disable interrupt instruction format <Cop0|MFMC0|rt|12|0|sc|0|0>
537//===----------------------------------------------------------------------===//
538
539class EI_FM<bits<1> sc>
540{
541  bits<32> Inst;
542  bits<5> rt;
543  let Inst{31-26} = 0x10;
544  let Inst{25-21} = 0xb;
545  let Inst{20-16} = rt;
546  let Inst{15-11} = 0xc;
547  let Inst{10-6}  = 0;
548  let Inst{5}     = sc;
549  let Inst{4-0}   = 0;
550}
551
552//===----------------------------------------------------------------------===//
553//
554//  FLOATING POINT INSTRUCTION FORMATS
555//
556//  opcode  - operation code.
557//  fs      - src reg.
558//  ft      - dst reg (on a 2 regs instr) or src reg (on a 3 reg instr).
559//  fd      - dst reg, only used on 3 regs instr.
560//  fmt     - double or single precision.
561//  funct   - combined with opcode field give us an operation code.
562//
563//===----------------------------------------------------------------------===//
564
565//===----------------------------------------------------------------------===//
566// Format FI instruction class in Mips : <|opcode|base|ft|immediate|>
567//===----------------------------------------------------------------------===//
568
569class FFI<bits<6> op, dag outs, dag ins, string asmstr, list<dag> pattern>:
570  InstSE<outs, ins, asmstr, pattern, NoItinerary, FrmFI>
571{
572  bits<5>  ft;
573  bits<5>  base;
574  bits<16> imm16;
575
576  let Opcode = op;
577
578  let Inst{25-21} = base;
579  let Inst{20-16} = ft;
580  let Inst{15-0}  = imm16;
581}
582
583class ADDS_FM<bits<6> funct, bits<5> fmt> {
584  bits<5> fd;
585  bits<5> fs;
586  bits<5> ft;
587
588  bits<32> Inst;
589
590  let Inst{31-26} = 0x11;
591  let Inst{25-21} = fmt;
592  let Inst{20-16} = ft;
593  let Inst{15-11} = fs;
594  let Inst{10-6}  = fd;
595  let Inst{5-0}   = funct;
596}
597
598class ABSS_FM<bits<6> funct, bits<5> fmt> {
599  bits<5> fd;
600  bits<5> fs;
601
602  bits<32> Inst;
603
604  let Inst{31-26} = 0x11;
605  let Inst{25-21} = fmt;
606  let Inst{20-16} = 0;
607  let Inst{15-11} = fs;
608  let Inst{10-6}  = fd;
609  let Inst{5-0}   = funct;
610}
611
612class MFC1_FM<bits<5> funct> {
613  bits<5> rt;
614  bits<5> fs;
615
616  bits<32> Inst;
617
618  let Inst{31-26} = 0x11;
619  let Inst{25-21} = funct;
620  let Inst{20-16} = rt;
621  let Inst{15-11} = fs;
622  let Inst{10-0}  = 0;
623}
624
625class LW_FM<bits<6> op> : StdArch {
626  bits<5> rt;
627  bits<21> addr;
628
629  bits<32> Inst;
630
631  let Inst{31-26} = op;
632  let Inst{25-21} = addr{20-16};
633  let Inst{20-16} = rt;
634  let Inst{15-0}  = addr{15-0};
635}
636
637class MADDS_FM<bits<3> funct, bits<3> fmt> {
638  bits<5> fd;
639  bits<5> fr;
640  bits<5> fs;
641  bits<5> ft;
642
643  bits<32> Inst;
644
645  let Inst{31-26} = 0x13;
646  let Inst{25-21} = fr;
647  let Inst{20-16} = ft;
648  let Inst{15-11} = fs;
649  let Inst{10-6}  = fd;
650  let Inst{5-3}   = funct;
651  let Inst{2-0}   = fmt;
652}
653
654class LWXC1_FM<bits<6> funct> {
655  bits<5> fd;
656  bits<5> base;
657  bits<5> index;
658
659  bits<32> Inst;
660
661  let Inst{31-26} = 0x13;
662  let Inst{25-21} = base;
663  let Inst{20-16} = index;
664  let Inst{15-11} = 0;
665  let Inst{10-6}  = fd;
666  let Inst{5-0}   = funct;
667}
668
669class SWXC1_FM<bits<6> funct> {
670  bits<5> fs;
671  bits<5> base;
672  bits<5> index;
673
674  bits<32> Inst;
675
676  let Inst{31-26} = 0x13;
677  let Inst{25-21} = base;
678  let Inst{20-16} = index;
679  let Inst{15-11} = fs;
680  let Inst{10-6}  = 0;
681  let Inst{5-0}   = funct;
682}
683
684class BC1F_FM<bit nd, bit tf> {
685  bits<3>  fcc;
686  bits<16> offset;
687
688  bits<32> Inst;
689
690  let Inst{31-26} = 0x11;
691  let Inst{25-21} = 0x8;
692  let Inst{20-18} = fcc;
693  let Inst{17} = nd;
694  let Inst{16} = tf;
695  let Inst{15-0} = offset;
696}
697
698class CEQS_FM<bits<5> fmt> {
699  bits<5> fs;
700  bits<5> ft;
701  bits<4> cond;
702
703  bits<32> Inst;
704
705  let Inst{31-26} = 0x11;
706  let Inst{25-21} = fmt;
707  let Inst{20-16} = ft;
708  let Inst{15-11} = fs;
709  let Inst{10-8} = 0; // cc
710  let Inst{7-4} = 0x3;
711  let Inst{3-0} = cond;
712}
713
714class C_COND_FM<bits<5> fmt, bits<4> c> : CEQS_FM<fmt> {
715  let cond = c;
716}
717
718class CMov_I_F_FM<bits<6> funct, bits<5> fmt> {
719  bits<5> fd;
720  bits<5> fs;
721  bits<5> rt;
722
723  bits<32> Inst;
724
725  let Inst{31-26} = 0x11;
726  let Inst{25-21} = fmt;
727  let Inst{20-16} = rt;
728  let Inst{15-11} = fs;
729  let Inst{10-6} = fd;
730  let Inst{5-0} = funct;
731}
732
733class CMov_F_I_FM<bit tf> {
734  bits<5> rd;
735  bits<5> rs;
736  bits<3> fcc;
737
738  bits<32> Inst;
739
740  let Inst{31-26} = 0;
741  let Inst{25-21} = rs;
742  let Inst{20-18} = fcc;
743  let Inst{17} = 0;
744  let Inst{16} = tf;
745  let Inst{15-11} = rd;
746  let Inst{10-6} = 0;
747  let Inst{5-0} = 1;
748}
749
750class CMov_F_F_FM<bits<5> fmt, bit tf> {
751  bits<5> fd;
752  bits<5> fs;
753  bits<3> fcc;
754
755  bits<32> Inst;
756
757  let Inst{31-26} = 0x11;
758  let Inst{25-21} = fmt;
759  let Inst{20-18} = fcc;
760  let Inst{17} = 0;
761  let Inst{16} = tf;
762  let Inst{15-11} = fs;
763  let Inst{10-6} = fd;
764  let Inst{5-0} = 0x11;
765}
766