memset.S revision 7c860db0747f6276a6e43984d43f8fa5181ea936 
1/*
2 * Copyright (C) 2008 The Android Open Source Project
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions
7 * are met:
8 *  * Redistributions of source code must retain the above copyright
9 *    notice, this list of conditions and the following disclaimer.
10 *  * Redistributions in binary form must reproduce the above copyright
11 *    notice, this list of conditions and the following disclaimer in
12 *    the documentation and/or other materials provided with the
13 *    distribution.
14 *
15 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
16 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
17 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
18 * FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
19 * COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
20 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
21 * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS
22 * OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
23 * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
24 * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
25 * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
26 * SUCH DAMAGE.
27 */
28
29#include <machine/cpu-features.h>
30#include <machine/asm.h>
31#include "libc_events.h"
32
33/*
34 * This code assumes it is running on a processor that supports all arm v7
35 * instructions, that supports neon instructions, and that supports
36 * unaligned neon instruction accesses to memory.
37 */
38
39    .fpu    neon
40
41ENTRY(__memset_chk)
42        cmp         r2, r3
43        bls         done
44
45        ldr         r0, error_message
46        ldr         r1, error_code
471:
48        add         r0, pc
49        bl          __fortify_chk_fail
50error_code:
51        .word       BIONIC_EVENT_MEMSET_BUFFER_OVERFLOW
52error_message:
53        .word       error_string-(1b+8)
54
55END(__memset_chk)
56
57ENTRY(bzero)
58        mov     r2, r1
59        mov     r1, #0
60
61done:
62        // Fall through to memset...
63END(bzero)
64
65/* memset() returns its first argument.  */
66ENTRY(memset)
67        .save       {r0}
68        stmfd       sp!, {r0}
69
70        vdup.8      q0, r1
71
72        /* make sure we have at least 32 bytes to write */
73        subs        r2, r2, #32
74        blo         2f
75        vmov        q1, q0
76
771:      /* The main loop writes 32 bytes at a time */
78        subs        r2, r2, #32
79        vst1.8      {d0 - d3}, [r0]!
80        bhs         1b
81
822:      /* less than 32 left */
83        add         r2, r2, #32
84        tst         r2, #0x10
85        beq         3f
86
87        // writes 16 bytes, 128-bits aligned
88        vst1.8      {d0, d1}, [r0]!
893:      /* write up to 15-bytes (count in r2) */
90        movs        ip, r2, lsl #29
91        bcc         1f
92        vst1.8      {d0}, [r0]!
931:      bge         2f
94        vst1.32     {d0[0]}, [r0]!
952:      movs        ip, r2, lsl #31
96        strmib      r1, [r0], #1
97        strcsb      r1, [r0], #1
98        strcsb      r1, [r0], #1
99        ldmfd       sp!, {r0}
100        bx          lr
101END(memset)
102
103        .data
104error_string:
105        .string     "memset buffer overflow"
106