configure.ac revision 12f5c0a222a2f0aebe63c0d367937a0ff985474a 
1AC_PREREQ([2.64])
2AC_INIT([HarfBuzz],
3        [0.9.0],
4        [http://bugs.freedesktop.org/enter_bug.cgi?product=harfbuzz],
5        [harfbuzz],
6        [http://harfbuzz.org/])
7
8AC_CONFIG_SRCDIR([harfbuzz.pc.in])
9AC_CONFIG_HEADERS([config.h])
10
11AM_INIT_AUTOMAKE([1.11.1 gnu dist-bzip2 no-dist-gzip -Wall no-define])
12AM_SILENT_RULES([yes])
13
14# Initialize libtool
15LT_PREREQ([2.2])
16LT_INIT([disable-static])
17
18# Check for programs
19AC_PROG_CC
20AM_PROG_CC_C_O
21AC_PROG_CXX
22
23# Version
24m4_define(hb_version_triplet,m4_split(AC_PACKAGE_VERSION,[[.]]))
25m4_define(hb_version_major,m4_argn(1,hb_version_triplet))
26m4_define(hb_version_minor,m4_argn(2,hb_version_triplet))
27m4_define(hb_version_micro,m4_argn(3,hb_version_triplet))
28HB_VERSION_MAJOR=hb_version_major
29HB_VERSION_MINOR=hb_version_minor
30HB_VERSION_MICRO=hb_version_micro
31HB_VERSION=AC_PACKAGE_VERSION
32AC_SUBST(HB_VERSION_MAJOR)
33AC_SUBST(HB_VERSION_MINOR)
34AC_SUBST(HB_VERSION_MICRO)
35AC_SUBST(HB_VERSION)
36
37# Libtool version
38m4_define([hb_version_int],
39	  m4_eval(hb_version_major*10000 + hb_version_minor*100 + hb_version_micro))
40m4_if(m4_eval(hb_version_minor % 2), [1],
41      dnl for unstable releases
42      [m4_define([hb_libtool_revision], 0)],
43      dnl for stable releases
44      [m4_define([hb_libtool_revision], hb_version_micro)])
45m4_define([hb_libtool_age],
46	  m4_eval(hb_version_int - hb_libtool_revision))
47m4_define([hb_libtool_current],
48	  m4_eval(hb_version_major + hb_libtool_age))
49HB_LIBTOOL_VERSION_INFO=hb_libtool_current:hb_libtool_revision:hb_libtool_age
50AC_SUBST(HB_LIBTOOL_VERSION_INFO)
51
52dnl GOBJECT_INTROSPECTION_CHECK([0.9.0])
53dnl GTK_DOC_CHECK([1.15],[--flavour no-tmpl])
54
55# Functions and headers
56AC_CHECK_FUNCS(atexit mprotect sysconf getpagesize sched_yield mmap _setmode isatty)
57AC_CHECK_HEADERS(unistd.h sys/mman.h sched.h io.h)
58
59# Compiler flags
60AC_CANONICAL_HOST
61if test "x$GCC" = "xyes"; then
62
63	# Make symbols link locally
64	LDFLAGS="$LDFLAGS -Bsymbolic-functions"
65
66	# Make sure we don't link to libstdc++
67	CXXFLAGS="$CXXFLAGS -fno-rtti -fno-exceptions"
68
69	case "$host" in
70		arm-*-*)
71			# Request byte alignment on arm
72			CXXFLAGS="$CXXFLAGS -mstructure-size-boundary=8"
73		;;
74	esac
75fi
76
77dnl ==========================================================================
78
79have_ot=true
80if $have_ot; then
81	AC_DEFINE(HAVE_OT, 1, [Have native OpenType Layout backend])
82fi
83AM_CONDITIONAL(HAVE_OT, $have_ot)
84
85dnl ===========================================================================
86
87PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.16, have_glib=true, have_glib=false)
88if $have_glib; then
89	AC_DEFINE(HAVE_GLIB, 1, [Have glib2 library])
90fi
91AM_CONDITIONAL(HAVE_GLIB, $have_glib)
92
93PKG_CHECK_MODULES(GTHREAD, gthread-2.0, have_gthread=true, have_gthread=false)
94if $have_gthread; then
95	AC_DEFINE(HAVE_GTHREAD, 1, [Have gthread2 library])
96fi
97AM_CONDITIONAL(HAVE_GTHREAD, $have_gthread)
98
99PKG_CHECK_MODULES(GOBJECT, gobject-2.0 glib-2.0 >= 2.16, have_gobject=true, have_gobject=false)
100if $have_gobject; then
101	AC_DEFINE(HAVE_GOBJECT, 1, [Have gobject2 library])
102	GLIB_MKENUMS=`$PKG_CONFIG --variable=glib_mkenums glib-2.0`
103	AC_SUBST(GLIB_MKENUMS)
104fi
105AM_CONDITIONAL(HAVE_GOBJECT, $have_gobject)
106
107dnl ==========================================================================
108
109PKG_CHECK_MODULES(CAIRO, cairo >= 1.8.0, have_cairo=true, have_cairo=false)
110if $have_cairo; then
111	AC_DEFINE(HAVE_CAIRO, 1, [Have cairo graphics library])
112fi
113AM_CONDITIONAL(HAVE_CAIRO, $have_cairo)
114
115PKG_CHECK_MODULES(CAIRO_FT, cairo-ft, have_cairo_ft=true, have_cairo_ft=false)
116if $have_cairo_ft; then
117	AC_DEFINE(HAVE_CAIRO_FT, 1, [Have cairo-ft support in cairo graphics library])
118fi
119AM_CONDITIONAL(HAVE_CAIRO_FT, $have_cairo_ft)
120
121dnl ==========================================================================
122
123PKG_CHECK_MODULES(ICU, icu, have_icu=true, [
124	have_icu=true
125	AC_CHECK_HEADERS(unicode/uchar.h,, have_icu=false)
126	AC_MSG_CHECKING([for libicuuc])
127	LIBS_old=$LIBS
128	LIBS="$LIBS -licuuc"
129	AC_TRY_LINK([#include <unicode/uchar.h>],
130		    [u_getIntPropertyValue (0, (UProperty)0);],
131		    AC_MSG_RESULT(yes),
132		    AC_MSG_RESULT(no);have_icu=false)
133	LIBS=$LIBS_old
134	if $have_icu; then
135		ICU_CFLAGS=-D_REENTRANT
136		ICU_LIBS="-licuuc"
137		AC_SUBST(ICU_CFLAGS)
138		AC_SUBST(ICU_LIBS)
139	fi
140])
141if $have_icu; then
142	AC_DEFINE(HAVE_ICU, 1, [Have ICU library])
143fi
144AM_CONDITIONAL(HAVE_ICU, $have_icu)
145
146dnl ==========================================================================
147
148PKG_CHECK_MODULES(GRAPHITE2, graphite2, have_graphite=true, have_graphite=false)
149if $have_graphite; then
150    AC_DEFINE(HAVE_GRAPHITE2, 1, [Have Graphite library])
151fi
152AM_CONDITIONAL(HAVE_GRAPHITE2, $have_graphite)
153
154dnl ==========================================================================
155
156PKG_CHECK_MODULES(FREETYPE, freetype2 >= 2.3.8, have_freetype=true, have_freetype=false)
157if $have_freetype; then
158	AC_DEFINE(HAVE_FREETYPE, 1, [Have FreeType 2 library])
159	_save_libs="$LIBS"
160	_save_cflags="$CFLAGS"
161	LIBS="$LIBS $FREETYPE_LIBS"
162	CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
163	AC_CHECK_FUNCS(FT_Face_GetCharVariantIndex)
164	LIBS="$_save_libs"
165	CFLAGS="$_save_cflags"
166fi
167AM_CONDITIONAL(HAVE_FREETYPE, $have_freetype)
168
169dnl ===========================================================================
170
171AC_CHECK_HEADERS(usp10.h windows.h, have_uniscribe=true, have_uniscribe=false)
172if $have_uniscribe; then
173	UNISCRIBE_CFLAGS=
174	UNISCRIBE_LIBS="-lusp10 -lgdi32"
175	AC_SUBST(UNISCRIBE_CFLAGS)
176	AC_SUBST(UNISCRIBE_LIBS)
177	AC_DEFINE(HAVE_UNISCRIBE, 1, [Have Uniscribe backend])
178fi
179AM_CONDITIONAL(HAVE_UNISCRIBE, $have_uniscribe)
180
181dnl ===========================================================================
182
183AC_CACHE_CHECK([for Intel atomic primitives], hb_cv_have_intel_atomic_primitives, [
184	hb_cv_have_intel_atomic_primitives=false
185	AC_TRY_LINK([
186		void memory_barrier (void) { __sync_synchronize (); }
187		int atomic_add (int *i) { return __sync_fetch_and_add (i, 1); }
188		int mutex_trylock (int *m) { return __sync_lock_test_and_set (m, 1); }
189		void mutex_unlock (int *m) { __sync_lock_release (m); }
190		], [], hb_cv_have_intel_atomic_primitives=true
191	)
192])
193if $hb_cv_have_intel_atomic_primitives; then
194	AC_DEFINE(HAVE_INTEL_ATOMIC_PRIMITIVES, 1, [Have Intel __sync_* atomic primitives])
195fi
196
197dnl ===========================================================================
198
199AC_CONFIG_FILES([
200Makefile
201harfbuzz.pc
202src/Makefile
203src/hb-version.h
204util/Makefile
205test/Makefile
206test/api/Makefile
207test/shaping/Makefile
208])
209
210AC_OUTPUT
211