1# Copyright (c) 2014 The WebRTC project authors. All Rights Reserved.
2#
3# Use of this source code is governed by a BSD-style license
4# that can be found in the LICENSE file in the root of the source
5# tree. An additional intellectual property rights grant can be found
6# in the file PATENTS.  All contributing project authors may
7# be found in the AUTHORS file in the root of the source tree.
8
9import("//build/config/arm.gni")
10import("../build/webrtc.gni")
11
12config("common_audio_config") {
13  include_dirs = [
14    "resampler/include",
15    "signal_processing/include",
16    "vad/include",
17  ]
18}
19
20source_set("common_audio") {
21  sources = [
22    "audio_util.cc",
23    "fir_filter.cc",
24    "fir_filter.h",
25    "fir_filter_neon.h",
26    "fir_filter_sse.h",
27    "include/audio_util.h",
28    "resampler/include/push_resampler.h",
29    "resampler/include/resampler.h",
30    "resampler/push_resampler.cc",
31    "resampler/push_sinc_resampler.cc",
32    "resampler/push_sinc_resampler.h",
33    "resampler/resampler.cc",
34    "resampler/sinc_resampler.cc",
35    "resampler/sinc_resampler.h",
36    "signal_processing/include/real_fft.h",
37    "signal_processing/include/signal_processing_library.h",
38    "signal_processing/include/spl_inl.h",
39    "signal_processing/auto_corr_to_refl_coef.c",
40    "signal_processing/auto_correlation.c",
41    "signal_processing/complex_fft_tables.h",
42    "signal_processing/copy_set_operations.c",
43    "signal_processing/cross_correlation.c",
44    "signal_processing/division_operations.c",
45    "signal_processing/dot_product_with_scale.c",
46    "signal_processing/downsample_fast.c",
47    "signal_processing/energy.c",
48    "signal_processing/filter_ar.c",
49    "signal_processing/filter_ma_fast_q12.c",
50    "signal_processing/get_hanning_window.c",
51    "signal_processing/get_scaling_square.c",
52    "signal_processing/ilbc_specific_functions.c",
53    "signal_processing/levinson_durbin.c",
54    "signal_processing/lpc_to_refl_coef.c",
55    "signal_processing/min_max_operations.c",
56    "signal_processing/randomization_functions.c",
57    "signal_processing/refl_coef_to_lpc.c",
58    "signal_processing/real_fft.c",
59    "signal_processing/resample.c",
60    "signal_processing/resample_48khz.c",
61    "signal_processing/resample_by_2.c",
62    "signal_processing/resample_by_2_internal.c",
63    "signal_processing/resample_by_2_internal.h",
64    "signal_processing/resample_fractional.c",
65    "signal_processing/spl_init.c",
66    "signal_processing/spl_sqrt.c",
67    "signal_processing/spl_version.c",
68    "signal_processing/splitting_filter.c",
69    "signal_processing/sqrt_of_one_minus_x_squared.c",
70    "signal_processing/vector_scaling_operations.c",
71    "vad/include/webrtc_vad.h",
72    "vad/webrtc_vad.c",
73    "vad/vad_core.c",
74    "vad/vad_core.h",
75    "vad/vad_filterbank.c",
76    "vad/vad_filterbank.h",
77    "vad/vad_gmm.c",
78    "vad/vad_gmm.h",
79    "vad/vad_sp.c",
80    "vad/vad_sp.h",
81    "wav_header.cc",
82    "wav_header.h",
83    "wav_writer.cc",
84    "wav_writer.h",
85  ]
86
87  deps = [ "../system_wrappers" ]
88
89  if (cpu_arch == "arm") {
90    sources += [
91      "signal_processing/complex_bit_reverse_arm.S",
92      "signal_processing/spl_sqrt_floor_arm.S",
93    ]
94
95    if (arm_version == 7) {
96      deps += [ ":common_audio_neon" ]
97      sources += [ "signal_processing/filter_ar_fast_q12_armv7.S" ]
98    } else {
99      sources += [ "signal_processing/filter_ar_fast_q12.c" ]
100    }
101  }
102
103  if (cpu_arch == "mipsel") {
104    sources += [
105      "signal_processing/include/spl_inl_mips.h",
106      "signal_processing/complex_bit_reverse_mips.c",
107      "signal_processing/complex_fft_mips.c",
108      "signal_processing/cross_correlation_mips.c",
109      "signal_processing/downsample_fast_mips.c",
110      "signal_processing/filter_ar_fast_q12_mips.c",
111      "signal_processing/min_max_operations_mips.c",
112      "signal_processing/resample_by_2_mips.c",
113      "signal_processing/spl_sqrt_floor_mips.c",
114    ]
115    if (mips_dsp_rev > 0) {
116      sources += [ "signal_processing/vector_scaling_operations_mips.c" ]
117    }
118  } else {
119    sources += [
120      "signal_processing/complex_fft.c",
121      "signal_processing/filter_ar_fast_q12.c",
122    ]
123  }
124
125  if (cpu_arch != "arm" && cpu_arch != "mipsel") {
126    sources += [
127      "signal_processing/complex_bit_reverse.c",
128      "signal_processing/spl_sqrt_floor.c",
129    ]
130  }
131
132  if (is_win) {
133    cflags = [
134      "/wd4334",  # Ignore warning on shift operator promotion.
135    ]
136  }
137
138  direct_dependent_configs = [
139    "..:common_inherited_config",
140    ":common_audio_config",
141  ]
142
143  if (is_clang) {
144    # Suppress warnings from Chrome's Clang plugins.
145    # See http://code.google.com/p/webrtc/issues/detail?id=163 for details.
146    configs -= [ "//build/config/clang:find_bad_constructs" ]
147  }
148
149  if (cpu_arch == "x86" || cpu_arch == "x64") {
150    deps += [ ":common_audio_sse2" ]
151  }
152}
153
154if (cpu_arch == "x86" || cpu_arch == "x64") {
155  source_set("common_audio_sse2") {
156    sources = [
157      "fir_filter_sse.cc",
158      "resampler/sinc_resampler_sse.cc",
159    ]
160
161    cflags = [ "-msse2" ]
162
163    configs += [ "..:common_inherited_config" ]
164
165    if (is_clang) {
166      # Suppress warnings from Chrome's Clang plugins.
167      # See http://code.google.com/p/webrtc/issues/detail?id=163 for details.
168      configs -= [ "//build/config/clang:find_bad_constructs" ]
169    }
170  }
171}
172
173if (rtc_build_armv7_neon) {
174  source_set("common_audio_neon") {
175    sources = [
176      "fir_filter_neon.cc",
177      "resampler/sinc_resampler_neon.cc",
178      "signal_processing/cross_correlation_neon.S",
179      "signal_processing/downsample_fast_neon.S",
180      "signal_processing/min_max_operations_neon.S",
181      "signal_processing/vector_scaling_operations_neon.S",
182    ]
183
184    configs += [
185       "..:common_config",
186       "..:common_inherited_config",
187    ]
188
189    # Enable compilation for the ARM v7 Neon instruction set. This is needed
190    # since //build/config/arm.gni only enables Neon for iOS, not Android.
191    # This provides the same functionality as webrtc/build/arm_neon.gypi.
192    # TODO(kjellander): Investigate if this can be moved into webrtc.gni or
193    # //build/config/arm.gni instead, to reduce code duplication.
194    # Remove the -mfpu=vfpv3-d16 cflag.
195    configs -= [ "//build/config/compiler:compiler_arm_fpu" ]
196    cflags = [
197      "-flax-vector-conversions",
198      "-mfpu=neon",
199    ]
200
201    # Disable LTO in audio_processing_neon target due to compiler bug.
202    if (rtc_use_lto) {
203      cflags -= [
204        "-flto",
205        "-ffat-lto-objects",
206      ]
207    }
208
209    if (is_clang) {
210      # Suppress warnings from Chrome's Clang plugins.
211      # See http://code.google.com/p/webrtc/issues/detail?id=163 for details.
212      configs -= [ "//build/config/clang:find_bad_constructs" ]
213    }
214  }
215}
216