__bionic_clone.S revision 851e68a2402fa414544e66650e09dfdaac813e51 
1/*
2 * Copyright (C) 2013 The Android Open Source Project
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions
7 * are met:
8 *  * Redistributions of source code must retain the above copyright
9 *    notice, this list of conditions and the following disclaimer.
10 *  * Redistributions in binary form must reproduce the above copyright
11 *    notice, this list of conditions and the following disclaimer in
12 *    the documentation and/or other materials provided with the
13 *    distribution.
14 *
15 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
16 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
17 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
18 * FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
19 * COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
20 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
21 * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS
22 * OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
23 * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
24 * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
25 * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
26 * SUCH DAMAGE.
27 */
28
29#include <private/bionic_asm.h>
30
31// pid_t __bionic_clone(int flags, void* child_stack, pid_t* parent_tid, void* tls, pid_t* child_tid, int (*fn)(void*), void* arg);
32ENTRY(__bionic_clone)
33        # Enforce 16-byte alignment for child stack.
34        andq    $~15, %rsi
35
36        # Copy 'fn' and 'arg' onto the child stack.
37        movq    %r9, -16(%rsi)  # fn
38        movq    8(%rsp), %rax   # Read 'arg'.
39        movq    %rax, -8(%rsi)  # Write 'arg'.
40
41        subq    $16, %rsi
42
43        # Translate to the kernel calling convention and swap the 'tls' and 'child_tid' arguments.
44        # They're flipped for x86-64 compared to all our other architectures and __bionic_clone.
45        movq    %r8, %r10
46        movq    %rcx, %r8
47
48        # Make the system call.
49        movl    $__NR_clone, %eax
50        syscall
51        testl   %eax, %eax
52        jns     1f
53
54        # An error occurred, set errno and return -1.
55        negl    %eax
56        movl    %eax, %edi
57        call    __set_errno
58        orl     $-1, %eax
59        jmp     2f
601:
61        jnz     2f
62
63        # We're in the child now, so call __bionic_clone_entry
64        # with the arguments from the child stack moved into
65        # the appropriate registers.
66        popq    %rdi  # fn
67        popq    %rsi  # arg
68        call    __bionic_clone_entry
69        hlt
702:
71        ret
72END(__bionic_clone)
73