configure.ac revision 76691f0240d6de230e9b42280b54e91639464635 
1AC_PREREQ(2.59)
2AC_INIT(harfbuzz, 0.3, [http://bugs.freedesktop.org/enter_bug.cgi?product=harfbuzz])
3AC_CONFIG_SRCDIR([harfbuzz.pc.in])
4AC_CONFIG_HEADERS([config.h])
5AM_INIT_AUTOMAKE([1.9.6 gnu dist-bzip2 no-dist-gzip -Wall no-define])
6m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
7
8AC_LIBTOOL_WIN32_DLL
9AC_PROG_LIBTOOL dnl ([1.4]) Don't remove!
10
11AC_PROG_CC
12AM_PROG_CC_C_O
13AC_PROG_CXX
14
15AC_CHECK_FUNCS(mprotect sysconf getpagesize)
16AC_CHECK_HEADERS(unistd.h sys/mman.h)
17
18# Make sure we don't link to libstdc++
19if test "x$GCC" = "xyes"; then
20	CXXFLAGS="$CXXFLAGS -fno-rtti -fno-exceptions"
21fi
22
23dnl ==========================================================================
24
25PKG_CHECK_MODULES(GLIB, glib-2.0, have_glib=true, have_glib=false)
26if $have_glib; then
27	AC_DEFINE(HAVE_GLIB, 1, [Have glib2 library])
28fi
29AM_CONDITIONAL(HAVE_GLIB, $have_glib)
30
31PKG_CHECK_MODULES(ICU, icu, have_icu=true, [
32	AC_CHECK_PROG([have_icu], [icu-config], [true], [false])
33	if $have_icu; then
34		icu_cflags=`icu-config --cppflags`
35		icu_libs=`icu-config --ldflags-libsonly`
36		AC_SUBST(ICU_CFLAGS, [$icu_cflags])
37		AC_SUBST(ICU_LIBS, [$icu_libs])
38	fi
39])
40if $have_icu; then
41	AC_DEFINE(HAVE_ICU, 1, [Have ICU library])
42fi
43AM_CONDITIONAL(HAVE_ICU, $have_icu)
44
45PKG_CHECK_MODULES(FREETYPE, freetype2, have_freetype=true, have_freetype=false)
46if $have_freetype; then
47	AC_DEFINE(HAVE_FREETYPE, 1, [Have FreeType 2 library])
48	_save_libs="$LIBS"
49	_save_cflags="$CFLAGS"
50	LIBS="$LIBS $FREETYPE_LIBS"
51	CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
52	AC_CHECK_FUNCS(FT_Face_GetCharVariantIndex)
53	LIBS="$_save_libs"
54	CFLAGS="$_save_cflags"
55fi
56AM_CONDITIONAL(HAVE_FREETYPE, $have_freetype)
57
58dnl ==========================================================================
59
60AC_CONFIG_FILES([
61harfbuzz.pc
62Makefile
63src/Makefile
64])
65
66AC_OUTPUT
67