fwd_txfm_ssse3_x86_64.asm revision 7ce0a1d1337c01056ba24006efab21f00e179e04 
1;
2;  Copyright (c) 2015 The WebM project authors. All Rights Reserved.
3;
4;  Use of this source code is governed by a BSD-style license
5;  that can be found in the LICENSE file in the root of the source
6;  tree. An additional intellectual property rights grant can be found
7;  in the file PATENTS.  All contributing project authors may
8;  be found in the AUTHORS file in the root of the source tree.
9;
10
11%include "third_party/x86inc/x86inc.asm"
12
13; This file provides SSSE3 version of the forward transformation. Part
14; of the macro definitions are originally derived from the ffmpeg project.
15; The current version applies to x86 64-bit only.
16
17SECTION_RODATA
18
19pw_11585x2: times 8 dw 23170
20pd_8192:    times 4 dd 8192
21
22%macro TRANSFORM_COEFFS 2
23pw_%1_%2:   dw  %1,  %2,  %1,  %2,  %1,  %2,  %1,  %2
24pw_%2_m%1:  dw  %2, -%1,  %2, -%1,  %2, -%1,  %2, -%1
25%endmacro
26
27TRANSFORM_COEFFS 11585,  11585
28TRANSFORM_COEFFS 15137,   6270
29TRANSFORM_COEFFS 16069,   3196
30TRANSFORM_COEFFS  9102,  13623
31
32SECTION .text
33
34%if ARCH_X86_64
35%macro SUM_SUB 3
36  psubw  m%3, m%1, m%2
37  paddw  m%1, m%2
38  SWAP    %2, %3
39%endmacro
40
41; butterfly operation
42%macro MUL_ADD_2X 6 ; dst1, dst2, src, round, coefs1, coefs2
43  pmaddwd            m%1, m%3, %5
44  pmaddwd            m%2, m%3, %6
45  paddd              m%1,  %4
46  paddd              m%2,  %4
47  psrad              m%1,  14
48  psrad              m%2,  14
49%endmacro
50
51%macro BUTTERFLY_4X 7 ; dst1, dst2, coef1, coef2, round, tmp1, tmp2
52  punpckhwd          m%6, m%2, m%1
53  MUL_ADD_2X         %7,  %6,  %6,  %5, [pw_%4_%3], [pw_%3_m%4]
54  punpcklwd          m%2, m%1
55  MUL_ADD_2X         %1,  %2,  %2,  %5, [pw_%4_%3], [pw_%3_m%4]
56  packssdw           m%1, m%7
57  packssdw           m%2, m%6
58%endmacro
59
60; matrix transpose
61%macro INTERLEAVE_2X 4
62  punpckh%1          m%4, m%2, m%3
63  punpckl%1          m%2, m%3
64  SWAP               %3,  %4
65%endmacro
66
67%macro TRANSPOSE8X8 9
68  INTERLEAVE_2X  wd, %1, %2, %9
69  INTERLEAVE_2X  wd, %3, %4, %9
70  INTERLEAVE_2X  wd, %5, %6, %9
71  INTERLEAVE_2X  wd, %7, %8, %9
72
73  INTERLEAVE_2X  dq, %1, %3, %9
74  INTERLEAVE_2X  dq, %2, %4, %9
75  INTERLEAVE_2X  dq, %5, %7, %9
76  INTERLEAVE_2X  dq, %6, %8, %9
77
78  INTERLEAVE_2X  qdq, %1, %5, %9
79  INTERLEAVE_2X  qdq, %3, %7, %9
80  INTERLEAVE_2X  qdq, %2, %6, %9
81  INTERLEAVE_2X  qdq, %4, %8, %9
82
83  SWAP  %2, %5
84  SWAP  %4, %7
85%endmacro
86
87; 1D forward 8x8 DCT transform
88%macro FDCT8_1D 1
89  SUM_SUB            0,  7,  9
90  SUM_SUB            1,  6,  9
91  SUM_SUB            2,  5,  9
92  SUM_SUB            3,  4,  9
93
94  SUM_SUB            0,  3,  9
95  SUM_SUB            1,  2,  9
96  SUM_SUB            6,  5,  9
97%if %1 == 0
98  SUM_SUB            0,  1,  9
99%endif
100
101  BUTTERFLY_4X       2,  3,  6270,  15137,  m8,  9,  10
102
103  pmulhrsw           m6, m12
104  pmulhrsw           m5, m12
105%if %1 == 0
106  pmulhrsw           m0, m12
107  pmulhrsw           m1, m12
108%else
109  BUTTERFLY_4X       1,  0,  11585, 11585,  m8,  9,  10
110  SWAP               0,  1
111%endif
112
113  SUM_SUB            4,  5,  9
114  SUM_SUB            7,  6,  9
115  BUTTERFLY_4X       4,  7,  3196,  16069,  m8,  9,  10
116  BUTTERFLY_4X       5,  6,  13623,  9102,  m8,  9,  10
117  SWAP               1,  4
118  SWAP               3,  6
119%endmacro
120
121%macro DIVIDE_ROUND_2X 4 ; dst1, dst2, tmp1, tmp2
122  psraw              m%3, m%1, 15
123  psraw              m%4, m%2, 15
124  psubw              m%1, m%3
125  psubw              m%2, m%4
126  psraw              m%1, 1
127  psraw              m%2, 1
128%endmacro
129
130INIT_XMM ssse3
131cglobal fdct8x8, 3, 5, 13, input, output, stride
132
133  mova               m8, [pd_8192]
134  mova              m12, [pw_11585x2]
135  pxor              m11, m11
136
137  lea                r3, [2 * strideq]
138  lea                r4, [4 * strideq]
139  mova               m0, [inputq]
140  mova               m1, [inputq + r3]
141  lea                inputq, [inputq + r4]
142  mova               m2, [inputq]
143  mova               m3, [inputq + r3]
144  lea                inputq, [inputq + r4]
145  mova               m4, [inputq]
146  mova               m5, [inputq + r3]
147  lea                inputq, [inputq + r4]
148  mova               m6, [inputq]
149  mova               m7, [inputq + r3]
150
151  ; left shift by 2 to increase forward transformation precision
152  psllw              m0, 2
153  psllw              m1, 2
154  psllw              m2, 2
155  psllw              m3, 2
156  psllw              m4, 2
157  psllw              m5, 2
158  psllw              m6, 2
159  psllw              m7, 2
160
161  ; column transform
162  FDCT8_1D  0
163  TRANSPOSE8X8 0, 1, 2, 3, 4, 5, 6, 7, 9
164
165  FDCT8_1D  1
166  TRANSPOSE8X8 0, 1, 2, 3, 4, 5, 6, 7, 9
167
168  DIVIDE_ROUND_2X   0, 1, 9, 10
169  DIVIDE_ROUND_2X   2, 3, 9, 10
170  DIVIDE_ROUND_2X   4, 5, 9, 10
171  DIVIDE_ROUND_2X   6, 7, 9, 10
172
173  mova              [outputq +   0], m0
174  mova              [outputq +  16], m1
175  mova              [outputq +  32], m2
176  mova              [outputq +  48], m3
177  mova              [outputq +  64], m4
178  mova              [outputq +  80], m5
179  mova              [outputq +  96], m6
180  mova              [outputq + 112], m7
181
182  RET
183%endif
184