configure.ac revision 84bd075a077809b7079a6e711b608b9b0927a889 
1dnl === configure.ac --------------------------------------------------------===
2dnl                     The LLVM Compiler Infrastructure
3dnl
4dnl This file is distributed under the University of Illinois Open Source
5dnl License. See LICENSE.TXT for details.
6dnl
7dnl===-----------------------------------------------------------------------===
8dnl This is the LLVM configuration script. It is processed by the autoconf
9dnl program to produce a script named configure. This script contains the
10dnl configuration checks that LLVM needs in order to support multiple platforms.
11dnl This file is composed of 10 sections per the recommended organization of
12dnl autoconf input defined in the autoconf documentation. As this file evolves,
13dnl please keep the various types of checks within their sections. The sections
14dnl are as follows:
15dnl
16dnl SECTION 1: Initialization & Setup
17dnl SECTION 2: Architecture, target, and host checks
18dnl SECTION 3: Command line arguments for the configure script.
19dnl SECTION 4: Check for programs we need and that they are the right version
20dnl SECTION 5: Check for libraries
21dnl SECTION 6: Check for header files
22dnl SECTION 7: Check for types and structures
23dnl SECTION 8: Check for specific functions needed
24dnl SECTION 9: Additional checks, variables, etc.
25dnl SECTION 10: Specify the output files and generate it
26dnl
27dnl===-----------------------------------------------------------------------===
28dnl===
29dnl=== SECTION 1: Initialization & Setup
30dnl===
31dnl===-----------------------------------------------------------------------===
32dnl Initialize autoconf and define the package name, version number and
33dnl email address for reporting bugs.
34AC_INIT([[llvm]],[[2.6svn]],[llvmbugs@cs.uiuc.edu])
35
36dnl Provide a copyright substitution and ensure the copyright notice is included
37dnl in the output of --version option of the generated configure script.
38AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign."])
39AC_COPYRIGHT([Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign.])
40
41dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
42dnl use some autoconf macros only available in 2.59.
43AC_PREREQ(2.59)
44
45dnl Verify that the source directory is valid. This makes sure that we are
46dnl configuring LLVM and not some other package (it validates --srcdir argument)
47AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
48
49dnl Place all of the extra autoconf files into the config subdirectory. Tell
50dnl various tools where the m4 autoconf macros are.
51AC_CONFIG_AUX_DIR([autoconf])
52
53dnl Quit if the source directory has already been configured.
54dnl NOTE: This relies upon undocumented autoconf behavior.
55if test ${srcdir} != "." ; then
56  if test -f ${srcdir}/include/llvm/Config/config.h ; then
57    AC_MSG_ERROR([Already configured in ${srcdir}])
58  fi
59fi
60
61dnl Configure all of the projects present in our source tree. While we could
62dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
63dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
64dnl Instead we match on the known projects.
65for i in `ls ${srcdir}/projects`
66do
67  if test -d ${srcdir}/projects/${i} ; then
68    case ${i} in
69      CVS) ;;
70      sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
71      privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
72      llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
73      # llvm-test is the old name of the test-suite, kept here for backwards
74      # compatibility
75      llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
76      test-suite)   AC_CONFIG_SUBDIRS([projects/test-suite]) ;;
77      llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
78      llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
79      llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
80      llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
81      llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
82      poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
83      llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
84      *)
85        AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
86        ;;
87    esac
88  fi
89done
90
91dnl===-----------------------------------------------------------------------===
92dnl===
93dnl=== SECTION 2: Architecture, target, and host checks
94dnl===
95dnl===-----------------------------------------------------------------------===
96
97dnl Check the target for which we're compiling and the host that will do the
98dnl compilations. This will tell us which LLVM compiler will be used for
99dnl compiling SSA into object code. This needs to be done early because
100dnl following tests depend on it.
101AC_CANONICAL_TARGET
102
103dnl Determine the platform type and cache its value. This helps us configure
104dnl the System library to the correct build platform.
105AC_CACHE_CHECK([type of operating system we're going to host on],
106               [llvm_cv_os_type],
107[case $host in
108  *-*-aix*)
109    llvm_cv_link_all_option="-Wl,--whole-archive"
110    llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
111    llvm_cv_os_type="AIX"
112    llvm_cv_platform_type="Unix" ;;
113  *-*-irix*)
114    llvm_cv_link_all_option="-Wl,--whole-archive"
115    llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
116    llvm_cv_os_type="IRIX"
117    llvm_cv_platform_type="Unix" ;;
118  *-*-cygwin*)
119    llvm_cv_link_all_option="-Wl,--whole-archive"
120    llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
121    llvm_cv_os_type="Cygwin"
122    llvm_cv_platform_type="Unix" ;;
123  *-*-darwin*)
124    llvm_cv_link_all_option="-Wl,-all_load"
125    llvm_cv_no_link_all_option="-Wl,-noall_load"
126    llvm_cv_os_type="Darwin"
127    llvm_cv_platform_type="Unix" ;;
128  *-*-freebsd*)
129    llvm_cv_link_all_option="-Wl,--whole-archive"
130    llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
131    llvm_cv_os_type="FreeBSD"
132    llvm_cv_platform_type="Unix" ;;
133  *-*-openbsd*)
134    llvm_cv_link_all_option="-Wl,--whole-archive"
135    llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
136    llvm_cv_os_type="OpenBSD"
137    llvm_cv_platform_type="Unix" ;;
138  *-*-netbsd*)
139    llvm_cv_link_all_option="-Wl,--whole-archive"
140    llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
141    llvm_cv_os_type="NetBSD"
142    llvm_cv_platform_type="Unix" ;;
143  *-*-dragonfly*)
144    llvm_cv_link_all_option="-Wl,--whole-archive"
145    llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
146    llvm_cv_os_type="DragonFly"
147    llvm_cv_platform_type="Unix" ;;
148  *-*-hpux*)
149    llvm_cv_link_all_option="-Wl,--whole-archive"
150    llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
151    llvm_cv_os_type="HP-UX"
152    llvm_cv_platform_type="Unix" ;;
153  *-*-interix*)
154    llvm_cv_link_all_option="-Wl,--whole-archive"
155    llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
156    llvm_cv_os_type="Interix"
157    llvm_cv_platform_type="Unix" ;;
158  *-*-linux*)
159    llvm_cv_link_all_option="-Wl,--whole-archive"
160    llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
161    llvm_cv_os_type="Linux"
162    llvm_cv_platform_type="Unix" ;;
163  *-*-solaris*)
164    llvm_cv_link_all_option="-Wl,-z,allextract"
165    llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
166    llvm_cv_os_type="SunOS"
167    llvm_cv_platform_type="Unix" ;;
168  *-*-win32*)
169    llvm_cv_link_all_option="-Wl,--whole-archive"
170    llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
171    llvm_cv_os_type="Win32"
172    llvm_cv_platform_type="Win32" ;;
173  *-*-mingw*)
174    llvm_cv_link_all_option="-Wl,--whole-archive"
175    llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
176    llvm_cv_os_type="MingW"
177    llvm_cv_platform_type="Win32" ;;
178  *)
179    llvm_cv_link_all_option=""
180    llvm_cv_no_link_all_option=""
181    llvm_cv_os_type="Unknown"
182    llvm_cv_platform_type="Unknown" ;;
183esac])
184
185dnl Make sure we aren't attempting to configure for an unknown system
186if test "$llvm_cv_os_type" = "Unknown" ; then
187  AC_MSG_ERROR([Operating system is unknown, configure can't continue])
188fi
189
190dnl Set the "OS" Makefile variable based on the platform type so the
191dnl makefile can configure itself to specific build hosts
192AC_SUBST(OS,$llvm_cv_os_type)
193
194dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
195AC_SUBST(LINKALL,$llvm_cv_link_all_option)
196AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
197
198dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
199dnl This is used by lib/System to determine the basic kind of implementation
200dnl to use.
201case $llvm_cv_platform_type in
202  Unix)
203    AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
204    AC_SUBST(LLVM_ON_UNIX,[1])
205    AC_SUBST(LLVM_ON_WIN32,[0])
206    ;;
207  Win32)
208    AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
209    AC_SUBST(LLVM_ON_UNIX,[0])
210    AC_SUBST(LLVM_ON_WIN32,[1])
211    ;;
212esac
213
214dnl Determine what our target architecture is and configure accordingly.
215dnl This will allow Makefiles to make a distinction between the hardware and
216dnl the OS.
217AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
218[case $target in
219  i?86-*)                 llvm_cv_target_arch="x86" ;;
220  amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
221  sparc*-*)               llvm_cv_target_arch="Sparc" ;;
222  powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
223  alpha*-*)               llvm_cv_target_arch="Alpha" ;;
224  ia64-*)                 llvm_cv_target_arch="IA64" ;;
225  arm*-*)                 llvm_cv_target_arch="ARM" ;;
226  mips-*)                 llvm_cv_target_arch="Mips" ;;
227  pic16-*)                llvm_cv_target_arch="PIC16" ;;
228  xcore-*)                llvm_cv_target_arch="XCore" ;;
229  msp430-*)               llvm_cv_target_arch="MSP430" ;;
230  *)                      llvm_cv_target_arch="Unknown" ;;
231esac])
232
233if test "$llvm_cv_target_arch" = "Unknown" ; then
234  AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
235fi
236
237dnl Define a substitution, ARCH, for the target architecture
238AC_SUBST(ARCH,$llvm_cv_target_arch)
239
240dnl Check for the endianness of the target
241AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
242
243dnl Check for build platform executable suffix if we're crosscompiling
244if test "$cross_compiling" = yes; then
245  AC_SUBST(LLVM_CROSS_COMPILING, [1])
246  AC_BUILD_EXEEXT
247  ac_build_prefix=${build_alias}-
248  AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
249  if test -z "$BUILD_CXX"; then
250     AC_CHECK_PROG(BUILD_CXX, g++, g++)
251     if test -z "$BUILD_CXX"; then
252       AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
253     fi
254  fi
255else
256  AC_SUBST(LLVM_CROSS_COMPILING, [0])
257fi
258
259dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
260dnl that this build is being done from a checkout. This sets up several
261dnl defaults for the command line switches. When we build with a CVS directory,
262dnl we get a debug with assertions turned on. Without, we assume a source
263dnl release and we get an optimized build without assertions.
264dnl See --enable-optimized and --enable-assertions below
265if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
266  cvsbuild="yes"
267  optimize="no"
268  AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
269else
270  cvsbuild="no"
271  optimize="yes"
272fi
273
274dnl===-----------------------------------------------------------------------===
275dnl===
276dnl=== SECTION 3: Command line arguments for the configure script.
277dnl===
278dnl===-----------------------------------------------------------------------===
279
280dnl --enable-optimized : check whether they want to do an optimized build:
281AC_ARG_ENABLE(optimized, AS_HELP_STRING(
282 --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
283if test ${enableval} = "no" ; then
284  AC_SUBST(ENABLE_OPTIMIZED,[[]])
285else
286  AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
287fi
288
289dnl --enable-profiling : check whether they want to do a profile build:
290AC_ARG_ENABLE(profiling, AS_HELP_STRING(
291 --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
292if test ${enableval} = "no" ; then
293  AC_SUBST(ENABLE_PROFILING,[[]])
294else
295  AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
296fi
297
298dnl --enable-assertions : check whether they want to turn on assertions or not:
299AC_ARG_ENABLE(assertions,AS_HELP_STRING(
300  --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
301if test ${enableval} = "yes" ; then
302  AC_SUBST(DISABLE_ASSERTIONS,[[]])
303else
304  AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
305fi
306
307dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
308AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
309  --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
310if test ${enableval} = "yes" ; then
311  AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
312  AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
313else
314  AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
315  AC_SUBST(EXPENSIVE_CHECKS,[[no]])
316fi
317
318dnl --enable-debug-runtime : should runtime libraries have debug symbols?
319AC_ARG_ENABLE(debug-runtime,
320   AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
321if test ${enableval} = "no" ; then
322  AC_SUBST(DEBUG_RUNTIME,[[]])
323else
324  AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
325fi
326
327dnl --enable-jit: check whether they want to enable the jit
328AC_ARG_ENABLE(jit,
329  AS_HELP_STRING(--enable-jit,
330                 [Enable Just In Time Compiling (default is YES)]),,
331  enableval=default)
332if test ${enableval} = "no"
333then
334  AC_SUBST(JIT,[[]])
335else
336  case "$llvm_cv_target_arch" in
337    x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
338    Sparc)   AC_SUBST(TARGET_HAS_JIT,0) ;;
339    PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
340    x86_64)  AC_SUBST(TARGET_HAS_JIT,1) ;;
341    Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
342    IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
343    ARM)     AC_SUBST(TARGET_HAS_JIT,0) ;;
344    Mips)    AC_SUBST(TARGET_HAS_JIT,0) ;;
345    PIC16)   AC_SUBST(TARGET_HAS_JIT,0) ;;
346    XCore)   AC_SUBST(TARGET_HAS_JIT,0) ;;
347    MSP430)  AC_SUBST(TARGET_HAS_JIT,0) ;;
348    *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
349  esac
350fi
351
352dnl Allow enablement of doxygen generated documentation
353AC_ARG_ENABLE(doxygen,
354              AS_HELP_STRING([--enable-doxygen],
355                             [Build doxygen documentation (default is NO)]),,
356                             enableval=default)
357case "$enableval" in
358  yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
359  no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
360  default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
361  *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
362esac
363
364dnl Allow disablement of threads
365AC_ARG_ENABLE(threads,
366              AS_HELP_STRING([--enable-threads],
367                             [Use threads if available (default is YES)]),,
368                             enableval=default)
369case "$enableval" in
370  yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
371  no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
372  default) AC_SUBST(ENABLE_THREADS,[1]) ;;
373  *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
374esac
375AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
376
377dnl Allow building without position independent code
378AC_ARG_ENABLE(pic,
379  AS_HELP_STRING([--enable-pic],
380                 [Build LLVM with Position Independent Code (default is YES)]),,
381                 enableval=default)
382case "$enableval" in
383  yes) AC_SUBST(ENABLE_PIC,[1]) ;;
384  no)  AC_SUBST(ENABLE_PIC,[0]) ;;
385  default) AC_SUBST(ENABLE_PIC,[1]) ;;
386  *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
387esac
388AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
389                   [Define if position independent code is enabled])
390
391dnl Allow specific targets to be specified for building (or not)
392TARGETS_TO_BUILD=""
393AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
394    [Build specific host targets: all,host-only,{target-name} (default=all)]),,
395    enableval=all)
396case "$enableval" in
397  all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM Mips CellSPU PIC16 XCore MSP430 CBackend MSIL CppBackend" ;;
398  host-only)
399    case "$llvm_cv_target_arch" in
400      x86)     TARGETS_TO_BUILD="X86" ;;
401      x86_64)  TARGETS_TO_BUILD="X86" ;;
402      Sparc)   TARGETS_TO_BUILD="Sparc" ;;
403      PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
404      Alpha)   TARGETS_TO_BUILD="Alpha" ;;
405      IA64)    TARGETS_TO_BUILD="IA64" ;;
406      ARM)     TARGETS_TO_BUILD="ARM" ;;
407      Mips)    TARGETS_TO_BUILD="Mips" ;;
408      CellSPU|SPU) TARGETS_TO_BUILD="CellSPU" ;;
409      PIC16)   TARGETS_TO_BUILD="PIC16" ;;
410      XCore)   TARGETS_TO_BUILD="XCore" ;;
411      MSP430)  TARGETS_TO_BUILD="MSP430" ;;
412      *)       AC_MSG_ERROR([Can not set target to build]) ;;
413    esac
414    ;;
415  *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
416      case "$a_target" in
417        x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
418        x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
419        sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
420        powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
421        alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
422        ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
423        arm)     TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
424        mips)    TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
425        spu)     TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
426        pic16)   TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
427        xcore)   TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
428        msp430)  TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
429        cbe)     TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
430        msil)    TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
431        cpp)     TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
432        *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
433      esac
434  done
435  ;;
436esac
437AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
438
439dnl Prevent the CBackend from using printf("%a") for floating point so older
440dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
441dnl can still compile the CBE's output
442AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
443  [Enable C Backend output with hex floating point via %a  (default is YES)]),,
444  enableval=default)
445case "$enableval" in
446  yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
447  no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
448  default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
449  *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
450esac
451AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
452                   [Define if CBE is enabled for printf %a output])
453
454dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
455AC_ARG_WITH(llvmgccdir,
456  AS_HELP_STRING([--with-llvmgccdir],
457    [Specify location of llvm-gcc install dir (default searches PATH)]),,
458    withval=default)
459case "$withval" in
460  default) WITH_LLVMGCCDIR=default ;;
461  /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
462  *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
463esac
464
465dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
466AC_ARG_WITH(llvmgcc,
467  AS_HELP_STRING([--with-llvmgcc],
468    [Specify location of llvm-gcc driver (default searches PATH)]),
469    LLVMGCC=$with_llvmgcc
470      WITH_LLVMGCCDIR="",)
471
472dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
473AC_ARG_WITH(llvmgxx,
474  AS_HELP_STRING([--with-llvmgxx],
475    [Specify location of llvm-g++ driver (default searches PATH)]),
476    LLVMGXX=$with_llvmgxx
477    WITH_LLVMGCCDIR="",)
478
479if test -n "$LLVMGCC"; then
480   LLVMGCCCOMMAND="$LLVMGCC"
481fi
482
483if test -n "$LLVMGXX"; then
484   LLVMGXXCOMMAND="$LLVMGXX"
485fi
486
487if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
488   AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
489fi
490
491if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
492   AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
493fi
494
495dnl Specify extra build options
496AC_ARG_WITH(extra-options,
497  AS_HELP_STRING([--with-extra-options],
498                 [Specify additional options to compile LLVM with]),,
499                 withval=default)
500case "$withval" in
501  default) EXTRA_OPTIONS= ;;
502  *) EXTRA_OPTIONS=$withval ;;
503esac
504AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
505
506dnl Allow specific bindings to be specified for building (or not)
507AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
508    [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
509    enableval=default)
510BINDINGS_TO_BUILD=""
511case "$enableval" in
512  yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
513  all ) BINDINGS_TO_BUILD="ocaml" ;;
514  none | no) BINDINGS_TO_BUILD="" ;;
515  *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
516      case "$a_binding" in
517        ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
518        *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
519      esac
520  done
521  ;;
522esac
523
524dnl Allow the ocaml libdir to be overridden. This could go in a configure
525dnl script for bindings/ocaml/configure, except that its auto value depends on
526dnl OCAMLC, which is found here to support tests.
527AC_ARG_WITH([ocaml-libdir],
528  [AS_HELP_STRING([--with-ocaml-libdir],
529    [Specify install location for ocaml bindings (default is stdlib)])],
530  [],
531  [withval=auto])
532case "$withval" in
533  auto) with_ocaml_libdir="$withval" ;;
534  /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
535  *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
536esac
537
538dnl Allow linking of LLVM with GPLv3 binutils code.
539AC_ARG_WITH(binutils-include,
540  AS_HELP_STRING([--with-binutils-include],
541    [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
542  withval=default)
543case "$withval" in
544  default) WITH_BINUTILS_INCDIR=default ;;
545  /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
546  *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
547esac
548if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
549  AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
550  if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
551     echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
552     AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
553  fi
554fi
555
556dnl --enable-libffi : check whether the user wants to turn off libffi:
557AC_ARG_ENABLE(libffi,AS_HELP_STRING(
558  --enable-libffi,[Check for the presence of libffi (default is YES)]),,
559  enableval=yes)
560case "$enableval" in
561  yes) llvm_cv_enable_libffi="yes" ;;
562  no)  llvm_cv_enable_libffi="no"  ;;
563  *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
564esac
565
566dnl===-----------------------------------------------------------------------===
567dnl===
568dnl=== SECTION 4: Check for programs we need and that they are the right version
569dnl===
570dnl===-----------------------------------------------------------------------===
571
572dnl Check for compilation tools
573AC_PROG_CPP
574AC_PROG_CC(gcc)
575AC_PROG_CXX(g++)
576
577AC_PROG_NM
578AC_SUBST(NM)
579
580dnl Check for the tools that the makefiles require
581AC_CHECK_GNU_MAKE
582AC_PROG_LN_S
583AC_PATH_PROG(CMP, [cmp], [cmp])
584AC_PATH_PROG(CP, [cp], [cp])
585AC_PATH_PROG(DATE, [date], [date])
586AC_PATH_PROG(FIND, [find], [find])
587AC_PATH_PROG(GREP, [grep], [grep])
588AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
589AC_PATH_PROG(MV,   [mv],   [mv])
590AC_PROG_RANLIB
591AC_PATH_PROG(RM,   [rm],   [rm])
592AC_PATH_PROG(SED,  [sed],  [sed])
593AC_PATH_PROG(TAR,  [tar],  [gtar])
594AC_PATH_PROG(BINPWD,[pwd],  [pwd])
595
596dnl Looking for misc. graph plotting software
597AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
598if test "$GRAPHVIZ" != "echo Graphviz" ; then
599  AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
600  dnl If we're targeting for mingw we should emit windows paths, not msys
601  if test "$llvm_cv_os_type" = "MingW" ; then
602    GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
603  fi
604  AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
605   [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
606fi
607AC_PATH_PROG(DOT, [dot], [echo dot])
608if test "$DOT" != "echo dot" ; then
609  AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
610  dnl If we're targeting for mingw we should emit windows paths, not msys
611  if test "$llvm_cv_os_type" = "MingW" ; then
612    DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
613  fi
614  AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
615   [Define to path to dot program if found or 'echo dot' otherwise])
616fi
617AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
618if test "$GV" != "echo gv" ; then
619  AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
620  dnl If we're targeting for mingw we should emit windows paths, not msys
621  if test "$llvm_cv_os_type" = "MingW" ; then
622    GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
623  fi
624  AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
625   [Define to path to gv program if found or 'echo gv' otherwise])
626fi
627AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
628if test "$DOTTY" != "echo dotty" ; then
629  AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
630  dnl If we're targeting for mingw we should emit windows paths, not msys
631  if test "$llvm_cv_os_type" = "MingW" ; then
632    DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
633  fi
634  AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
635   [Define to path to dotty program if found or 'echo dotty' otherwise])
636fi
637
638dnl Look for a sufficiently recent version of Perl.
639LLVM_PROG_PERL([5.006])
640AC_SUBST(PERL)
641if test x"$PERL" = xnone; then
642   AC_SUBST(HAVE_PERL,0)
643   AC_MSG_ERROR([perl is required but was not found, please install it])
644else
645   AC_SUBST(HAVE_PERL,1)
646fi
647
648dnl Find the install program
649AC_PROG_INSTALL
650
651dnl Checks for documentation and testing tools that we can do without. If these
652dnl are not found then they are set to "true" which always succeeds but does
653dnl nothing. This just lets the build output show that we could have done
654dnl something if the tool was available.
655AC_PATH_PROG(BZIP2, [bzip2])
656AC_PATH_PROG(DOXYGEN, [doxygen])
657AC_PATH_PROG(GROFF, [groff])
658AC_PATH_PROG(GZIP, [gzip])
659AC_PATH_PROG(POD2HTML, [pod2html])
660AC_PATH_PROG(POD2MAN, [pod2man])
661AC_PATH_PROG(RUNTEST, [runtest])
662DJ_AC_PATH_TCLSH
663AC_PATH_PROG(ZIP, [zip])
664AC_PATH_PROGS(OCAMLC, [ocamlc])
665AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
666AC_PATH_PROGS(OCAMLDEP, [ocamldep])
667AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
668AC_PATH_PROGS(GAS, [gas as])
669
670dnl Determine whether the linker supports the -R option.
671AC_LINK_USE_R
672
673dnl Determine whether the linker supports the -export-dynamic option.
674AC_LINK_EXPORT_DYNAMIC
675
676dnl Check for libtool and the library that has dlopen function (which must come
677dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
678dnl libtool).
679AC_LIBTOOL_DLOPEN
680AC_LIB_LTDL
681AC_PROG_LIBTOOL
682
683if test "$lt_cv_dlopen_self" = "yes" ; then
684  AC_DEFINE([CAN_DLOPEN_SELF],[1],
685              [Define if dlopen(0) will open the symbols of the program])
686fi
687
688
689if test "$WITH_LLVMGCCDIR" = "default" ; then
690  LLVMGCC="llvm-gcc${EXEEXT}"
691  LLVMGXX="llvm-g++${EXEEXT}"
692  LLVMGCCCOMMAND="$LLVMGCC"
693  LLVMGXXCOMMAND="$LLVMGXX"
694  AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
695  AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
696  AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
697  AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
698else
699  if test -z "$LLVMGCC"; then
700    LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
701    LLVMGCCCOMMAND="$LLVMGCC"
702  fi
703  if test -z "$LLVMGXX"; then
704    LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
705    LLVMGXXCOMMAND="$LLVMGXX"
706  fi
707
708  AC_SUBST(LLVMGCC,$LLVMGCC)
709  AC_SUBST(LLVMGXX,$LLVMGXX)
710  AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
711  AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
712fi
713
714
715AC_MSG_CHECKING([tool compatibility])
716
717dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
718dnl ICC; we use GCC specific options in the makefiles so the compiler needs
719dnl to support those options.
720dnl "icc" emits gcc signatures
721dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
722ICC=no
723IXX=no
724case $CC in
725  icc*|icpc*)
726    ICC=yes
727    IXX=yes
728    ;;
729   *)
730    ;;
731esac
732
733if test "$GCC" != "yes" && test "$ICC" != "yes"
734then
735  AC_MSG_ERROR([gcc|icc required but not found])
736fi
737
738dnl Ensure that compilation tools are GCC; we use GCC specific extensions
739if test "$GXX" != "yes" && test "$IXX" != "yes"
740then
741  AC_MSG_ERROR([g++|icc required but not found])
742fi
743
744dnl Verify that GCC is version 3.0 or higher
745if test "$GCC" = "yes"
746then
747  AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
748#error Unsupported GCC version
749#endif
750]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
751fi
752
753dnl Check for GNU Make.  We use its extensions, so don't build without it
754if test -z "$llvm_cv_gnu_make_command"
755then
756  AC_MSG_ERROR([GNU Make required but not found])
757fi
758
759dnl Tool compatibility is okay if we make it here.
760AC_MSG_RESULT([ok])
761
762dnl===-----------------------------------------------------------------------===
763dnl===
764dnl=== SECTION 5: Check for libraries
765dnl===
766dnl===-----------------------------------------------------------------------===
767
768dnl libelf is for sparc only; we can ignore it if we don't have it
769AC_CHECK_LIB(elf, elf_begin)
770AC_CHECK_LIB(m,sin)
771if test "$llvm_cv_os_type" = "MingW" ; then
772  AC_CHECK_LIB(imagehlp, main)
773  AC_CHECK_LIB(psapi, main)
774fi
775
776dnl dlopen() is required for plugin support.
777AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
778               [Define if dlopen() is available on this platform.]),
779               AC_MSG_WARN([dlopen() not found - disabling plugin support]))
780
781dnl libffi is optional; used to call external functions from the interpreter
782if test "$llvm_cv_enable_libffi" = "yes" ; then
783  AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
784                 [Define if libffi is available on this platform.]),
785                 AC_MSG_WARN([libffi not found - disabling external calls from interpreter]))
786fi
787
788dnl mallinfo is optional; the code can compile (minus features) without it
789AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
790               [Define if mallinfo() is available on this platform.]))
791
792dnl pthread locking functions are optional - but llvm will not be thread-safe
793dnl without locks.
794if test "$ENABLE_THREADS" -eq 1 ; then
795  AC_CHECK_LIB(pthread,pthread_mutex_init)
796  AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
797                 AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
798                           [Have pthread_mutex_lock]))
799fi
800
801dnl Allow extra x86-disassembler library
802AC_ARG_WITH(udis86,
803  AS_HELP_STRING([--with-udis86=<path>],
804    [Use udis86 external x86 disassembler library]),
805    [
806      AC_SUBST(USE_UDIS86, [1])
807      case "$withval" in
808        /usr/lib|yes) ;;
809        *) LDFLAGS="$LDFLAGS -L${withval}" ;;
810      esac
811      AC_CHECK_LIB(udis86, ud_init, [], [
812        echo "Error! You need to have libudis86 around."
813        exit -1
814      ])
815    ],
816    AC_SUBST(USE_UDIS86, [0]))
817AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
818                   [Define if use udis86 library])
819
820dnl===-----------------------------------------------------------------------===
821dnl===
822dnl=== SECTION 6: Check for header files
823dnl===
824dnl===-----------------------------------------------------------------------===
825
826dnl First, use autoconf provided macros for specific headers that we need
827dnl We don't check for ancient stuff or things that are guaranteed to be there
828dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
829dnl Generally we're looking for POSIX headers.
830AC_HEADER_DIRENT
831AC_HEADER_MMAP_ANONYMOUS
832AC_HEADER_STAT
833AC_HEADER_STDC
834AC_HEADER_SYS_WAIT
835AC_HEADER_TIME
836
837AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
838AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
839AC_CHECK_HEADERS([utime.h windows.h])
840AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
841AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
842if test "$ENABLE_THREADS" -eq 1 ; then
843  AC_CHECK_HEADERS(pthread.h,
844                   AC_SUBST(HAVE_PTHREAD, 1),
845                   AC_SUBST(HAVE_PTHREAD, 0))
846else
847  AC_SUBST(HAVE_PTHREAD, 0)
848fi
849
850dnl Try to find ffi.h.
851if test "$llvm_cv_enable_libffi" = "yes" ; then
852  AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
853fi
854
855dnl===-----------------------------------------------------------------------===
856dnl===
857dnl=== SECTION 7: Check for types and structures
858dnl===
859dnl===-----------------------------------------------------------------------===
860
861AC_HUGE_VAL_CHECK
862AC_TYPE_PID_T
863AC_TYPE_SIZE_T
864AC_TYPE_SIGNAL
865AC_STRUCT_TM
866AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
867AC_CHECK_TYPES([uint64_t],,
868         AC_CHECK_TYPES([u_int64_t],,
869         AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
870
871dnl===-----------------------------------------------------------------------===
872dnl===
873dnl=== SECTION 8: Check for specific functions needed
874dnl===
875dnl===-----------------------------------------------------------------------===
876
877AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
878AC_CHECK_FUNCS([powf fmodf strtof round ])
879AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
880AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
881AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
882AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
883AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
884AC_C_PRINTF_A
885AC_FUNC_ALLOCA
886AC_FUNC_RAND48
887
888dnl Check for variations in the Standard C++ library and STL. These macros are
889dnl provided by LLVM in the autoconf/m4 directory.
890AC_CXX_HAVE_STD_ITERATOR
891AC_CXX_HAVE_BI_ITERATOR
892AC_CXX_HAVE_FWD_ITERATOR
893AC_FUNC_ISNAN
894AC_FUNC_ISINF
895
896dnl Check for mmap support.We also need to know if /dev/zero is required to
897dnl be opened for allocating RWX memory.
898dnl Make sure we aren't attempting to configure for an unknown system
899if test "$llvm_cv_platform_type" = "Unix" ; then
900  AC_FUNC_MMAP
901  AC_FUNC_MMAP_FILE
902  AC_NEED_DEV_ZERO_FOR_MMAP
903
904  if test "$ac_cv_func_mmap_fixed_mapped" = "no"
905  then
906    AC_MSG_WARN([mmap() of a fixed address required but not supported])
907  fi
908  if test "$ac_cv_func_mmap_file" = "no"
909  then
910    AC_MSG_WARN([mmap() of files required but not found])
911  fi
912fi
913
914dnl atomic builtins are required for threading support.
915AC_MSG_CHECKING(for GCC atomic builtins)
916AC_LINK_IFELSE(
917  AC_LANG_SOURCE(
918    [[int main() { 
919        volatile unsigned long val = 1;
920        __sync_synchronize();
921        __sync_val_compare_and_swap(&val, 1, 0);
922        return 0;
923      }
924    ]]),
925  AC_MSG_RESULT(yes)
926  AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
927  AC_MSG_RESULT(no)
928  AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
929  AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
930
931
932dnl===-----------------------------------------------------------------------===
933dnl===
934dnl=== SECTION 9: Additional checks, variables, etc.
935dnl===
936dnl===-----------------------------------------------------------------------===
937
938dnl Check, whether __dso_handle is present
939AC_CHECK_FUNCS([__dso_handle])
940
941dnl See if the llvm-gcc executable can compile to LLVM assembly
942AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
943[llvm_cv_llvmgcc_sanity="no"
944if test -x "$LLVMGCC" ; then
945  cp /dev/null conftest.c
946  "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
947      grep 'target datalayout =' > /dev/null 2>&1
948  if test $? -eq 0 ; then
949    llvm_cv_llvmgcc_sanity="yes"
950  fi
951  rm conftest.c
952fi])
953
954dnl Since we have a sane llvm-gcc, identify it and its sub-tools
955if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
956  AC_MSG_CHECKING([llvm-gcc component support])
957  llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
958  AC_SUBST(LLVMCC1,$llvmcc1path)
959  llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
960  AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
961  llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
962  AC_SUBST(LLVMGCCDIR,$llvmgccdir)
963  llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
964  AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
965  llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
966  llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
967  AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
968  AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
969  llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
970  AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
971  AC_MSG_RESULT([ok])
972fi
973
974dnl Propagate the shared library extension that the libltdl checks did to
975dnl the Makefiles so we can use it there too
976AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
977
978# Translate the various configuration directories and other basic
979# information into substitutions that will end up in Makefile.config.in
980# that these configured values can be used by the makefiles
981if test "${prefix}" = "NONE" ; then
982  prefix="/usr/local"
983fi
984eval LLVM_PREFIX="${prefix}";
985eval LLVM_BINDIR="${prefix}/bin";
986eval LLVM_LIBDIR="${prefix}/lib";
987eval LLVM_DATADIR="${prefix}/share/llvm";
988eval LLVM_DOCSDIR="${prefix}/docs/llvm";
989eval LLVM_ETCDIR="${prefix}/etc/llvm";
990eval LLVM_INCLUDEDIR="${prefix}/include";
991eval LLVM_INFODIR="${prefix}/info";
992eval LLVM_MANDIR="${prefix}/man";
993LLVM_CONFIGTIME=`date`
994AC_SUBST(LLVM_PREFIX)
995AC_SUBST(LLVM_BINDIR)
996AC_SUBST(LLVM_LIBDIR)
997AC_SUBST(LLVM_DATADIR)
998AC_SUBST(LLVM_DOCSDIR)
999AC_SUBST(LLVM_ETCDIR)
1000AC_SUBST(LLVM_INCLUDEDIR)
1001AC_SUBST(LLVM_INFODIR)
1002AC_SUBST(LLVM_MANDIR)
1003AC_SUBST(LLVM_CONFIGTIME)
1004
1005# Place the various directores into the config.h file as #defines so that we
1006# can know about the installation paths within LLVM.
1007AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1008                   [Installation prefix directory])
1009AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1010                   [Installation directory for binary executables])
1011AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1012                   [Installation directory for libraries])
1013AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1014                   [Installation directory for data files])
1015AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1016                   [Installation directory for documentation])
1017AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1018                   [Installation directory for config files])
1019AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1020                   [Installation directory for include files])
1021AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1022                   [Installation directory for .info files])
1023AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1024                   [Installation directory for man pages])
1025AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1026                   [Time at which LLVM was configured])
1027AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1028                   [Host triple we were built on])
1029
1030# Determine which bindings to build.
1031if test "$BINDINGS_TO_BUILD" = auto ; then
1032  BINDINGS_TO_BUILD=""
1033  if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1034    BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1035  fi
1036fi
1037AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1038
1039# This isn't really configurey, but it avoids having to repeat the list in
1040# other files.
1041AC_SUBST(ALL_BINDINGS,ocaml)
1042
1043# Do any work necessary to ensure that bindings have what they need.
1044binding_prereqs_failed=0
1045for a_binding in $BINDINGS_TO_BUILD ; do
1046  case "$a_binding" in
1047  ocaml)
1048    if test "x$OCAMLC" = x ; then
1049      AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1050      binding_prereqs_failed=1
1051    fi
1052    if test "x$OCAMLDEP" = x ; then
1053      AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1054      binding_prereqs_failed=1
1055    fi
1056    if test "x$OCAMLOPT" = x ; then
1057      AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1058      dnl ocamlopt is optional!
1059    fi
1060    if test "x$with_ocaml_libdir" != xauto ; then
1061      AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1062    else
1063      ocaml_stdlib="`"$OCAMLC" -where`"
1064      if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1065      then
1066        # ocaml stdlib is beneath our prefix; use stdlib
1067        AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1068      else
1069        # ocaml stdlib is outside our prefix; use libdir/ocaml
1070        AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1071      fi
1072    fi
1073    ;;
1074  esac
1075done
1076if test "$binding_prereqs_failed" = 1 ; then
1077  AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1078fi
1079
1080dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1081AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1082
1083dnl Determine linker rpath flag
1084if test "$llvm_cv_link_use_r" = "yes" ; then
1085  RPATH="-Wl,-R"
1086else
1087  RPATH="-Wl,-rpath"
1088fi
1089AC_SUBST(RPATH)
1090
1091dnl Determine linker rdynamic flag
1092if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1093  RDYNAMIC="-Wl,-export-dynamic"
1094else
1095  RDYNAMIC=""
1096fi
1097AC_SUBST(RDYNAMIC)
1098
1099dnl===-----------------------------------------------------------------------===
1100dnl===
1101dnl=== SECTION 10: Specify the output files and generate it
1102dnl===
1103dnl===-----------------------------------------------------------------------===
1104
1105dnl Configure header files
1106dnl WARNING: dnl If you add or remove any of the following config headers, then
1107dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1108dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1109dnl files can be updated automatically when their *.in sources change.
1110AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1111AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1112AC_CONFIG_HEADERS([include/llvm/ADT/iterator.h])
1113
1114dnl Configure the makefile's configuration data
1115AC_CONFIG_FILES([Makefile.config])
1116
1117dnl Configure the RPM spec file for LLVM
1118AC_CONFIG_FILES([llvm.spec])
1119
1120dnl Configure doxygen's configuration file
1121AC_CONFIG_FILES([docs/doxygen.cfg])
1122
1123dnl Configure llvmc's Base plugin
1124AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1125
1126dnl Do the first stage of configuration for llvm-config.in.
1127AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1128
1129dnl Do special configuration of Makefiles
1130AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1131AC_CONFIG_MAKEFILE(Makefile)
1132AC_CONFIG_MAKEFILE(Makefile.common)
1133AC_CONFIG_MAKEFILE(examples/Makefile)
1134AC_CONFIG_MAKEFILE(lib/Makefile)
1135AC_CONFIG_MAKEFILE(runtime/Makefile)
1136AC_CONFIG_MAKEFILE(test/Makefile)
1137AC_CONFIG_MAKEFILE(test/Makefile.tests)
1138AC_CONFIG_MAKEFILE(unittests/Makefile)
1139AC_CONFIG_MAKEFILE(tools/Makefile)
1140AC_CONFIG_MAKEFILE(utils/Makefile)
1141AC_CONFIG_MAKEFILE(projects/Makefile)
1142AC_CONFIG_MAKEFILE(bindings/Makefile)
1143AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1144
1145dnl Finally, crank out the output
1146AC_OUTPUT
1147