configure.ac revision aac5f4514f71d04ac3dcb8b923209781895d7ff2 
1AC_PREREQ(2.60)
2AC_INIT([kmod],
3	[19],
4	[linux-modules@vger.kernel.org],
5	[kmod],
6	[http://git.kernel.org/?p=utils/kernel/kmod/kmod.git])
7
8AC_CONFIG_SRCDIR([libkmod/libkmod.c])
9AC_CONFIG_AUX_DIR([build-aux])
10AM_INIT_AUTOMAKE([check-news foreign 1.11 silent-rules
11	tar-pax no-dist-gzip dist-xz subdir-objects color-tests parallel-tests])
12AC_PROG_CC_STDC
13AC_USE_SYSTEM_EXTENSIONS
14AC_SYS_LARGEFILE
15AC_CONFIG_MACRO_DIR([m4])
16m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
17AM_SILENT_RULES([yes])
18LT_INIT([disable-static pic-only])
19AC_PREFIX_DEFAULT([/usr])
20AM_MAINTAINER_MODE([enable])
21
22AS_IF([test "x$enable_static" = "xyes"],
23      [AC_MSG_ERROR([--enable-static is not supported by kmod])])
24
25
26#####################################################################
27# Program checks and configurations
28#####################################################################
29
30AC_PROG_CC
31AC_PROG_CC_C99
32AM_PROG_CC_C_O
33AC_PROG_GCC_TRADITIONAL
34AC_C_BIGENDIAN
35
36AC_PROG_SED
37AC_PROG_MKDIR_P
38PKG_PROG_PKG_CONFIG
39AC_PATH_PROG([XSLTPROC], [xsltproc])
40
41
42#####################################################################
43# Function and structure checks
44#####################################################################
45
46AC_CHECK_FUNCS_ONCE(__xstat)
47AC_CHECK_FUNCS_ONCE([__secure_getenv secure_getenv])
48AC_CHECK_FUNCS_ONCE([finit_module])
49
50CC_CHECK_FUNC_BUILTIN([__builtin_clz])
51CC_CHECK_FUNC_BUILTIN([__builtin_types_compatible_p])
52CC_CHECK_FUNC_BUILTIN([__builtin_uaddl_overflow], [ ], [ ])
53CC_CHECK_FUNC_BUILTIN([__builtin_uaddll_overflow], [ ], [ ])
54
55# dietlibc doesn't have st.st_mtim struct member
56AC_CHECK_MEMBERS([struct stat.st_mtim], [], [], [#include <sys/stat.h>])
57
58# musl 1.0 and bionic 4.4 don't have strndupa
59AC_CHECK_DECLS_ONCE([strndupa])
60
61# RHEL 5 and older do not have be32toh
62AC_CHECK_DECLS_ONCE([be32toh])
63
64# Check kernel headers
65AC_CHECK_HEADERS_ONCE([linux/module.h])
66
67AC_MSG_CHECKING([whether _Static_assert() is supported])
68AC_COMPILE_IFELSE(
69	[AC_LANG_SOURCE([[_Static_assert(1, "Test");]])],
70        [AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define if _Static_assert() is available])
71	 AC_MSG_RESULT([yes])],
72	[AC_MSG_RESULT([no])])
73
74#####################################################################
75# --with-
76#####################################################################
77
78AC_ARG_WITH([rootlibdir],
79        AS_HELP_STRING([--with-rootlibdir=DIR], [rootfs directory to install shared libraries]),
80        [], [with_rootlibdir=$libdir])
81AC_SUBST([rootlibdir], [$with_rootlibdir])
82
83AC_ARG_WITH([xz],
84	AS_HELP_STRING([--with-xz], [handle Xz-compressed modules @<:@default=disabled@:>@]),
85	[], [with_xz=no])
86AS_IF([test "x$with_xz" != "xno"], [
87	PKG_CHECK_MODULES([liblzma], [liblzma >= 4.99])
88	AC_DEFINE([ENABLE_XZ], [1], [Enable Xz for modules.])
89], [
90	AC_MSG_NOTICE([Xz support not requested])
91])
92
93AC_ARG_WITH([zlib],
94	AS_HELP_STRING([--with-zlib], [handle gzipped modules @<:@default=disabled@:>@]),
95	[], [with_zlib=no])
96AS_IF([test "x$with_zlib" != "xno"], [
97	PKG_CHECK_MODULES([zlib], [zlib])
98	AC_DEFINE([ENABLE_ZLIB], [1], [Enable zlib for modules.])
99], [
100	AC_MSG_NOTICE([zlib support not requested])
101])
102
103AC_ARG_WITH([bashcompletiondir],
104	AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
105	[],
106	[AS_IF([$($PKG_CONFIG --exists bash-completion)], [
107		with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
108	] , [
109		with_bashcompletiondir=${datadir}/bash-completion/completions
110	])])
111AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
112
113#####################################################################
114# --enable-
115#####################################################################
116
117AC_ARG_ENABLE([tools],
118        AS_HELP_STRING([--disable-tools], [disable building tools that provide same functionality as module-init-tools @<:@default=enabled@:>@]),
119	[], enable_tools=yes)
120AM_CONDITIONAL([BUILD_TOOLS], [test "x$enable_tools" = "xyes"])
121
122AC_ARG_ENABLE([manpages],
123        AS_HELP_STRING([--disable-manpages], [disable manpages @<:@default=enabled@:>@]),
124	[], enable_manpages=yes)
125AM_CONDITIONAL([BUILD_MANPAGES], [test "x$enable_manpages" = "xyes"])
126
127AC_ARG_ENABLE([logging],
128	AS_HELP_STRING([--disable-logging], [disable system logging @<:@default=enabled@:>@]),
129	[], enable_logging=yes)
130AS_IF([test "x$enable_logging" = "xyes"], [
131	AC_DEFINE(ENABLE_LOGGING, [1], [System logging.])
132])
133
134AC_ARG_ENABLE([debug],
135	AS_HELP_STRING([--enable-debug], [enable debug messages @<:@default=disabled@:>@]),
136	[], [enable_debug=no])
137AS_IF([test "x$enable_debug" = "xyes"], [
138	AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
139])
140
141AC_ARG_ENABLE([python],
142	AS_HELP_STRING([--enable-python], [enable Python libkmod bindings @<:@default=disabled@:>@]),
143	[], [enable_python=no])
144AS_IF([test "x$enable_python" = "xyes"], [
145	AM_PATH_PYTHON(,,[:])
146	AC_PATH_PROG([CYTHON], [cython], [:])
147
148	PKG_CHECK_MODULES([PYTHON], [python-${PYTHON_VERSION}],
149			  [have_python=yes],
150			  [PKG_CHECK_MODULES([PYTHON], [python],
151					     [have_python=yes],
152					     [have_python=no])])
153
154	AS_IF([test "x$have_python" = xno],
155	      [AC_MSG_ERROR([*** python support requested but libraries not found])])
156])
157AM_CONDITIONAL([BUILD_PYTHON], [test "x$enable_python" = "xyes"])
158
159AC_ARG_ENABLE([coverage],
160	AS_HELP_STRING([--enable-coverage], [enable test coverage @<:@default=disabled@:>@]),
161	[], [enable_coverage=no])
162AS_IF([test "x$enable_coverage" = "xyes"], [
163	AC_CHECK_PROG(have_coverage, [lcov], [yes], [no])
164	AS_IF([test "x$have_coverage" = xno],[
165		AC_MSG_ERROR([*** lcov support requested but the program was not found])
166	], [
167		lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
168		lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
169		AS_IF([test "$lcov_version_major" -lt 1 -o "$lcov_version_minor" -lt 10], [
170			AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
171		], [
172			have_coverage=yes
173                        CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
174                        -fprofile-arcs \
175                        -ftest-coverage])
176		])
177        ])
178])
179AM_CONDITIONAL([ENABLE_COVERAGE], [test "x$enable_coverage" = "xyes"])
180
181m4_ifdef([GTK_DOC_CHECK], [
182GTK_DOC_CHECK([1.14],[--flavour no-tmpl-flat])
183], [
184AM_CONDITIONAL([ENABLE_GTK_DOC], false)])
185
186
187#####################################################################
188# Default CFLAGS and LDFLAGS
189#####################################################################
190
191CC_CHECK_FLAGS_APPEND(with_cflags, [CFLAGS], [\
192		       -pipe \
193		       -DANOTHER_BRICK_IN_THE \
194		       -Wall \
195		       -W \
196		       -Wextra \
197		       -Wno-inline \
198		       -Wvla \
199		       -Wundef \
200		       -Wformat=2 \
201		       -Wlogical-op \
202		       -Wsign-compare \
203		       -Wformat-security \
204		       -Wmissing-include-dirs \
205		       -Wformat-nonliteral \
206		       -Wold-style-definition \
207		       -Wpointer-arith \
208		       -Winit-self \
209		       -Wdeclaration-after-statement \
210		       -Wfloat-equal \
211		       -Wmissing-prototypes \
212		       -Wstrict-prototypes \
213		       -Wredundant-decls \
214		       -Wmissing-declarations \
215		       -Wmissing-noreturn \
216		       -Wshadow \
217		       -Wendif-labels \
218		       -Wstrict-aliasing=3 \
219		       -Wwrite-strings \
220		       -Wno-long-long \
221		       -Wno-overlength-strings \
222		       -Wno-unused-parameter \
223		       -Wno-missing-field-initializers \
224		       -Wno-unused-result \
225		       -Wnested-externs \
226		       -Wchar-subscripts \
227		       -Wtype-limits \
228		       -Wuninitialized \
229		       -fno-common \
230		       -fdiagnostics-show-option \
231		       -fvisibility=hidden \
232		       -ffunction-sections \
233		       -fdata-sections])
234AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
235
236
237CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [ \
238		       -Wl,--as-needed \
239		       -Wl,--no-undefined \
240		       -Wl,--gc-sections])
241AC_SUBST([OUR_LDFLAGS], $with_ldflags)
242
243#####################################################################
244# Generate files from *.in
245#####################################################################
246
247AC_CONFIG_HEADERS(config.h)
248AC_CONFIG_FILES([
249	Makefile
250	man/Makefile
251	libkmod/docs/Makefile
252	libkmod/docs/version.xml
253])
254
255
256#####################################################################
257
258AC_OUTPUT
259AC_MSG_RESULT([
260	$PACKAGE $VERSION
261	=======
262
263	prefix:			${prefix}
264	sysconfdir:		${sysconfdir}
265	libdir:			${libdir}
266	rootlibdir:		${rootlibdir}
267	includedir:		${includedir}
268	bindir:			${bindir}
269	Bash completions dir:   ${with_bashcompletiondir}
270
271	compiler:		${CC}
272	cflags:			${with_cflags} ${CFLAGS}
273	ldflags:		${with_ldflags} ${LDFLAGS}
274
275	tools:			${enable_tools}
276	python bindings:	${enable_python}
277	logging:		${enable_logging}
278	compression:		xz=${with_xz}  zlib=${with_zlib}
279	debug:			${enable_debug}
280	coverage:		${enable_coverage}
281	doc:			${enable_gtk_doc}
282	man:			${enable_manpages}
283])
284