pred_lt4_1_neon.s revision 41050cdb033641ddf26831d9272c0930f7b40a2d 
1@/*
2@ ** Copyright 2003-2010, VisualOn, Inc.
3@ **
4@ ** Licensed under the Apache License, Version 2.0 (the "License");
5@ ** you may not use this file except in compliance with the License.
6@ ** You may obtain a copy of the License at
7@ **
8@ **     http://www.apache.org/licenses/LICENSE-2.0
9@ **
10@ ** Unless required by applicable law or agreed to in writing, software
11@ ** distributed under the License is distributed on an "AS IS" BASIS,
12@ ** WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
13@ ** See the License for the specific language governing permissions and
14@ ** limitations under the License.
15@ */
16@
17@void Pred_lt4(
18@     Word16 exc[],                         /* in/out: excitation buffer */
19@     Word16 T0,                            /* input : integer pitch lag */
20@     Word16 frac,                          /* input : fraction of lag   */
21@     Word16 L_subfr                        /* input : subframe size     */
22@)
23@***********************************************************************
24@ r0    ---  exc[]
25@ r1    ---  T0
26@ r2    ---  frac
27@ r3    ---  L_subfr
28
29          .section  .text
30          .global   pred_lt4_asm
31          .extern   inter4_2
32
33pred_lt4_asm:
34
35          STMFD   	r13!, {r4 - r12, r14}
36          SUB           r4, r0, r1, LSL #1                        @ x = exc - T0
37          RSB           r2, r2, #0                                @ frac = - frac
38          SUB           r4, r4, #30                               @ x -= L_INTERPOL2 - 1
39          CMP           r2, #0
40          ADDLT         r2, r2, #4                                @ frac += UP_SAMP
41          SUBLT         r4, r4, #2                                @ x--
42
43          LDR           r11, Lable1
44          RSB           r2, r2, #3                                @ k = UP_SAMP - 1 - frac
45          MOV           r8, #0                                    @ j = 0
46	  ADD           r11, r11, r2, LSL #6                      @ get inter4_2[k][]
47
48	  VLD1.S16      {Q0, Q1}, [r11]!
49	  VLD1.S16      {Q2, Q3}, [r11]!
50
51	  MOV           r6, #0x8000
52
53          VLD1.S16      {Q4, Q5}, [r4]!                           @load 16 x[]
54          VLD1.S16      {Q6, Q7}, [r4]!                           @load 16 x[]
55
56LOOP:
57          VQDMULL.S16   Q15, D8, D0
58          VQDMLAL.S16   Q15, D9, D1
59          VQDMLAL.S16   Q15, D10, D2
60          VQDMLAL.S16   Q15, D11, D3
61
62          VQDMLAL.S16   Q15, D12, D4
63          VQDMLAL.S16   Q15, D13, D5
64          VQDMLAL.S16   Q15, D14, D6
65          VQDMLAL.S16   Q15, D15, D7
66
67          LDRSH         r12, [r4], #2
68
69          VEXT.S16      D8, D8, D9, #1
70          VEXT.S16      D9, D9, D10, #1
71          VEXT.S16      D10, D10, D11, #1
72          VEXT.S16      D11, D11, D12, #1
73          VDUP.S16      D24, r12
74          VEXT.S16      D12, D12, D13, #1
75          VEXT.S16      D13, D13, D14, #1
76
77          VQADD.S32     D30, D30, D31
78	  MOV           r11, #0x8000
79          VPADD.S32     D30, D30, D30
80          ADD           r8, r8, #1
81          VMOV.S32      r12, D30[0]
82          VEXT.S16      D14, D14, D15, #1
83
84          QADD          r1, r12, r12                              @ L_sum = (L_sum << 2)
85          VEXT.S16      D15, D15, D24, #1
86          QADD          r5, r1, r6
87          MOV           r1, r5, ASR #16
88          CMP           r8, r3
89          STRH          r1, [r0], #2                              @ exc[j] = (L_sum + 0x8000) >> 16
90          BLT           LOOP
91
92pred_lt4_end:
93
94          LDMFD   	r13!, {r4 - r12, r15}
95
96Lable1:
97          .word   	inter4_2
98          @ENDFUNC
99          .END
100
101