configure.ac revision 68a086a1479233654423409b2aa6c0047f3c7f57 
1#                                               -*- Autoconf -*-
2# Process this file with autoconf to produce a configure script.
3
4AC_PREREQ([2.56])
5AC_INIT([libjpeg-turbo], [1.1.2])
6BUILD=`date +%Y%m%d`
7
8AM_INIT_AUTOMAKE([-Wall foreign dist-bzip2])
9AC_PREFIX_DEFAULT(/opt/libjpeg-turbo)
10
11# Always build with prototypes
12AC_DEFINE([HAVE_PROTOTYPES], 1, [Define if your compiler supports prototypes])
13
14# Checks for programs.
15SAVED_CFLAGS=${CFLAGS}
16SAVED_CPPFLAGS=${CPPFLAGS}
17AC_PROG_CPP
18AC_PROG_CC
19AC_PROG_INSTALL
20AC_PROG_LIBTOOL
21AC_PROG_LN_S
22
23# Check whether compiler supports pointers to undefined structures
24AC_MSG_CHECKING(whether compiler supports pointers to undefined structures)
25AC_TRY_COMPILE([ typedef struct undefined_structure * undef_struct_ptr; ], ,
26AC_MSG_RESULT(yes),
27[AC_MSG_RESULT(no)
28AC_DEFINE([INCOMPLETE_TYPES_BROKEN],[1],[Compiler does not support pointers to undefined structures.])])
29
30if test "x${GCC}" = "xyes"; then
31  if test "x${SAVED_CFLAGS}" = "x"; then
32    CFLAGS=-O3
33  fi
34  if test "x${SAVED_CPPFLAGS}" = "x"; then
35    CPPFLAGS=-Wall
36  fi
37fi
38
39AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
40if test "x${SUNCC}" = "xyes"; then
41  if test "x${SAVED_CFLAGS}" = "x"; then
42    CFLAGS=-xO5
43  fi
44fi
45
46# Checks for libraries.
47
48# Checks for header files.
49AC_HEADER_STDC
50AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
51AC_CHECK_HEADER([sys/types.h], AC_DEFINE([NEED_SYS_TYPES_H], 1, [Define if you have sys/types.h]))
52
53# Checks for typedefs, structures, and compiler characteristics.
54AC_C_CONST
55AC_C_CHAR_UNSIGNED
56AC_C_INLINE
57AC_TYPE_SIZE_T
58AC_CHECK_TYPES([unsigned char, unsigned short])
59
60AC_MSG_CHECKING([if right shift is signed])
61AC_TRY_RUN(
62	[#include <stdio.h>
63	 int is_shifting_signed (long arg) {
64	 long res = arg >> 4;
65
66	 if (res == -0x7F7E80CL)
67		return 1; /* right shift is signed */
68
69	 /* see if unsigned-shift hack will fix it. */
70	 /* we can't just test exact value since it depends on width of long... */
71	 res |= (~0L) << (32-4);
72	 if (res == -0x7F7E80CL)
73		return 0; /* right shift is unsigned */
74
75	 printf("Right shift isn't acting as I expect it to.\n");
76	 printf("I fear the JPEG software will not work at all.\n\n");
77	 return 0; /* try it with unsigned anyway */
78	 }
79	 int main (void) {
80		exit(is_shifting_signed(-0x7F7E80B1L));
81	 }],
82	[AC_MSG_RESULT(no)
83	 AC_DEFINE([RIGHT_SHIFT_IS_UNSIGNED], 1, [Define if shift is unsigned])],
84	[AC_MSG_RESULT(yes)],
85	[AC_MSG_RESULT(Assuming that right shift is signed on target machine.)])
86
87# test whether global names are unique to at least 15 chars
88AC_MSG_CHECKING([for short external names])
89AC_TRY_LINK(
90	[int possibly_duplicate_function () { return 0; }
91	 int possibly_dupli_function () { return 1; }], [ ],
92	[AC_MSG_RESULT(ok)],
93	[AC_MSG_RESULT(short)
94	 AC_DEFINE([NEED_SHORT_EXTERNAL_NAMES], 1, [Define if you need short function names])])
95
96# Checks for library functions.
97AC_CHECK_FUNCS([memset memcpy], [],
98	[AC_DEFINE([NEED_BSD_STRINGS], 1,
99		   [Define if you have BSD-like bzero and bcopy])])
100
101AC_MSG_CHECKING([libjpeg API version])
102AC_ARG_VAR(JPEG_LIB_VERSION, [libjpeg API version (62, 70, or 80)])
103if test "x$JPEG_LIB_VERSION" = "x"; then
104    AC_ARG_WITH([jpeg7],
105        AC_HELP_STRING([--with-jpeg7], [Emulate libjpeg v7 API/ABI (this makes libjpeg-turbo backward incompatible with libjpeg v6b.)]))
106    AC_ARG_WITH([jpeg8],
107        AC_HELP_STRING([--with-jpeg8], [Emulate libjpeg v8 API/ABI (this makes libjpeg-turbo backward incompatible with libjpeg v6b.)]))
108    if test "x${with_jpeg8}" = "xyes"; then
109        JPEG_LIB_VERSION=80
110    else
111        if test "x${with_jpeg7}" = "xyes"; then
112            JPEG_LIB_VERSION=70
113        else
114            JPEG_LIB_VERSION=62
115        fi
116    fi
117fi
118JPEG_LIB_VERSION_DECIMAL=`expr $JPEG_LIB_VERSION / 10`.`expr $JPEG_LIB_VERSION % 10`
119AC_SUBST(JPEG_LIB_VERSION_DECIMAL)
120AC_MSG_RESULT([$JPEG_LIB_VERSION_DECIMAL])
121AC_DEFINE_UNQUOTED(JPEG_LIB_VERSION, [$JPEG_LIB_VERSION], [libjpeg API version])
122
123AC_MSG_CHECKING([libjpeg shared library version])
124AC_ARG_VAR(SO_MAJOR_VERSION, [Major version of the libjpeg-turbo shared library (default is determined by the API version)])
125AC_ARG_VAR(SO_MINOR_VERSION, [Minor version of the libjpeg-turbo shared library (default is determined by the API version)])
126if test "x$SO_MAJOR_VERSION" = "x"; then
127    case "$JPEG_LIB_VERSION" in
128        62)  SO_MAJOR_VERSION=$JPEG_LIB_VERSION ;;
129        *)   SO_MAJOR_VERSION=`expr $JPEG_LIB_VERSION / 10` ;;
130    esac
131fi
132if test "x$SO_MINOR_VERSION" = "x"; then
133    case "$JPEG_LIB_VERSION" in
134        80)  SO_MINOR_VERSION=2 ;;
135        *)   SO_MINOR_VERSION=0 ;;
136    esac
137fi
138AC_MSG_RESULT([$SO_MAJOR_VERSION:$SO_MINOR_VERSION])
139AC_SUBST(SO_MAJOR_VERSION)
140AC_SUBST(SO_MINOR_VERSION)
141
142VERSION_SCRIPT=yes
143AC_ARG_ENABLE([ld-version-script],
144  AS_HELP_STRING([--disable-ld-version-script],
145    [Disable linker version script for libjpeg-turbo (default is to use linker version script if the linker supports it)]),
146    [VERSION_SCRIPT=$enableval], [])
147
148AC_MSG_CHECKING([whether the linker supports version scripts])
149SAVED_LDFLAGS="$LDFLAGS"
150LDFLAGS="$LDFLAGS -Wl,--version-script,conftest.map"
151cat > conftest.map <<EOF
152VERS_1 {
153  global: *;
154};
155EOF
156AC_LINK_IFELSE(AC_LANG_PROGRAM([], []),
157  [VERSION_SCRIPT_FLAG=-Wl,--version-script,; AC_MSG_RESULT([yes (GNU style)])], [])
158if test "x$VERSION_SCRIPT_FLAG" = "x"; then
159  LDFLAGS="$SAVED_LDFLAGS -Wl,-M,conftest.map"
160  AC_LINK_IFELSE(AC_LANG_PROGRAM([], []),
161    [VERSION_SCRIPT_FLAG=-Wl,-M,; AC_MSG_RESULT([yes (Sun style)])], [])
162fi
163if test "x$VERSION_SCRIPT_FLAG" = "x"; then
164  VERSION_SCRIPT=no
165  AC_MSG_RESULT(no)
166fi
167LDFLAGS="$SAVED_LDFLAGS"
168
169AC_MSG_CHECKING([whether to use version script when building libjpeg-turbo])
170AC_MSG_RESULT($VERSION_SCRIPT)
171
172AM_CONDITIONAL(VERSION_SCRIPT, test "x$VERSION_SCRIPT" = "xyes")
173AC_SUBST(VERSION_SCRIPT_FLAG)
174
175AC_MSG_CHECKING([whether to include arithmetic encoding support])
176AC_ARG_WITH([arith-enc],
177    AC_HELP_STRING([--without-arith-enc], [Omit arithmetic encoding support]))
178if test "x$with_arith_enc" = "xno"; then
179    AC_MSG_RESULT(no)
180else
181    AC_DEFINE([C_ARITH_CODING_SUPPORTED], [1], [Support arithmetic encoding])
182    AC_MSG_RESULT(yes)
183fi
184AM_CONDITIONAL([WITH_ARITH_ENC], [test "x$with_arith_enc" != "xno"])
185
186AC_MSG_CHECKING([whether to include arithmetic decoding support])
187AC_ARG_WITH([arith-dec],
188    AC_HELP_STRING([--without-arith-dec], [Omit arithmetic decoding support]))
189if test "x$with_arith_dec" = "xno"; then
190    AC_MSG_RESULT(no)
191else
192    AC_DEFINE([D_ARITH_CODING_SUPPORTED], [1], [Support arithmetic decoding])
193    AC_MSG_RESULT(yes)
194fi
195AM_CONDITIONAL([WITH_ARITH_DEC], [test "x$with_arith_dec" != "xno"])
196
197AM_CONDITIONAL([WITH_ARITH], [test "x$with_arith_dec" != "xno" -o "x$with_arith_enc" != "xno"])
198
199# SIMD is optional
200AC_ARG_WITH([simd],
201    AC_HELP_STRING([--without-simd],[Omit SIMD extensions.]))
202if test "x${with_simd}" != "xno"; then
203  # Check if we're on a supported CPU
204  AC_MSG_CHECKING([if we have SIMD optimisations for cpu type])
205  case "$host_cpu" in
206    x86_64 | amd64)
207      AC_MSG_RESULT([yes (x86_64)])
208      AC_PROG_NASM
209      simd_arch=x86_64
210    ;;
211    i*86 | x86 | ia32)
212      AC_MSG_RESULT([yes (i386)])
213      AC_PROG_NASM
214      simd_arch=i386
215    ;;
216    *)
217      AC_MSG_RESULT([no ("$host_cpu")])
218      AC_MSG_WARN([SIMD support not available for this CPU.  Performance will suffer.])
219      with_simd=no;
220    ;;
221  esac
222
223  if test "x${with_simd}" != "xno"; then
224    AC_DEFINE([WITH_SIMD], [1], [Use accelerated SIMD routines.])
225  fi
226fi
227
228AM_CONDITIONAL([WITH_SIMD], [test "x$with_simd" != "xno"])
229AM_CONDITIONAL([SIMD_I386], [test "x$simd_arch" = "xi386"])
230AM_CONDITIONAL([SIMD_X86_64], [test "x$simd_arch" = "xx86_64"])
231AM_CONDITIONAL([X86_64], [test "x$host_cpu" = "xx86_64" -o "x$host_cpu" = "xamd64"])
232
233case "$host_cpu" in
234  x86_64)
235    RPMARCH=x86_64
236    DEBARCH=amd64
237    ;;
238  i*86 | x86 | ia32)
239    RPMARCH=i386
240    DEBARCH=i386
241    ;;
242esac
243
244AC_SUBST(RPMARCH)
245AC_SUBST(DEBARCH)
246AC_SUBST(BUILD)
247AC_DEFINE_UNQUOTED([BUILD], "$BUILD", [Build number])
248
249# jconfig.h is the file we use, but we have another before that to
250# fool autoheader. the reason is that we include this header in our
251# API headers, which can screw things up for users of the lib.
252# jconfig.h is a minimal version that allows this package to be built
253AC_CONFIG_HEADERS([config.h])
254AC_CONFIG_HEADERS([jconfig.h])
255AC_CONFIG_FILES([pkgscripts/libjpeg-turbo.spec:release/libjpeg-turbo.spec.in])
256AC_CONFIG_FILES([pkgscripts/makecygwinpkg:release/makecygwinpkg.in])
257AC_CONFIG_FILES([pkgscripts/makedpkg:release/makedpkg.in])
258AC_CONFIG_FILES([pkgscripts/makemacpkg:release/makemacpkg.in])
259AC_CONFIG_FILES([pkgscripts/Description.plist:release/Description.plist.in])
260AC_CONFIG_FILES([pkgscripts/Info.plist:release/Info.plist.in])
261AC_CONFIG_FILES([pkgscripts/uninstall:release/uninstall.in])
262AC_CONFIG_FILES([pkgscripts/makesunpkg:release/makesunpkg.in])
263AC_CONFIG_FILES([pkgscripts/pkginfo:release/pkginfo.in])
264AC_CONFIG_FILES([libjpeg.map])
265AC_CONFIG_FILES([Makefile simd/Makefile])
266AC_OUTPUT
267