configure.ac revision 0fbb2dc83132a89201ad8b56c6909610437d2da0 
1AC_PREREQ([2.64])
2AC_INIT([harfbuzz],
3        [0.7.0],
4        [http://bugs.freedesktop.org/enter_bug.cgi?product=harfbuzz],
5        [harfbuzz],
6        [http://harfbuzz.org/])
7
8AC_CONFIG_SRCDIR([harfbuzz.pc.in])
9AC_CONFIG_HEADERS([config.h])
10
11AM_INIT_AUTOMAKE([1.11.1 gnu dist-bzip2 no-dist-gzip -Wall no-define])
12AM_SILENT_RULES([yes])
13
14# Check for programs
15AC_PROG_CC
16AM_PROG_CC_C_O
17AC_PROG_CXX
18
19# Initialize libtool
20LT_PREREQ([2.2])
21LT_INIT([disable-static])
22
23# Version
24m4_define(hb_version_triplet,m4_split(AC_PACKAGE_VERSION,[[.]]))
25m4_define(hb_version_major,m4_argn(1,hb_version_triplet))
26m4_define(hb_version_minor,m4_argn(2,hb_version_triplet))
27m4_define(hb_version_micro,m4_argn(3,hb_version_triplet))
28HB_VERSION_MAJOR=hb_version_major
29HB_VERSION_MINOR=hb_version_minor
30HB_VERSION_MICRO=hb_version_micro
31HB_VERSION=AC_PACKAGE_VERSION
32AC_SUBST(HB_VERSION_MAJOR)
33AC_SUBST(HB_VERSION_MINOR)
34AC_SUBST(HB_VERSION_MICRO)
35AC_SUBST(HB_VERSION)
36
37# Libtool version
38m4_define([hb_version_int],
39	  m4_eval(hb_version_major*10000 + hb_version_minor*100 + hb_version_micro))
40m4_if(m4_eval(hb_version_minor % 2), [1],
41      dnl for unstable releases
42      [m4_define([hb_libtool_revision], 0)],
43      dnl for stable releases
44      [m4_define([hb_libtool_revision], hb_version_micro)])
45m4_define([hb_libtool_age],
46	  m4_eval(hb_version_int - hb_libtool_revision))
47m4_define([hb_libtool_current],
48	  m4_eval(hb_version_major + hb_libtool_age))
49HB_LIBTOOL_VERSION_INFO=hb_libtool_current:hb_libtool_revision:hb_libtool_age
50AC_SUBST(HB_LIBTOOL_VERSION_INFO)
51
52# Functions and headers
53AC_CHECK_FUNCS(mprotect sysconf getpagesize mmap)
54AC_CHECK_HEADERS(unistd.h sys/mman.h)
55
56# Compiler flags
57AC_CANONICAL_HOST
58if test "x$GCC" = "xyes"; then
59
60	# Make symbols link locally
61	LDFLAGS="$LDFLAGS -Bsymbolic-functions"
62
63	# Make sure we don't link to libstdc++
64	CXXFLAGS="$CXXFLAGS -fno-rtti -fno-exceptions"
65
66	case "$host" in
67		arm-*-*)
68			# Request byte alignment on arm
69			CXXFLAGS="$CXXFLAGS -mstructure-size-boundary=8"
70		;;
71	esac
72fi
73
74dnl ==========================================================================
75
76PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.16, have_glib=true, have_glib=false)
77PKG_CHECK_MODULES(GTHREAD, gthread-2.0, , have_glib=false)
78if $have_glib; then
79	AC_DEFINE(HAVE_GLIB, 1, [Have glib2 library])
80fi
81AM_CONDITIONAL(HAVE_GLIB, $have_glib)
82
83dnl ==========================================================================
84
85PKG_CHECK_MODULES(CAIRO, cairo >= 1.8.0, have_cairo=true, have_cairo=false)
86if $have_cairo; then
87	AC_DEFINE(HAVE_CAIRO, 1, [Have cairo graphics library])
88fi
89AM_CONDITIONAL(HAVE_CAIRO, $have_cairo)
90
91PKG_CHECK_MODULES(CAIRO_PNG, cairo-png, have_cairo_png=true, have_cairo_png=false)
92if $have_cairo_png; then
93	AC_DEFINE(HAVE_CAIRO_PNG, 1, [Have cairo-png support in cairo graphics library])
94fi
95AM_CONDITIONAL(HAVE_CAIRO_PNG, $have_cairo_png)
96
97PKG_CHECK_MODULES(CAIRO_FT, cairo-ft, have_cairo_ft=true, have_cairo_ft=false)
98if $have_cairo_ft; then
99	AC_DEFINE(HAVE_CAIRO_FT, 1, [Have cairo-ft support in cairo graphics library])
100fi
101AM_CONDITIONAL(HAVE_CAIRO_FT, $have_cairo_ft)
102
103dnl ==========================================================================
104
105PKG_CHECK_MODULES(ICU, icu, have_icu=true, [
106	have_icu=false
107	if test $cross_compiling == no; then
108		AC_CHECK_PROG([have_icu], [icu-config], [true], [false])
109		if $have_icu; then
110			ICU_CFLAGS=`icu-config --cppflags`
111			ICU_LIBS=`icu-config --ldflags-libsonly`
112			ICU_CFLAGS=`echo "$ICU_CFLAGS" | sed "s@ -I/usr/include @ @"`
113			AC_SUBST(ICU_CFLAGS)
114			AC_SUBST(ICU_LIBS)
115		fi
116	fi
117])
118if $have_icu; then
119	AC_DEFINE(HAVE_ICU, 1, [Have ICU library])
120fi
121AM_CONDITIONAL(HAVE_ICU, $have_icu)
122
123dnl ==========================================================================
124
125PKG_CHECK_MODULES(FREETYPE, freetype2, have_freetype=true, have_freetype=false)
126if $have_freetype; then
127	AC_DEFINE(HAVE_FREETYPE, 1, [Have FreeType 2 library])
128	_save_libs="$LIBS"
129	_save_cflags="$CFLAGS"
130	LIBS="$LIBS $FREETYPE_LIBS"
131	CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
132	AC_CHECK_FUNCS(FT_Face_GetCharVariantIndex)
133	LIBS="$_save_libs"
134	CFLAGS="$_save_cflags"
135fi
136AM_CONDITIONAL(HAVE_FREETYPE, $have_freetype)
137
138dnl ===========================================================================
139
140AC_CHECK_HEADERS(usp10.h windows.h, have_uniscribe=true, have_uniscribe=false)
141if $have_uniscribe; then
142	UNISCRIBE_CFLAGS=
143	UNISCRIBE_LIBS="-lusp10 -lgdi32"
144	AC_SUBST(UNISCRIBE_CFLAGS)
145	AC_SUBST(UNISCRIBE_LIBS)
146fi
147AM_CONDITIONAL(HAVE_UNISCRIBE, $have_uniscribe)
148
149AC_CONFIG_FILES([
150Makefile
151harfbuzz.pc
152src/Makefile
153src/hb-version.h
154test/Makefile
155])
156
157AC_OUTPUT
158