BUILD.gn revision 8aa4d2d2cd46bca6da7e071583482dd7ed0e2d0c 
1# Copyright (c) 2014 The WebRTC project authors. All Rights Reserved.
2#
3# Use of this source code is governed by a BSD-style license
4# that can be found in the LICENSE file in the root of the source
5# tree. An additional intellectual property rights grant can be found
6# in the file PATENTS.  All contributing project authors may
7# be found in the AUTHORS file in the root of the source tree.
8
9import("//build/config/arm.gni")
10import("../build/webrtc.gni")
11
12config("common_audio_config") {
13  include_dirs = [
14    "resampler/include",
15    "signal_processing/include",
16    "vad/include",
17  ]
18}
19
20source_set("common_audio") {
21  sources = [
22    "audio_converter.cc",
23    "audio_converter.h",
24    "audio_util.cc",
25    "blocker.cc",
26    "blocker.h",
27    "fir_filter.cc",
28    "fir_filter.h",
29    "fir_filter_neon.h",
30    "fir_filter_sse.h",
31    "include/audio_util.h",
32    "resampler/include/push_resampler.h",
33    "resampler/include/resampler.h",
34    "resampler/push_resampler.cc",
35    "resampler/push_sinc_resampler.cc",
36    "resampler/push_sinc_resampler.h",
37    "resampler/resampler.cc",
38    "resampler/sinc_resampler.cc",
39    "resampler/sinc_resampler.h",
40    "signal_processing/include/real_fft.h",
41    "signal_processing/include/signal_processing_library.h",
42    "signal_processing/include/spl_inl.h",
43    "signal_processing/auto_corr_to_refl_coef.c",
44    "signal_processing/auto_correlation.c",
45    "signal_processing/complex_fft_tables.h",
46    "signal_processing/copy_set_operations.c",
47    "signal_processing/cross_correlation.c",
48    "signal_processing/division_operations.c",
49    "signal_processing/dot_product_with_scale.c",
50    "signal_processing/downsample_fast.c",
51    "signal_processing/energy.c",
52    "signal_processing/filter_ar.c",
53    "signal_processing/filter_ma_fast_q12.c",
54    "signal_processing/get_hanning_window.c",
55    "signal_processing/get_scaling_square.c",
56    "signal_processing/ilbc_specific_functions.c",
57    "signal_processing/levinson_durbin.c",
58    "signal_processing/lpc_to_refl_coef.c",
59    "signal_processing/min_max_operations.c",
60    "signal_processing/randomization_functions.c",
61    "signal_processing/refl_coef_to_lpc.c",
62    "signal_processing/real_fft.c",
63    "signal_processing/resample.c",
64    "signal_processing/resample_48khz.c",
65    "signal_processing/resample_by_2.c",
66    "signal_processing/resample_by_2_internal.c",
67    "signal_processing/resample_by_2_internal.h",
68    "signal_processing/resample_fractional.c",
69    "signal_processing/spl_init.c",
70    "signal_processing/spl_sqrt.c",
71    "signal_processing/splitting_filter.c",
72    "signal_processing/sqrt_of_one_minus_x_squared.c",
73    "signal_processing/vector_scaling_operations.c",
74    "vad/include/vad.h",
75    "vad/include/webrtc_vad.h",
76    "vad/vad.cc",
77    "vad/webrtc_vad.c",
78    "vad/vad_core.c",
79    "vad/vad_core.h",
80    "vad/vad_filterbank.c",
81    "vad/vad_filterbank.h",
82    "vad/vad_gmm.c",
83    "vad/vad_gmm.h",
84    "vad/vad_sp.c",
85    "vad/vad_sp.h",
86    "wav_header.cc",
87    "wav_header.h",
88    "wav_writer.cc",
89    "wav_writer.h",
90    "window_generator.cc",
91    "window_generator.h",
92  ]
93
94  deps = [ "../system_wrappers" ]
95
96  if (rtc_use_openmax_dl) {
97    sources += [
98      "lapped_transform.cc",
99      "lapped_transform.h",
100      "real_fourier.cc",
101      "real_fourier.h",
102    ]
103
104    deps += [ "//third_party/openmax_dl/dl" ]
105  }
106
107  if (cpu_arch == "arm") {
108    sources += [
109      "signal_processing/complex_bit_reverse_arm.S",
110      "signal_processing/spl_sqrt_floor_arm.S",
111    ]
112
113    if (arm_version == 7) {
114      deps += [ ":common_audio_neon" ]
115      sources += [ "signal_processing/filter_ar_fast_q12_armv7.S" ]
116    } else {
117      sources += [ "signal_processing/filter_ar_fast_q12.c" ]
118    }
119  }
120
121  if (cpu_arch == "mipsel") {
122    sources += [
123      "signal_processing/include/spl_inl_mips.h",
124      "signal_processing/complex_bit_reverse_mips.c",
125      "signal_processing/complex_fft_mips.c",
126      "signal_processing/cross_correlation_mips.c",
127      "signal_processing/downsample_fast_mips.c",
128      "signal_processing/filter_ar_fast_q12_mips.c",
129      "signal_processing/min_max_operations_mips.c",
130      "signal_processing/resample_by_2_mips.c",
131      "signal_processing/spl_sqrt_floor_mips.c",
132    ]
133    if (mips_dsp_rev > 0) {
134      sources += [ "signal_processing/vector_scaling_operations_mips.c" ]
135    }
136  } else {
137    sources += [ "signal_processing/complex_fft.c" ]
138  }
139
140  if (cpu_arch != "arm" && cpu_arch != "mipsel") {
141    sources += [
142      "signal_processing/complex_bit_reverse.c",
143      "signal_processing/filter_ar_fast_q12.c",
144      "signal_processing/spl_sqrt_floor.c",
145    ]
146  }
147
148  if (is_win) {
149    cflags = [
150      "/wd4334",  # Ignore warning on shift operator promotion.
151    ]
152  }
153
154  configs += [ "..:common_config" ]
155
156  public_configs = [
157    "..:common_inherited_config",
158    ":common_audio_config",
159  ]
160
161  if (is_clang) {
162    # Suppress warnings from Chrome's Clang plugins.
163    # See http://code.google.com/p/webrtc/issues/detail?id=163 for details.
164    configs -= [ "//build/config/clang:find_bad_constructs" ]
165  }
166
167  if (cpu_arch == "x86" || cpu_arch == "x64") {
168    deps += [ ":common_audio_sse2" ]
169  }
170}
171
172if (cpu_arch == "x86" || cpu_arch == "x64") {
173  source_set("common_audio_sse2") {
174    sources = [
175      "fir_filter_sse.cc",
176      "resampler/sinc_resampler_sse.cc",
177    ]
178
179    cflags = [ "-msse2" ]
180
181    configs += [ "..:common_inherited_config" ]
182
183    if (is_clang) {
184      # Suppress warnings from Chrome's Clang plugins.
185      # See http://code.google.com/p/webrtc/issues/detail?id=163 for details.
186      configs -= [ "//build/config/clang:find_bad_constructs" ]
187    }
188  }
189}
190
191if (rtc_build_armv7_neon) {
192  source_set("common_audio_neon") {
193    sources = [
194      "fir_filter_neon.cc",
195      "resampler/sinc_resampler_neon.cc",
196      "signal_processing/cross_correlation_neon.S",
197      "signal_processing/downsample_fast_neon.S",
198      "signal_processing/min_max_operations_neon.S",
199      "signal_processing/vector_scaling_operations_neon.S",
200    ]
201
202    configs += [ "..:common_config" ]
203    public_configs = [ "..:common_inherited_config" ]
204
205
206    # Enable compilation for the ARM v7 Neon instruction set. This is needed
207    # since //build/config/arm.gni only enables Neon for iOS, not Android.
208    # This provides the same functionality as webrtc/build/arm_neon.gypi.
209    # TODO(kjellander): Investigate if this can be moved into webrtc.gni or
210    # //build/config/arm.gni instead, to reduce code duplication.
211    # Remove the -mfpu=vfpv3-d16 cflag.
212    configs -= [ "//build/config/compiler:compiler_arm_fpu" ]
213    cflags = [
214      "-flax-vector-conversions",
215      "-mfpu=neon",
216    ]
217
218    # Disable LTO in audio_processing_neon target due to compiler bug.
219    if (rtc_use_lto) {
220      cflags -= [
221        "-flto",
222        "-ffat-lto-objects",
223      ]
224    }
225
226    if (is_clang) {
227      # Suppress warnings from Chrome's Clang plugins.
228      # See http://code.google.com/p/webrtc/issues/detail?id=163 for details.
229      configs -= [ "//build/config/clang:find_bad_constructs" ]
230    }
231  }
232}
233