BUILD.gn revision ac4234ccfc964208163d6152977cc1d015448bbb 
1# Copyright (c) 2014 The WebRTC project authors. All Rights Reserved.
2#
3# Use of this source code is governed by a BSD-style license
4# that can be found in the LICENSE file in the root of the source
5# tree. An additional intellectual property rights grant can be found
6# in the file PATENTS.  All contributing project authors may
7# be found in the AUTHORS file in the root of the source tree.
8
9import("//build/config/arm.gni")
10import("../build/webrtc.gni")
11
12config("common_audio_config") {
13  include_dirs = [
14    "resampler/include",
15    "signal_processing/include",
16    "vad/include",
17  ]
18}
19
20source_set("common_audio") {
21  sources = [
22    "audio_converter.cc",
23    "audio_converter.h",
24    "audio_ring_buffer.cc",
25    "audio_ring_buffer.h",
26    "audio_util.cc",
27    "blocker.cc",
28    "blocker.h",
29    "channel_buffer.cc",
30    "channel_buffer.h",
31    "fft4g.c",
32    "fft4g.h",
33    "fir_filter.cc",
34    "fir_filter.h",
35    "fir_filter_neon.h",
36    "fir_filter_sse.h",
37    "include/audio_util.h",
38    "lapped_transform.cc",
39    "lapped_transform.h",
40    "real_fourier.cc",
41    "real_fourier.h",
42    "real_fourier_ooura.cc",
43    "real_fourier_ooura.h",
44    "resampler/include/push_resampler.h",
45    "resampler/include/resampler.h",
46    "resampler/push_resampler.cc",
47    "resampler/push_sinc_resampler.cc",
48    "resampler/push_sinc_resampler.h",
49    "resampler/resampler.cc",
50    "resampler/sinc_resampler.cc",
51    "resampler/sinc_resampler.h",
52    "ring_buffer.c",
53    "ring_buffer.h",
54    "signal_processing/auto_corr_to_refl_coef.c",
55    "signal_processing/auto_correlation.c",
56    "signal_processing/complex_fft_tables.h",
57    "signal_processing/copy_set_operations.c",
58    "signal_processing/cross_correlation.c",
59    "signal_processing/division_operations.c",
60    "signal_processing/dot_product_with_scale.c",
61    "signal_processing/downsample_fast.c",
62    "signal_processing/energy.c",
63    "signal_processing/filter_ar.c",
64    "signal_processing/filter_ma_fast_q12.c",
65    "signal_processing/get_hanning_window.c",
66    "signal_processing/get_scaling_square.c",
67    "signal_processing/ilbc_specific_functions.c",
68    "signal_processing/include/real_fft.h",
69    "signal_processing/include/signal_processing_library.h",
70    "signal_processing/include/spl_inl.h",
71    "signal_processing/levinson_durbin.c",
72    "signal_processing/lpc_to_refl_coef.c",
73    "signal_processing/min_max_operations.c",
74    "signal_processing/randomization_functions.c",
75    "signal_processing/real_fft.c",
76    "signal_processing/refl_coef_to_lpc.c",
77    "signal_processing/resample.c",
78    "signal_processing/resample_48khz.c",
79    "signal_processing/resample_by_2.c",
80    "signal_processing/resample_by_2_internal.c",
81    "signal_processing/resample_by_2_internal.h",
82    "signal_processing/resample_fractional.c",
83    "signal_processing/spl_init.c",
84    "signal_processing/spl_sqrt.c",
85    "signal_processing/splitting_filter.c",
86    "signal_processing/sqrt_of_one_minus_x_squared.c",
87    "signal_processing/vector_scaling_operations.c",
88    "sparse_fir_filter.cc",
89    "sparse_fir_filter.h",
90    "vad/include/vad.h",
91    "vad/include/webrtc_vad.h",
92    "vad/vad.cc",
93    "vad/vad_core.c",
94    "vad/vad_core.h",
95    "vad/vad_filterbank.c",
96    "vad/vad_filterbank.h",
97    "vad/vad_gmm.c",
98    "vad/vad_gmm.h",
99    "vad/vad_sp.c",
100    "vad/vad_sp.h",
101    "vad/webrtc_vad.c",
102    "wav_file.cc",
103    "wav_file.h",
104    "wav_header.cc",
105    "wav_header.h",
106    "window_generator.cc",
107    "window_generator.h",
108  ]
109
110  deps = [
111    "../system_wrappers",
112  ]
113
114  defines = []
115  if (rtc_use_openmax_dl) {
116    sources += [
117      "real_fourier_openmax.cc",
118      "real_fourier_openmax.h",
119    ]
120    defines += [ "RTC_USE_OPENMAX_DL" ]
121    if (rtc_build_openmax_dl) {
122      deps += [ "//third_party/openmax_dl/dl" ]
123    }
124  }
125
126  if (current_cpu == "arm") {
127    sources += [
128      "signal_processing/complex_bit_reverse_arm.S",
129      "signal_processing/spl_sqrt_floor_arm.S",
130    ]
131
132    if (arm_version >= 7) {
133      sources += [ "signal_processing/filter_ar_fast_q12_armv7.S" ]
134    } else {
135      sources += [ "signal_processing/filter_ar_fast_q12.c" ]
136    }
137  }
138
139  if (rtc_build_with_neon) {
140    deps += [ ":common_audio_neon" ]
141  }
142
143  if (current_cpu == "mipsel") {
144    sources += [
145      "signal_processing/complex_bit_reverse_mips.c",
146      "signal_processing/complex_fft_mips.c",
147      "signal_processing/cross_correlation_mips.c",
148      "signal_processing/downsample_fast_mips.c",
149      "signal_processing/filter_ar_fast_q12_mips.c",
150      "signal_processing/include/spl_inl_mips.h",
151      "signal_processing/min_max_operations_mips.c",
152      "signal_processing/resample_by_2_mips.c",
153      "signal_processing/spl_sqrt_floor_mips.c",
154    ]
155    if (mips_dsp_rev > 0) {
156      sources += [ "signal_processing/vector_scaling_operations_mips.c" ]
157    }
158  } else {
159    sources += [ "signal_processing/complex_fft.c" ]
160  }
161
162  if (current_cpu != "arm" && current_cpu != "mipsel") {
163    sources += [
164      "signal_processing/complex_bit_reverse.c",
165      "signal_processing/filter_ar_fast_q12.c",
166      "signal_processing/spl_sqrt_floor.c",
167    ]
168  }
169
170  if (is_win) {
171    cflags = [ "/wd4334" ]  # Ignore warning on shift operator promotion.
172  }
173
174  configs += [ "..:common_config" ]
175
176  public_configs = [
177    "..:common_inherited_config",
178    ":common_audio_config",
179  ]
180
181  if (is_clang) {
182    # Suppress warnings from Chrome's Clang plugins.
183    # See http://code.google.com/p/webrtc/issues/detail?id=163 for details.
184    configs -= [ "//build/config/clang:find_bad_constructs" ]
185  }
186
187  if (current_cpu == "x86" || current_cpu == "x64") {
188    deps += [ ":common_audio_sse2" ]
189  }
190}
191
192if (current_cpu == "x86" || current_cpu == "x64") {
193  source_set("common_audio_sse2") {
194    sources = [
195      "fir_filter_sse.cc",
196      "resampler/sinc_resampler_sse.cc",
197    ]
198
199    if (is_posix) {
200      cflags = [ "-msse2" ]
201    }
202
203    configs += [ "..:common_inherited_config" ]
204
205    if (is_clang) {
206      # Suppress warnings from Chrome's Clang plugins.
207      # See http://code.google.com/p/webrtc/issues/detail?id=163 for details.
208      configs -= [ "//build/config/clang:find_bad_constructs" ]
209    }
210  }
211}
212
213if (rtc_build_with_neon) {
214  source_set("common_audio_neon") {
215    sources = [
216      "fir_filter_neon.cc",
217      "resampler/sinc_resampler_neon.cc",
218      "signal_processing/cross_correlation_neon.c",
219      "signal_processing/downsample_fast_neon.c",
220      "signal_processing/min_max_operations_neon.c",
221    ]
222
223    if (current_cpu != "arm64") {
224      # Enable compilation for the NEON instruction set. This is needed
225      # since //build/config/arm.gni only enables NEON for iOS, not Android.
226      # This provides the same functionality as webrtc/build/arm_neon.gypi.
227      configs -= [ "//build/config/compiler:compiler_arm_fpu" ]
228      cflags = [ "-mfpu=neon" ]
229    }
230
231    # Disable LTO on NEON targets due to compiler bug.
232    # TODO(fdegans): Enable this. See crbug.com/408997.
233    if (rtc_use_lto) {
234      cflags -= [
235        "-flto",
236        "-ffat-lto-objects",
237      ]
238    }
239
240    configs += [ "..:common_config" ]
241    public_configs = [ "..:common_inherited_config" ]
242  }
243}
244