1%verify "executed"
2%verify "null object"
3%verify "field already resolved"
4%verify "field not yet resolved"
5%verify "field cannot be resolved"
6    /*
7     * Wide 32-bit instance field get.
8     */
9    /* iget-wide vA, vB, field@CCCC */
10    mov     r0, rINST, lsr #12          @ r0<- B
11    ldr     r3, [rSELF, #offThread_methodClassDex]    @ r3<- DvmDex
12    FETCH(r1, 1)                        @ r1<- field ref CCCC
13    ldr     r2, [r3, #offDvmDex_pResFields] @ r2<- pResFields
14    GET_VREG(r9, r0)                    @ r9<- fp[B], the object pointer
15    ldr     r0, [r2, r1, lsl #2]        @ r0<- resolved InstField ptr
16    cmp     r0, #0                      @ is resolved entry null?
17    bne     .L${opcode}_finish          @ no, already resolved
188:  ldr     r2, [rSELF, #offThread_method] @ r2<- current method
19    EXPORT_PC()                         @ resolve() could throw
20    ldr     r0, [r2, #offMethod_clazz]  @ r0<- method->clazz
21    bl      dvmResolveInstField         @ r0<- resolved InstField ptr
22    cmp     r0, #0
23    bne     .L${opcode}_finish
24    b       common_exceptionThrown
25%break
26
27    /*
28     * Currently:
29     *  r0 holds resolved field
30     *  r9 holds object
31     */
32.L${opcode}_finish:
33    cmp     r9, #0                      @ check object for null
34    ldr     r3, [r0, #offInstField_byteOffset]  @ r3<- byte offset of field
35    beq     common_errNullObject        @ object was null
36    ldrd    r0, [r9, r3]                @ r0/r1<- obj.field (64-bit align ok)
37    ubfx    r2, rINST, #8, #4           @ r2<- A
38    FETCH_ADVANCE_INST(2)               @ advance rPC, load rINST
39    add     r3, rFP, r2, lsl #2         @ r3<- &fp[A]
40    GET_INST_OPCODE(ip)                 @ extract opcode from rINST
41    stmia   r3, {r0-r1}                 @ fp[A]<- r0/r1
42    GOTO_OPCODE(ip)                     @ jump to next instruction
43