configure.ac revision 4451168e5d1ea26560899e9a9733b3a3f1853050 
1AC_PREREQ([2.64])
2AC_INIT([harfbuzz],
3        [0.7.0],
4        [http://bugs.freedesktop.org/enter_bug.cgi?product=harfbuzz],
5        [harfbuzz],
6        [http://harfbuzz.org/])
7
8AC_CONFIG_SRCDIR([harfbuzz.pc.in])
9AC_CONFIG_HEADERS([config.h])
10
11AM_INIT_AUTOMAKE([1.11.1 gnu dist-bzip2 no-dist-gzip -Wall no-define])
12AM_SILENT_RULES([yes])
13
14# Check for programs
15AC_PROG_CC
16AM_PROG_CC_C_O
17AC_PROG_CXX
18
19# Initialize libtool
20LT_PREREQ([2.2])
21LT_INIT([disable-static])
22
23# Version
24m4_define(hb_version_triplet,m4_split(AC_PACKAGE_VERSION,[[.]]))
25m4_define(hb_version_major,m4_argn(1,hb_version_triplet))
26m4_define(hb_version_minor,m4_argn(2,hb_version_triplet))
27m4_define(hb_version_micro,m4_argn(3,hb_version_triplet))
28HB_VERSION_MAJOR=hb_version_major
29HB_VERSION_MINOR=hb_version_minor
30HB_VERSION_MICRO=hb_version_micro
31HB_VERSION=AC_PACKAGE_VERSION
32AC_SUBST(HB_VERSION_MAJOR)
33AC_SUBST(HB_VERSION_MINOR)
34AC_SUBST(HB_VERSION_MICRO)
35AC_SUBST(HB_VERSION)
36
37# Libtool version
38m4_define([hb_version_int],
39	  m4_eval(hb_version_major*10000 + hb_version_minor*100 + hb_version_micro))
40m4_if(m4_eval(hb_version_minor % 2), [1],
41      dnl for unstable releases
42      [m4_define([hb_libtool_revision], 0)],
43      dnl for stable releases
44      [m4_define([hb_libtool_revision], hb_version_micro)])
45m4_define([hb_libtool_age],
46	  m4_eval(hb_version_int - hb_libtool_revision))
47m4_define([hb_libtool_current],
48	  m4_eval(hb_version_major + hb_libtool_age))
49HB_LIBTOOL_VERSION_INFO=hb_libtool_current:hb_libtool_revision:hb_libtool_age
50AC_SUBST(HB_LIBTOOL_VERSION_INFO)
51
52GTK_DOC_CHECK([1.15],[--flavour no-tmpl])
53
54# Functions and headers
55AC_CHECK_FUNCS(mprotect sysconf getpagesize mmap)
56AC_CHECK_HEADERS(unistd.h sys/mman.h io.h)
57
58# Compiler flags
59AC_CANONICAL_HOST
60if test "x$GCC" = "xyes"; then
61
62	# Make symbols link locally
63	LDFLAGS="$LDFLAGS -Bsymbolic-functions"
64
65	# Make sure we don't link to libstdc++
66	CXXFLAGS="$CXXFLAGS -fno-rtti -fno-exceptions"
67
68	case "$host" in
69		arm-*-*)
70			# Request byte alignment on arm
71			CXXFLAGS="$CXXFLAGS -mstructure-size-boundary=8"
72		;;
73	esac
74fi
75
76dnl ==========================================================================
77
78PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.16, have_glib=true, have_glib=false)
79if $have_glib; then
80	AC_DEFINE(HAVE_GLIB, 1, [Have glib2 library])
81fi
82AM_CONDITIONAL(HAVE_GLIB, $have_glib)
83
84PKG_CHECK_MODULES(GTHREAD, gthread-2.0, have_gthread=true, have_gthread=false)
85if $have_gthread; then
86	AC_DEFINE(HAVE_GTHREAD, 1, [Have gthread2 library])
87fi
88AM_CONDITIONAL(HAVE_GTHREAD, $have_gthread)
89
90PKG_CHECK_MODULES(GOBJECT, gobject-2.0, have_gobject=true, have_gobject=false)
91if $have_gobject; then
92	AC_DEFINE(HAVE_GOBJECT, 1, [Have gobject2 library])
93	GLIB_MKENUMS=`$PKG_CONFIG --variable=glib_mkenums glib-2.0`
94	AC_SUBST(GLIB_MKENUMS)
95fi
96AM_CONDITIONAL(HAVE_GOBJECT, $have_gobject)
97
98dnl ==========================================================================
99
100PKG_CHECK_MODULES(CAIRO, cairo >= 1.8.0, have_cairo=true, have_cairo=false)
101if $have_cairo; then
102	AC_DEFINE(HAVE_CAIRO, 1, [Have cairo graphics library])
103fi
104AM_CONDITIONAL(HAVE_CAIRO, $have_cairo)
105
106PKG_CHECK_MODULES(CAIRO_PNG, cairo-png, have_cairo_png=true, have_cairo_png=false)
107if $have_cairo_png; then
108	AC_DEFINE(HAVE_CAIRO_PNG, 1, [Have cairo-png support in cairo graphics library])
109fi
110AM_CONDITIONAL(HAVE_CAIRO_PNG, $have_cairo_png)
111
112PKG_CHECK_MODULES(CAIRO_FT, cairo-ft, have_cairo_ft=true, have_cairo_ft=false)
113if $have_cairo_ft; then
114	AC_DEFINE(HAVE_CAIRO_FT, 1, [Have cairo-ft support in cairo graphics library])
115fi
116AM_CONDITIONAL(HAVE_CAIRO_FT, $have_cairo_ft)
117
118dnl ==========================================================================
119
120PKG_CHECK_MODULES(ICU, icu, have_icu=true, [
121	if test $cross_compiling == no; then
122		AC_CHECK_PROG([have_icu], [icu-config], [true], [false])
123		if $have_icu; then
124			ICU_CFLAGS=`icu-config --cppflags`
125			ICU_LIBS=`icu-config --ldflags-libsonly`
126			ICU_CFLAGS=`echo "$ICU_CFLAGS" | sed "s@ -I/usr/include @ @"`
127			AC_SUBST(ICU_CFLAGS)
128			AC_SUBST(ICU_LIBS)
129		fi
130	else
131		have_icu=false
132	fi
133])
134if $have_icu; then
135	AC_DEFINE(HAVE_ICU, 1, [Have ICU library])
136fi
137AM_CONDITIONAL(HAVE_ICU, $have_icu)
138
139dnl ==========================================================================
140
141PKG_CHECK_MODULES(GRAPHITE, graphite2, have_graphite=true, have_graphite=false)
142if $have_graphite; then
143    AC_DEFINE(HAVE_GRAPHITE, 1, [Have Graphite library])
144fi
145AM_CONDITIONAL(HAVE_GRAPHITE, $have_graphite)
146
147dnl ==========================================================================
148
149PKG_CHECK_MODULES(FREETYPE, freetype2 >= 2.3.8, have_freetype=true, have_freetype=false)
150if $have_freetype; then
151	AC_DEFINE(HAVE_FREETYPE, 1, [Have FreeType 2 library])
152	_save_libs="$LIBS"
153	_save_cflags="$CFLAGS"
154	LIBS="$LIBS $FREETYPE_LIBS"
155	CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
156	AC_CHECK_FUNCS(FT_Face_GetCharVariantIndex)
157	LIBS="$_save_libs"
158	CFLAGS="$_save_cflags"
159fi
160AM_CONDITIONAL(HAVE_FREETYPE, $have_freetype)
161
162dnl ===========================================================================
163
164have_ot=true;
165if $have_ot; then
166	AC_DEFINE(HAVE_OT, 1, [Have native OpenType Layout backend])
167fi
168AM_CONDITIONAL(HAVE_OT, $have_ot)
169
170dnl ===========================================================================
171
172AC_CHECK_HEADERS(usp10.h windows.h, have_uniscribe=true, have_uniscribe=false)
173if $have_uniscribe; then
174	UNISCRIBE_CFLAGS=
175	UNISCRIBE_LIBS="-lusp10 -lgdi32"
176	AC_SUBST(UNISCRIBE_CFLAGS)
177	AC_SUBST(UNISCRIBE_LIBS)
178	AC_DEFINE(HAVE_UNISCRIBE, 1, [Have Uniscribe backend])
179fi
180AM_CONDITIONAL(HAVE_UNISCRIBE, $have_uniscribe)
181
182AC_CONFIG_FILES([
183Makefile
184harfbuzz.pc
185src/Makefile
186src/hb-version.h
187util/Makefile
188test/Makefile
189])
190
191AC_OUTPUT
192