__bionic_clone.S revision 36d6188f8cd8b948fb797f11d9620d63d0c2215a 
1/*
2 * Copyright (C) 2013 The Android Open Source Project
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions
7 * are met:
8 *  * Redistributions of source code must retain the above copyright
9 *    notice, this list of conditions and the following disclaimer.
10 *  * Redistributions in binary form must reproduce the above copyright
11 *    notice, this list of conditions and the following disclaimer in
12 *    the documentation and/or other materials provided with the
13 *    distribution.
14 *
15 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
16 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
17 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
18 * FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
19 * COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
20 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
21 * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS
22 * OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
23 * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
24 * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
25 * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
26 * SUCH DAMAGE.
27 */
28
29#include <asm/unistd.h>
30#include <machine/asm.h>
31
32// pid_t __bionic_clone(int flags, void* child_stack, pid_t* parent_tid, void* tls, pid_t* child_tid, int (*fn)(void*), void* arg);
33ENTRY(__bionic_clone)
34        # Enforce 16-byte alignment for child stack.
35        andq    $~15, %rsi
36
37        # Copy 'fn' and 'arg' onto the child stack.
38        movq    %r9, -16(%rsi)  # fn
39        movq    8(%rsp), %rax   # Read 'arg'.
40        movq    %rax, -8(%rsi)  # Write 'arg'.
41
42        subq    $16, %rsi
43
44        # Translate to the kernel calling convention and swap the 'tls' and 'child_tid' arguments.
45        # They're flipped for x86-64 compared to all our other architectures and __bionic_clone.
46        movq    %r8, %r10
47        movq    %rcx, %r8
48
49        # Make the system call.
50        movl    $__NR_clone, %eax
51        syscall
52        testl   %eax, %eax
53        jns     1f
54
55        # An error occurred, set errno and return -1.
56        negl    %eax
57        movl    %eax, %edi
58        call    __set_errno
59        orl     $-1, %eax
60        jmp     2f
611:
62        jnz     2f
63
64        # We're in the child now, so call __bionic_clone_entry
65        # with the arguments from the child stack moved into
66        # the appropriate registers.
67        popq    %rdi  # fn
68        popq    %rsi  # arg
69        call    __bionic_clone_entry
70        hlt
712:
72        ret
73