configure.ac revision ddd96a3fbc7c54146d1d831810fc9e29c9bc3c76 
1# -*- Autoconf -*-
2# Process this file with autoconf to produce a configure script.
3AC_PREREQ(2.65)
4
5AC_INIT([ltrace],[0.6.0],[ltrace-devel@lists.alioth.debian.org])
6AC_CONFIG_HEADERS([config.h])
7AC_CONFIG_SRCDIR(libltrace.c)
8AC_CONFIG_MACRO_DIR([config/m4])
9AC_CONFIG_AUX_DIR([config/autoconf])
10AC_CANONICAL_BUILD
11AC_CANONICAL_HOST
12
13case "${host_os}" in
14    linux-gnu*)	HOST_OS="linux-gnu" ;;
15    *)		AC_MSG_ERROR([unkown host-os ${host_os}]) ;;
16esac
17AC_SUBST(HOST_OS)
18
19case "${host_cpu}" in
20    arm*|sa110)		HOST_CPU="arm" ;;
21    powerpc|powerpc64)	HOST_CPU="ppc" ;;
22    sun4u|sparc64)	HOST_CPU="sparc" ;;
23    s390x)		HOST_CPU="s390" ;;
24    i?86|x86_64)	HOST_CPU="x86" ;;
25    *)			HOST_CPU="${host_cpu}" ;;
26esac
27AC_SUBST(HOST_CPU)
28
29# Checks for programs.
30AC_PROG_CC
31LT_INIT
32# libtool-2:  LT_INIT()
33AM_INIT_AUTOMAKE([foreign no-exeext dist-bzip2])
34AM_MAINTAINER_MODE
35
36AC_ARG_WITH([libelf],
37  AS_HELP_STRING([--with-libelf], [Prefix of libelf headers/library]),
38  [case "${withval}" in
39  (no)
40    AC_MSG_ERROR([*** libelf is a required dependency])
41    ;;
42  (yes)
43    AC_MSG_ERROR([*** --with-libelf requires you to specify a path])
44    ;;
45  (*)
46    AM_CPPFLAGS="${AM_CPPFLAGS} -I${withval}/include"
47    AM_LDFLAGS="${AM_LDFLAGS} -L${withval}/lib"
48    libelf_LD_LIBRARY_PATH="${withval}/lib"
49    ;;
50esac],[])
51
52# Checks for libraries.
53
54saved_CPPFLAGS="${CPPFLAGS}"
55saved_LDFLAGS="${LDFLAGS}"
56CPPFLAGS="${CPPFLAGS} ${AM_CPPFLAGS}"
57LDFLAGS="${LDFLAGS} ${AM_LDFLAGS}"
58# libelf
59AC_CHECK_HEADERS([elf.h gelf.h],,
60	[AC_MSG_ERROR([*** libelf.h or gelf.h not found on your system])]
61)
62AC_CHECK_LIB([elf], [elf_begin],,
63	[AC_MSG_ERROR([*** libelf not found on your system])]
64)
65CPPFLAGS="${saved_CPPFLAGS}"
66LDFLAGS="${saved_LDFLAGS}"
67
68
69# HAVE_LIBIBERTY
70AC_CHECK_LIB([iberty], [cplus_demangle], [
71	AC_DEFINE([HAVE_LIBIBERTY], [1], [we have libiberty])
72	liberty_LIBS="-liberty"], [
73	liberty_LIBS=""])
74AC_SUBST(liberty_LIBS)
75
76
77# HAVE_LIBSUPC__
78AC_CHECK_LIB([supc++], [__cxa_demangle], [
79	AC_DEFINE([HAVE_LIBSUPC__], [1], [we have libsupc++])
80	libsupcxx_LIBS="-lsupc++"], [
81	libsupcxx_LIBS=""])
82AC_SUBST(libsupcxx_LIBS)
83
84
85# HAVE_LIBSTDC__
86AC_CHECK_LIB([stdc++], [__cxa_demangle], [
87	AC_DEFINE([HAVE_LIBSTDC__], [1], [we have libstdc++])
88	libstdcxx_LIBS="-lstdc++"], [
89	libstdcxx_LIBS=""])
90AC_SUBST(libstdcxx_LIBS)
91
92
93dnl Check security_get_boolean_active availability.
94AC_CHECK_HEADERS(selinux/selinux.h)
95AC_CHECK_LIB(selinux, security_get_boolean_active)
96
97
98# HAVE_LIBUNWIND
99AC_ARG_WITH(libunwind,
100  AS_HELP_STRING([--with-libunwind], [Use libunwind frame unwinding support]),
101  [case "${withval}" in
102  (yes|no) enable_libunwind=$withval;;
103  (*) enable_libunwind=yes
104    AM_CPPFLAGS="${AM_CPPFLAGS} -I${withval}/include"
105    AM_LDFLAGS="${AM_LDFLAGS} -L${withval}/lib"
106    libunwind_LD_LIBRARY_PATH="${withval}/lib"
107    ;;
108esac],[enable_libunwind=maybe])
109
110saved_CPPFLAGS="${CPPFLAGS}"
111CPPFLAGS="${CPPFLAGS} ${AM_CPPFLAGS}"
112AC_CHECK_HEADERS([libunwind.h], [have_libunwind_h=yes])
113AC_CHECK_HEADERS([libunwind-ptrace.h], [have_libunwind_ptrace_h=yes])
114CPPFLAGS="${saved_CPPFLAGS}"
115
116AC_MSG_CHECKING([whether to use libunwind support])
117case "${enable_libunwind}" in
118(yes|maybe)
119  if test x$have_libunwind_h = xyes -o x$have_libunwind_ptrace_h = xyes; then
120    enable_libunwind=yes
121  elif test $enable_libunwind = maybe; then
122    enable_libunwind=no
123  else
124    AC_MSG_RESULT([$enable_libunwind])
125    AC_MSG_ERROR([libunwind.h or libunwind-ptrace.h cannot be found])	
126  fi
127  ;;
128(*) ;;
129esac
130AC_MSG_RESULT([$enable_libunwind])
131
132if test x"$enable_libunwind" = xyes; then
133  saved_LDFLAGS="${LDFLAGS}"
134  LDFLAGS="${LDFLAGS} ${AM_LDFLAGS}"
135  AC_CHECK_LIB(unwind, backtrace, libunwind_LIBS=-lunwind, libunwind_LIBS=)
136  AC_SUBST(libunwind_LIBS)
137  AC_CHECK_LIB(unwind-ptrace, _UPT_create, libunwind_ptrace_LIBS=-lunwind-ptrace, libunwind_ptrace_LIBS=)
138  AC_SUBST(libunwind_ptrace_LIBS)
139
140  case "${host_cpu}" in
141      arm*|sa110)         UNWIND_ARCH="arm" ;;
142      i?86)               UNWIND_ARCH="x86" ;;
143      powerpc)            UNWIND_ARCH="ppc32" ;;
144      ppc64)              UNWIND_ARCH="ppc64" ;;
145      mips*)              UNWIND_ARCH="mips" ;;
146      *)                  UNWIND_ARCH="${host_cpu}" ;;
147  esac
148
149  AC_CHECK_LIB(unwind-${UNWIND_ARCH}, _U${UNWIND_ARCH}_init_remote, libunwind_arch_LIBS=-lunwind-${UNWIND_ARCH}, libunwind_arch_LIBS=)
150  AC_SUBST(libunwind_arch_LIBS)
151  AC_DEFINE([HAVE_LIBUNWIND], [1], [we have libunwind])
152  LDFLAGS="${saved_LDFLAGS}"
153fi
154
155
156saved_CPPFLAGS="${CPPFLAGS}"
157saved_LDFLAGS="${LDFLAGS}"
158CPPFLAGS="${CPPFLAGS} ${AM_CPPFLAGS}"
159LDFLAGS="${LDFLAGS} ${AM_LDFLAGS}"
160# HAVE_ELF_C_READ_MMAP
161AC_MSG_CHECKING([whether elf_begin accepts ELF_C_READ_MMAP])
162AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <gelf.h>]], [[
163int main () {
164	Elf *elf = elf_begin(4, ELF_C_READ_MMAP, 0);
165	return 0;
166}
167	]])],[
168	AC_DEFINE([HAVE_ELF_C_READ_MMAP], [1], [we have read mmap support])
169	AC_MSG_RESULT([yes])],[
170	AC_MSG_RESULT([no])])
171
172saved_CFLAGS="${CFLAGS}"
173CFLAGS="${CFLAGS} -Wall -Werror"
174AC_MSG_CHECKING([whether elf_hash takes a char* argument])
175AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <libelf.h>]], [[
176	(void) elf_hash("name");
177	]])],
178	[AC_DEFINE([ELF_HASH_TAKES_CHARP], [1],
179		[elf_hash() takes char* (as opposed to unsigned char *)])
180	 AC_MSG_RESULT([yes])],
181	[AC_MSG_RESULT([no])])
182CFLAGS="${saved_CFLAGS}"
183CPPFLAGS="${saved_CPPFLAGS}"
184LDFLAGS="${saved_LDFLAGS}"
185
186AM_CPPFLAGS=" \
187	${AM_CPPFLAGS} \
188	-I\$(top_srcdir)/sysdeps/${HOST_OS}/${HOST_CPU} \
189	-I\$(top_srcdir)/sysdeps/${HOST_OS} \
190	-I\$(top_srcdir)/sysdeps \
191	-I\$(top_srcdir) \
192"
193
194# Checks for header files.
195AC_CHECK_HEADERS([ \
196	fcntl.h \
197	limits.h \
198	stddef.h \
199	stdint.h \
200	stdlib.h \
201	string.h \
202	sys/ioctl.h \
203	sys/param.h \
204	sys/time.h \
205	unistd.h \
206])
207
208# Checks for typedefs, structures, and compiler characteristics.
209AC_TYPE_UID_T
210AC_C_INLINE
211AC_TYPE_PID_T
212AC_TYPE_SIZE_T
213AC_CHECK_SIZEOF([long])
214
215
216# Checks for library functions.
217AC_FUNC_ERROR_AT_LINE
218AC_FUNC_FORK
219AC_CHECK_FUNCS([ \
220	alarm \
221	atexit \
222	getcwd \
223	gettimeofday \
224	memset \
225	mkdir \
226	rmdir \
227	strchr \
228	strdup \
229	strerror \
230	strtol \
231	strtoul \
232])
233
234
235#
236# Debugging
237#
238AC_MSG_CHECKING([whether to enable debugging])
239AC_ARG_ENABLE(debug,
240    AS_HELP_STRING([--enable-debug], [enable debugging @<:@default=no@:>@]),
241	[case "$enableval" in
242	y | yes) CONFIG_DEBUG=yes ;;
243        *) CONFIG_DEBUG=no ;;
244    esac],
245    [CONFIG_DEBUG=no])
246AC_MSG_RESULT([${CONFIG_DEBUG}])
247if test "${CONFIG_DEBUG}" = "yes"; then
248    AC_DEFINE(DEBUG, 1, [debugging])
249fi
250
251# Ignore the compiler's warnings at your own risk.
252AM_CFLAGS="${AM_CFLAGS} -Wall -Wsign-compare -Wfloat-equal -Wformat-security"
253AC_ARG_ENABLE([werror],
254    AS_HELP_STRING([--disable-werror], [disable use of -Werror]),
255    [enable_werror=$enableval], [enable_werror=yes])
256if test x$enable_werror = xyes; then
257    AM_CFLAGS="${AM_CFLAGS} -Werror"
258fi
259
260AC_SUBST(AM_CPPFLAGS)
261AC_SUBST(AM_CFLAGS)
262AC_SUBST(AM_LDFLAGS)
263AC_SUBST(libelf_LD_LIBRARY_PATH)
264AC_SUBST(libunwind_LD_LIBRARY_PATH)
265
266AC_CONFIG_FILES([
267	Makefile
268	sysdeps/Makefile
269	sysdeps/linux-gnu/Makefile
270	sysdeps/linux-gnu/${HOST_CPU}/Makefile
271	testsuite/Makefile
272	testsuite/ltrace.main/Makefile
273	testsuite/ltrace.minor/Makefile
274	testsuite/ltrace.torture/Makefile
275])
276AC_OUTPUT
277