floatundidf.S revision 2d1fdb26e458c4ddc04155c1d421bced3ba90cd0 
1//===-- floatundidf.S - Implement __floatundidf for i386 ------------------===//
2//
3//                     The LLVM Compiler Infrastructure
4//
5// This file is dual licensed under the MIT and the University of Illinois Open
6// Source Licenses. See LICENSE.TXT for details.
7//
8//===----------------------------------------------------------------------===//
9//
10// This file implements __floatundidf for the compiler_rt library.
11//
12//===----------------------------------------------------------------------===//
13
14#include "../assembly.h"
15
16// double __floatundidf(du_int a);
17
18#ifdef __i386__
19
20#ifndef __ELF__
21.const
22#endif
23.balign 4
24twop52: .quad 0x4330000000000000
25twop84_plus_twop52:
26		.quad 0x4530000000100000
27twop84: .quad 0x4530000000000000
28
29#define REL_ADDR(_a)	(_a)-0b(%eax)
30
31.text
32.balign 4
33DEFINE_COMPILERRT_FUNCTION(__floatundidf)
34	movss	8(%esp),						%xmm1 // high 32 bits of a
35	movss	4(%esp),						%xmm0 // low 32 bits of a
36	calll	0f
370:	popl	%eax
38	orpd	REL_ADDR(twop84),				%xmm1 // 0x1p84 + a_hi (no rounding occurs)
39	subsd	REL_ADDR(twop84_plus_twop52),	%xmm1 // a_hi - 0x1p52 (no rounding occurs)
40	orpd	REL_ADDR(twop52),				%xmm0 // 0x1p52 + a_lo (no rounding occurs)
41	addsd	%xmm1,							%xmm0 // a_hi + a_lo   (round happens here)
42	movsd	%xmm0,						   4(%esp)
43	fldl   4(%esp)
44	ret
45END_COMPILERRT_FUNCTION(__floatundidf)
46
47#endif // __i386__
48