configure.ac revision 1512a7357513b72e2a07dda706a176bb23d694e9 
1AC_PREREQ([2.64])
2AC_INIT([HarfBuzz],
3        [0.9.0],
4        [http://bugs.freedesktop.org/enter_bug.cgi?product=harfbuzz],
5        [harfbuzz],
6        [http://harfbuzz.org/])
7
8AC_CONFIG_SRCDIR([harfbuzz.pc.in])
9AC_CONFIG_HEADERS([config.h])
10
11AM_INIT_AUTOMAKE([1.11.1 gnu dist-bzip2 no-dist-gzip -Wall no-define])
12AM_SILENT_RULES([yes])
13
14# Initialize libtool
15LT_PREREQ([2.2])
16LT_INIT([disable-static])
17
18# Check for programs
19AC_PROG_CC
20AM_PROG_CC_C_O
21AC_PROG_CXX
22
23# Version
24m4_define(hb_version_triplet,m4_split(AC_PACKAGE_VERSION,[[.]]))
25m4_define(hb_version_major,m4_argn(1,hb_version_triplet))
26m4_define(hb_version_minor,m4_argn(2,hb_version_triplet))
27m4_define(hb_version_micro,m4_argn(3,hb_version_triplet))
28HB_VERSION_MAJOR=hb_version_major
29HB_VERSION_MINOR=hb_version_minor
30HB_VERSION_MICRO=hb_version_micro
31HB_VERSION=AC_PACKAGE_VERSION
32AC_SUBST(HB_VERSION_MAJOR)
33AC_SUBST(HB_VERSION_MINOR)
34AC_SUBST(HB_VERSION_MICRO)
35AC_SUBST(HB_VERSION)
36
37# Libtool version
38m4_define([hb_version_int],
39	  m4_eval(hb_version_major*10000 + hb_version_minor*100 + hb_version_micro))
40m4_if(m4_eval(hb_version_minor % 2), [1],
41      dnl for unstable releases
42      [m4_define([hb_libtool_revision], 0)],
43      dnl for stable releases
44      [m4_define([hb_libtool_revision], hb_version_micro)])
45m4_define([hb_libtool_age],
46	  m4_eval(hb_version_int - hb_libtool_revision))
47m4_define([hb_libtool_current],
48	  m4_eval(hb_version_major + hb_libtool_age))
49HB_LIBTOOL_VERSION_INFO=hb_libtool_current:hb_libtool_revision:hb_libtool_age
50AC_SUBST(HB_LIBTOOL_VERSION_INFO)
51
52dnl GOBJECT_INTROSPECTION_CHECK([0.9.0])
53dnl GTK_DOC_CHECK([1.15],[--flavour no-tmpl])
54
55# Functions and headers
56AC_CHECK_FUNCS(atexit mprotect sysconf getpagesize sched_yield mmap _setmode isatty)
57AC_CHECK_HEADERS(unistd.h sys/mman.h sched.h io.h)
58
59# Compiler flags
60AC_CANONICAL_HOST
61if test "x$GCC" = "xyes"; then
62
63	# Make symbols link locally
64	LDFLAGS="$LDFLAGS -Bsymbolic-functions"
65
66	# Make sure we don't link to libstdc++
67	CXXFLAGS="$CXXFLAGS -fno-rtti -fno-exceptions"
68
69	# Hide inline methods
70	CXXFLAGS="$CXXFLAGS -fvisibility-inlines-hidden"
71
72	# Assorted warnings
73	CXXFLAGS="$CXXFLAGS -Wcast-align"
74
75	case "$host" in
76		arm-*-*)
77			# Request byte alignment on arm
78			CXXFLAGS="$CXXFLAGS -mstructure-size-boundary=8"
79		;;
80	esac
81fi
82
83dnl ==========================================================================
84
85have_ot=true
86if $have_ot; then
87	AC_DEFINE(HAVE_OT, 1, [Have native OpenType Layout backend])
88fi
89AM_CONDITIONAL(HAVE_OT, $have_ot)
90
91dnl ===========================================================================
92
93PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.16, have_glib=true, have_glib=false)
94if $have_glib; then
95	AC_DEFINE(HAVE_GLIB, 1, [Have glib2 library])
96fi
97AM_CONDITIONAL(HAVE_GLIB, $have_glib)
98
99PKG_CHECK_MODULES(GTHREAD, gthread-2.0, have_gthread=true, have_gthread=false)
100if $have_gthread; then
101	AC_DEFINE(HAVE_GTHREAD, 1, [Have gthread2 library])
102fi
103AM_CONDITIONAL(HAVE_GTHREAD, $have_gthread)
104
105PKG_CHECK_MODULES(GOBJECT, gobject-2.0 glib-2.0 >= 2.16, have_gobject=true, have_gobject=false)
106if $have_gobject; then
107	AC_DEFINE(HAVE_GOBJECT, 1, [Have gobject2 library])
108	GLIB_MKENUMS=`$PKG_CONFIG --variable=glib_mkenums glib-2.0`
109	AC_SUBST(GLIB_MKENUMS)
110fi
111AM_CONDITIONAL(HAVE_GOBJECT, $have_gobject)
112
113dnl ==========================================================================
114
115PKG_CHECK_MODULES(CAIRO, cairo >= 1.8.0, have_cairo=true, have_cairo=false)
116if $have_cairo; then
117	AC_DEFINE(HAVE_CAIRO, 1, [Have cairo graphics library])
118fi
119AM_CONDITIONAL(HAVE_CAIRO, $have_cairo)
120
121PKG_CHECK_MODULES(CAIRO_FT, cairo-ft, have_cairo_ft=true, have_cairo_ft=false)
122if $have_cairo_ft; then
123	AC_DEFINE(HAVE_CAIRO_FT, 1, [Have cairo-ft support in cairo graphics library])
124fi
125AM_CONDITIONAL(HAVE_CAIRO_FT, $have_cairo_ft)
126
127dnl ==========================================================================
128
129PKG_CHECK_MODULES(ICU, icu, have_icu=true, [
130	have_icu=true
131	AC_CHECK_HEADERS(unicode/uchar.h,, have_icu=false)
132	AC_MSG_CHECKING([for libicuuc])
133	LIBS_old=$LIBS
134	LIBS="$LIBS -licuuc"
135	AC_TRY_LINK([#include <unicode/uchar.h>],
136		    [u_getIntPropertyValue (0, (UProperty)0);],
137		    AC_MSG_RESULT(yes),
138		    AC_MSG_RESULT(no);have_icu=false)
139	LIBS=$LIBS_old
140	if $have_icu; then
141		ICU_CFLAGS=-D_REENTRANT
142		ICU_LIBS="-licuuc"
143		AC_SUBST(ICU_CFLAGS)
144		AC_SUBST(ICU_LIBS)
145	fi
146])
147if $have_icu; then
148	AC_DEFINE(HAVE_ICU, 1, [Have ICU library])
149fi
150AM_CONDITIONAL(HAVE_ICU, $have_icu)
151
152dnl ==========================================================================
153
154PKG_CHECK_MODULES(GRAPHITE2, graphite2, have_graphite=true, have_graphite=false)
155if $have_graphite; then
156    AC_DEFINE(HAVE_GRAPHITE2, 1, [Have Graphite library])
157fi
158AM_CONDITIONAL(HAVE_GRAPHITE2, $have_graphite)
159
160dnl ==========================================================================
161
162PKG_CHECK_MODULES(FREETYPE, freetype2 >= 2.3.8, have_freetype=true, have_freetype=false)
163if $have_freetype; then
164	AC_DEFINE(HAVE_FREETYPE, 1, [Have FreeType 2 library])
165	_save_libs="$LIBS"
166	_save_cflags="$CFLAGS"
167	LIBS="$LIBS $FREETYPE_LIBS"
168	CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
169	AC_CHECK_FUNCS(FT_Face_GetCharVariantIndex)
170	LIBS="$_save_libs"
171	CFLAGS="$_save_cflags"
172fi
173AM_CONDITIONAL(HAVE_FREETYPE, $have_freetype)
174
175dnl ===========================================================================
176
177AC_CHECK_HEADERS(usp10.h windows.h, have_uniscribe=true, have_uniscribe=false)
178if $have_uniscribe; then
179	UNISCRIBE_CFLAGS=
180	UNISCRIBE_LIBS="-lusp10 -lgdi32"
181	AC_SUBST(UNISCRIBE_CFLAGS)
182	AC_SUBST(UNISCRIBE_LIBS)
183	AC_DEFINE(HAVE_UNISCRIBE, 1, [Have Uniscribe backend])
184fi
185AM_CONDITIONAL(HAVE_UNISCRIBE, $have_uniscribe)
186
187dnl ===========================================================================
188
189AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, have_coretext=true, have_coretext=false)
190if $have_coretext; then
191	CORETEXT_CFLAGS=
192	CORETEXT_LIBS=
193	AC_SUBST(CORETEXT_CFLAGS)
194	AC_SUBST(CORETEXT_LIBS)
195	AC_DEFINE(HAVE_CORETEXT, 1, [Have Core Text backend])
196fi
197AM_CONDITIONAL(HAVE_CORETEXT, $have_coretext)
198
199dnl ===========================================================================
200
201AC_CACHE_CHECK([for Intel atomic primitives], hb_cv_have_intel_atomic_primitives, [
202	hb_cv_have_intel_atomic_primitives=false
203	AC_TRY_LINK([
204		void memory_barrier (void) { __sync_synchronize (); }
205		int atomic_add (int *i) { return __sync_fetch_and_add (i, 1); }
206		int mutex_trylock (int *m) { return __sync_lock_test_and_set (m, 1); }
207		void mutex_unlock (int *m) { __sync_lock_release (m); }
208		], [], hb_cv_have_intel_atomic_primitives=true
209	)
210])
211if $hb_cv_have_intel_atomic_primitives; then
212	AC_DEFINE(HAVE_INTEL_ATOMIC_PRIMITIVES, 1, [Have Intel __sync_* atomic primitives])
213fi
214
215dnl ===========================================================================
216
217AC_CONFIG_FILES([
218Makefile
219harfbuzz.pc
220src/Makefile
221src/hb-version.h
222src/hb-old/Makefile
223util/Makefile
224test/Makefile
225test/api/Makefile
226test/shaping/Makefile
227])
228
229AC_OUTPUT
230